GDScript 语法

这是用 EBNF 描述的 GDScript 形式文法，供参考。

备注

此语法源自参考文档和当前实现，仅用于描述。GDScript 解析器不是根据语法定义生成的。如果有不一致的地方，应该是此语法的错误，不是 GDScript 的 Bug。

  1. (* GDScript EBNF grammar.
  2.    Uppercase words are terminals generated by the tokenizer.
  3.    INDENT/DEDENT are not generated by the tokenizer yet, but they are added
  4.    here for reading convenience.
  5.    Naturally, this only cover syntax. Semantics can't be inferred from this
  6.    description.
  7. *)
  9. program = [ inheritance NEWLINE ] [ className ] { topLevelDecl } ;
  11. inheritance = "extends" ( IDENTIFIER | STRING ) { "." IDENTIFIER } ;
  12. className = "class_name" IDENTIFIER [ "," STRING ] NEWLINE ;
  14. topLevelDecl
  15.     = classVarDecl
  16.     | constDecl
  17.     | signalDecl
  18.     | enumDecl
  19.     | methodDecl
  20.     | constructorDecl
  21.     | innerClass
  22.     | "tool"
  23.     ;
  25. classVarDecl = [ "onready" ] [ export ] "var" IDENTIFIER [ ":" typeHint ]
  26.     [ "=" expression ] [ setget ] NEWLINE ;
  27. setget = "setget" [ IDENTIFIER ] [ "," IDENTIFIER] ;
  28. export = "export" [ "(" [ BUILTINTYPE | IDENTIFIER { "," literal } ] ")" ] ;
  29. typeHint = BUILTINTYPE | IDENTIFIER ;
  31. constDecl = "const" IDENTIFIER [ ":" typeHint ] "=" expression NEWLINE ;
  33. signalDecl = "signal" IDENTIFIER [ signalParList ] NEWLINE ;
  34. signalParList = "(" [ IDENTIFIER { "," IDENTIFIER } ] ")" ;
  36. enumDecl = "enum" [ IDENTIFIER ] "{" [ IDENTIFIER [ "=" INTEGER ]
  37.     { "," IDENTIFIER [ "=" INTEGER ] } [ "," ] ] "}" NEWLINE ;
  39. methodDecl = [ rpc ] [ "static" ] "func" IDENTIFIER "(" [ parList ] ")"
  40.     [ "->" typeHint] ":" stmtOrSuite ;
  41. parList = parameter { "," parameter } ;
  42. parameter = [ "var" ] IDENTIFIER [ ":" typeHint ] [ "=" expression ] ;
  43. rpc = "remote" | "master" | "puppet"
  44.     | "remotesync" | "mastersync"  | "puppetsync";
  46. constructorDecl = "func" IDENTIFIER "(" [ parList ] ")"
  47.     [ "." "(" [ argList ] ")" ] ":" stmtOrSuite ;
  48. argList = expression { "," expression } ;
  50. innerClass = "class" IDENTIFIER [ inheritance ] ":" NEWLINE
  51.     INDENT [ inheritance NEWLINE ] topLevelDecl { topLevelDecl } DEDENT ;
  53. stmtOrSuite = stmt | NEWLINE INDENT suite DEDENT ;
  54. suite = stmt { stmt };
  56. stmt
  57.     = varDeclStmt
  58.     | ifStmt
  59.     | forStmt
  60.     | whileStmt
  61.     | matchStmt
  62.     | flowStmt
  63.     | assignmentStmt
  64.     | exprStmt
  65.     | assertStmt
  66.     | yieldStmt
  67.     | preloadStmt
  68.     | "breakpoint" stmtEnd
  69.     | "pass" stmtEnd
  70.     ;
  71. stmtEnd = NEWLINE | ";" ;
  73. ifStmt = "if" expression ":" stmtOrSuite { "elif" expression ":" stmtOrSuite }
  74.     [ "else" ":" stmtOrSuite ] ;
  75. whileStmt = "while" expression ":" stmtOrSuite;
  76. forStmt = "for" IDENTIFIER "in" expression ":" stmtOrSuite ;
  78. matchStmt = "match" expression ":" NEWLINE INDENT matchBlock DEDENT;
  79. matchBlock = patternList ":" stmtOrSuite { patternList ":" stmtOrSuite };
  80. patternList = pattern { "," pattern } ;
  81. (* Note: you can't have a binding in a pattern list, but to not complicate the
  82. grammar more it won't be restricted syntactically *)
  83. pattern = literal | BUILTINTYPE | CONSTANT | "_" | bindingPattern
  84.     | arrayPattern | dictPattern ;
  85. bindingPattern = "var" IDENTIFIER ;
  86. arrayPattern = "[" [ pattern { "," pattern } [ ".." ] ] "]" ;
  87. dictPattern = "{" [ keyValuePattern ] { "," keyValuePattern } [ ".." ] "}" ;
  88. keyValuePattern = STRING [ ":" pattern ] ;
  90. flowStmt
  91.     = "continue" stmtEnd
  92.     | "break" stmtEnd
  93.     | "return" [ expression ] stmtEnd
  94.     ;
  96. assignmentStmt = subscription ( "=" | "+=" | "-=" | "*=" | "/="
  97. | "%=" | "&=" | "|=" | "^=" ) expression stmtEnd;
  98. varDeclStmt = "var" IDENTIFIER [ "=" expression ] stmtEnd;
  100. assertStmt = "assert" "(" expression [ "," STRING ] ")" stmtEnd ;
  101. yieldStmt = "yield" "(" [ expression "," expression ] ")" ;
  102. preloadStmt = "preload" "(" CONSTANT ")" ;
  104. (* This expression grammar encodes precedence. Items later in the list have
  105. higher precedence than the ones before. *)
  106. exprStmt = expression stmtEnd ;
  107. expression = cast [ "[" expression "]" ] ;
  108. cast = ternaryExpr [ "as" typeHint ];
  109. ternaryExpr = logicOr [ "if" logicOr "else" logicOr ] ;
  110. logicOr = logicAnd { ( "or" | "||" ) logicAnd } ;
  111. logicAnd = logicNot { ( "and" | "&&" ) logicNot };
  112. logicNot = ( "!" | "not" ) logicNot | in;
  113. in = comparison { "in" comparison };
  114. comparison = bitOr { ( "<" | ">" | "<=" | ">=" | "==" | "!=" ) bitOr } ;
  115. bitOr = bitXor { "|" bitXor } ;
  116. bitXor = bitAnd { "^" bitAnd } ;
  117. bitAnd = bitShift { "&" bitShift } ;
  118. bitShift = minus { ( "<<" | ">>" ) minus } ;
  119. minus = plus { "-" plus } ;
  120. plus = factor { "+" factor } ;
  121. factor = sign { ( "*" | "/" | "%" ) sign } ;
  122. sign = ( "-" | "+" ) sign | bitNot ;
  123. bitNot = "~" bitNot | is ;
  124. is = call [ "is" ( IDENTIFIER | BUILTINTYPE ) ] ;
  125. call
  126.     = (attribute [ "(" [ argList ] ")" ])
  127.     | "." IDENTIFIER "(" [ argList ] ")"
  128.     | "$" ( STRING | IDENTIFIER { '/' IDENTIFIER } );
  129. attribute = subscription { "." IDENTIFIER } ;
  130. subscription = primary [ "[" expression "]" ] ;
  131. primary = "true" | "false" | "null" | "self" | literal | arrayDecl
  132.     | dictDecl | "(" expression ")" ;
  134. literal = STRING | NUMBER | IDENTIFIER | BUILTINTYPE
  135.     | "PI" | "TAU" | "NAN" | "INF" ;
  136. arrayDecl = "[" [ expression { "," expression } "," ] "]" ;
  137. dictDecl = "{" [ keyValue { "," keyValue } "," ] "}" ;
  138. keyValue
  139.     = expression ":" expression
  140.     | IDENTIFIER "=" expression
  141.     ;