14.3. XSLT approach

14.3. XSLT approach

The document that describes XSL Transformations (XSLT) is available here:

http://www.w3.org/TR/xslt

14.3.1. Create a Pads-Pcb netlist file

The pads-pcb format is comprised of two sections.

  • The footprint list.
  • The Nets list: grouping pads references by nets.

Immediately below is a style-sheet which converts the Intermediate Netlist file to a pads-pcb netlist format:

  1. <?xml version="1.0" encoding="ISO-8859-1"?>
  2. <!--XSL style sheet to Eeschema Generic Netlist Format to PADS netlist format
  3.     Copyright (C) 2010, SoftPLC Corporation.
  4.     GPL v2.
  6.     How to use:
  7.         https://lists.launchpad.net/kicad-developers/msg05157.html
  8. -->
  10. <!DOCTYPE xsl:stylesheet [
  11.   <!ENTITY nl  "&#xd;&#xa;"> <!--new line CR, LF -->
  12. ]>
  14. <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  15. <xsl:output method="text" omit-xml-declaration="yes" indent="no"/>
  17. <xsl:template match="/export">
  18.     <xsl:text>*PADS-PCB*&nl;*PART*&nl;</xsl:text>
  19.     <xsl:apply-templates select="components/comp"/>
  20.     <xsl:text>&nl;*NET*&nl;</xsl:text>
  21.     <xsl:apply-templates select="nets/net"/>
  22.     <xsl:text>*END*&nl;</xsl:text>
  23. </xsl:template>
  25. <!-- for each component -->
  26. <xsl:template match="comp">
  27.     <xsl:text> </xsl:text>
  28.     <xsl:value-of select="@ref"/>
  29.     <xsl:text> </xsl:text>
  30.     <xsl:choose>
  31.         <xsl:when test = "footprint != '' ">
  32.             <xsl:apply-templates select="footprint"/>
  33.         </xsl:when>
  34.         <xsl:otherwise>
  35.             <xsl:text>unknown</xsl:text>
  36.         </xsl:otherwise>
  37.     </xsl:choose>
  38.     <xsl:text>&nl;</xsl:text>
  39. </xsl:template>
  41. <!-- for each net -->
  42. <xsl:template match="net">
  43.     <!-- nets are output only if there is more than one pin in net -->
  44.     <xsl:if test="count(node)>1">
  45.         <xsl:text>*SIGNAL* </xsl:text>
  46.         <xsl:choose>
  47.             <xsl:when test = "@name != '' ">
  48.                 <xsl:value-of select="@name"/>
  49.             </xsl:when>
  50.             <xsl:otherwise>
  51.                 <xsl:text>N-</xsl:text>
  52.                 <xsl:value-of select="@code"/>
  53.             </xsl:otherwise>
  54.         </xsl:choose>
  55.         <xsl:text>&nl;</xsl:text>
  56.         <xsl:apply-templates select="node"/>
  57.     </xsl:if>
  58. </xsl:template>
  60. <!-- for each node -->
  61. <xsl:template match="node">
  62.     <xsl:text> </xsl:text>
  63.     <xsl:value-of select="@ref"/>
  64.     <xsl:text>.</xsl:text>
  65.     <xsl:value-of select="@pin"/>
  66.     <xsl:text>&nl;</xsl:text>
  67. </xsl:template>
  69. </xsl:stylesheet>

And here is the pads-pcb output file after running xsltproc:

  1. *PADS-PCB*
  2. *PART*
  3. P1 unknown
  4. U2 unknown
  5. U1 unknown
  6. C1 unknown
  7. R1 unknown
  8. *NET*
  9. *SIGNAL* GND
  10. U1.7
  11. C1.2
  12. U2.7
  13. P1.4
  14. *SIGNAL* VCC
  15. R1.1
  16. U1.14
  17. U2.4
  18. U2.1
  19. U2.14
  20. P1.1
  21. *SIGNAL* N-4
  22. U1.2
  23. U2.3
  24. *SIGNAL* /SIG_OUT
  25. P1.2
  26. U2.5
  27. U2.2
  28. *SIGNAL* /CLOCK_IN
  29. R1.2
  30. C1.1
  31. U1.1
  32. P1.3
  34. *END*

The command line to make this conversion is:

  1. kicad\\bin\\xsltproc.exe -o test.net kicad\\bin\\plugins\\netlist_form_pads-pcb.xsl test.tmp

14.3.2. Create a Cadstar netlist file

The Cadstar format is comprised of two sections.

  • The footprint list.
  • The Nets list: grouping pads references by nets.

Here is the style-sheet file to make this specific conversion:

  1. <?xml version="1.0" encoding="ISO-8859-1"?>
  2. <!--XSL style sheet to Eeschema Generic Netlist Format to CADSTAR netlist format
  3.     Copyright (C) 2010, Jean-Pierre Charras.
  4.     Copyright (C) 2010, SoftPLC Corporation.
  5.     GPL v2.
  7. <!DOCTYPE xsl:stylesheet [
  8.   <!ENTITY nl  "&#xd;&#xa;"> <!--new line CR, LF -->
  9. ]>
  11. <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  12. <xsl:output method="text" omit-xml-declaration="yes" indent="no"/>
  14. <!-- Netlist header -->
  15. <xsl:template match="/export">
  16.     <xsl:text>.HEA&nl;</xsl:text>
  17.     <xsl:apply-templates select="design/date"/>  <!-- Generate line .TIM <time> -->
  18.     <xsl:apply-templates select="design/tool"/>  <!-- Generate line .APP <eeschema version> -->
  19.     <xsl:apply-templates select="components/comp"/>  <!-- Generate list of components -->
  20.     <xsl:text>&nl;&nl;</xsl:text>
  21.     <xsl:apply-templates select="nets/net"/>          <!-- Generate list of nets and connections -->
  22.     <xsl:text>&nl;.END&nl;</xsl:text>
  23. </xsl:template>
  25.  <!-- Generate line .TIM 20/08/2010 10:45:33 -->
  26. <xsl:template match="tool">
  27.     <xsl:text>.APP "</xsl:text>
  28.     <xsl:apply-templates/>
  29.     <xsl:text>"&nl;</xsl:text>
  30. </xsl:template>
  32.  <!-- Generate line .APP "eeschema (2010-08-17 BZR 2450)-unstable" -->
  33. <xsl:template match="date">
  34.     <xsl:text>.TIM </xsl:text>
  35.     <xsl:apply-templates/>
  36.     <xsl:text>&nl;</xsl:text>
  37. </xsl:template>
  39. <!-- for each component -->
  40. <xsl:template match="comp">
  41.     <xsl:text>.ADD_COM </xsl:text>
  42.     <xsl:value-of select="@ref"/>
  43.     <xsl:text> </xsl:text>
  44.     <xsl:choose>
  45.         <xsl:when test = "value != '' ">
  46.             <xsl:text>"</xsl:text> <xsl:apply-templates select="value"/> <xsl:text>"</xsl:text>
  47.         </xsl:when>
  48.         <xsl:otherwise>
  49.             <xsl:text>""</xsl:text>
  50.         </xsl:otherwise>
  51.     </xsl:choose>
  52.     <xsl:text>&nl;</xsl:text>
  53. </xsl:template>
  55. <!-- for each net -->
  56. <xsl:template match="net">
  57.     <!-- nets are output only if there is more than one pin in net -->
  58.     <xsl:if test="count(node)>1">
  59.     <xsl:variable name="netname">
  60.         <xsl:text>"</xsl:text>
  61.         <xsl:choose>
  62.             <xsl:when test = "@name != '' ">
  63.                 <xsl:value-of select="@name"/>
  64.             </xsl:when>
  65.             <xsl:otherwise>
  66.                 <xsl:text>N-</xsl:text>
  67.                 <xsl:value-of select="@code"/>
  68.         </xsl:otherwise>
  69.         </xsl:choose>
  70.         <xsl:text>"&nl;</xsl:text>
  71.         </xsl:variable>
  72.         <xsl:apply-templates select="node" mode="first"/>
  73.         <xsl:value-of select="$netname"/>
  74.         <xsl:apply-templates select="node" mode="others"/>
  75.     </xsl:if>
  76. </xsl:template>
  78. <!-- for each node -->
  79. <xsl:template match="node" mode="first">
  80.     <xsl:if test="position()=1">
  81.        <xsl:text>.ADD_TER </xsl:text>
  82.     <xsl:value-of select="@ref"/>
  83.     <xsl:text>.</xsl:text>
  84.     <xsl:value-of select="@pin"/>
  85.     <xsl:text> </xsl:text>
  86.     </xsl:if>
  87. </xsl:template>
  89. <xsl:template match="node" mode="others">
  90.     <xsl:choose>
  91.         <xsl:when test='position()=1'>
  92.         </xsl:when>
  93.         <xsl:when test='position()=2'>
  94.            <xsl:text>.TER     </xsl:text>
  95.         </xsl:when>
  96.         <xsl:otherwise>
  97.            <xsl:text>         </xsl:text>
  98.         </xsl:otherwise>
  99.     </xsl:choose>
  100.     <xsl:if test="position()>1">
  101.         <xsl:value-of select="@ref"/>
  102.         <xsl:text>.</xsl:text>
  103.         <xsl:value-of select="@pin"/>
  104.         <xsl:text>&nl;</xsl:text>
  105.     </xsl:if>
  106. </xsl:template>
  108. </xsl:stylesheet>

Here is the Cadstar output file.

  1. .HEA
  2. .TIM 21/08/2010 08:12:08
  3. .APP "eeschema (2010-08-09 BZR 2439)-unstable"
  4. .ADD_COM P1 "CONN_4"
  5. .ADD_COM U2 "74LS74"
  6. .ADD_COM U1 "74LS04"
  7. .ADD_COM C1 "CP"
  8. .ADD_COM R1 "R"
  11. .ADD_TER U1.7 "GND"
  12. .TER     C1.2
  13.          U2.7
  14.          P1.4
  15. .ADD_TER R1.1 "VCC"
  16. .TER     U1.14
  17.          U2.4
  18.          U2.1
  19.          U2.14
  20.          P1.1
  21. .ADD_TER U1.2 "N-4"
  22. .TER     U2.3
  23. .ADD_TER P1.2 "/SIG_OUT"
  24. .TER     U2.5
  25.          U2.2
  26. .ADD_TER R1.2 "/CLOCK_IN"
  27. .TER     C1.1
  28.          U1.1
  29.          P1.3
  31. .END

14.3.3. Create a OrcadPCB2 netlist file

This format has only one section which is the footprint list. Each footprint includes its list of pads with reference to a net.

Here is the style-sheet for this specific conversion:

  1. <?xml version="1.0" encoding="ISO-8859-1"?>
  2. <!--XSL style sheet to Eeschema Generic Netlist Format to CADSTAR netlist format
  3.     Copyright (C) 2010, SoftPLC Corporation.
  4.     GPL v2.
  6.     How to use:
  7.         https://lists.launchpad.net/kicad-developers/msg05157.html
  8. -->
  10. <!DOCTYPE xsl:stylesheet [
  11.   <!ENTITY nl  "&#xd;&#xa;"> <!--new line CR, LF -->
  12. ]>
  14. <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  15. <xsl:output method="text" omit-xml-declaration="yes" indent="no"/>
  17. <!--
  18.     Netlist header
  19.     Creates the entire netlist
  20.     (can be seen as equivalent to main function in C
  21. -->
  22. <xsl:template match="/export">
  23.     <xsl:text>( { Eeschema Netlist Version 1.1  </xsl:text>
  24.     <!-- Generate line .TIM <time> -->
  25. <xsl:apply-templates select="design/date"/>
  26. <!-- Generate line eeschema version ... -->
  27. <xsl:apply-templates select="design/tool"/>
  28. <xsl:text>}&nl;</xsl:text>
  30. <!-- Generate the list of components -->
  31. <xsl:apply-templates select="components/comp"/>  <!-- Generate list of components -->
  33. <!-- end of file -->
  34. <xsl:text>)&nl;*&nl;</xsl:text>
  35. </xsl:template>
  37. <!--
  38.     Generate id in header like "eeschema (2010-08-17 BZR 2450)-unstable"
  39. -->
  40. <xsl:template match="tool">
  41.     <xsl:apply-templates/>
  42. </xsl:template>
  44. <!--
  45.     Generate date in header like "20/08/2010 10:45:33"
  46. -->
  47. <xsl:template match="date">
  48.     <xsl:apply-templates/>
  49.     <xsl:text>&nl;</xsl:text>
  50. </xsl:template>
  52. <!--
  53.     This template read each component
  54.     (path = /export/components/comp)
  55.     creates lines:
  56.      ( 3EBF7DBD $noname U1 74LS125
  57.       ... pin list ...
  58.       )
  59.     and calls "create_pin_list" template to build the pin list
  60. -->
  61. <xsl:template match="comp">
  62.     <xsl:text> ( </xsl:text>
  63.     <xsl:choose>
  64.         <xsl:when test = "tstamp != '' ">
  65.             <xsl:apply-templates select="tstamp"/>
  66.         </xsl:when>
  67.         <xsl:otherwise>
  68.             <xsl:text>00000000</xsl:text>
  69.         </xsl:otherwise>
  70.     </xsl:choose>
  71.     <xsl:text> </xsl:text>
  72.     <xsl:choose>
  73.         <xsl:when test = "footprint != '' ">
  74.             <xsl:apply-templates select="footprint"/>
  75.         </xsl:when>
  76.         <xsl:otherwise>
  77.             <xsl:text>$noname</xsl:text>
  78.         </xsl:otherwise>
  79.     </xsl:choose>
  80.     <xsl:text> </xsl:text>
  81.     <xsl:value-of select="@ref"/>
  82.     <xsl:text> </xsl:text>
  83.     <xsl:choose>
  84.         <xsl:when test = "value != '' ">
  85.             <xsl:apply-templates select="value"/>
  86.         </xsl:when>
  87.         <xsl:otherwise>
  88.             <xsl:text>"~"</xsl:text>
  89.         </xsl:otherwise>
  90.     </xsl:choose>
  91.     <xsl:text>&nl;</xsl:text>
  92.     <xsl:call-template name="Search_pin_list" >
  93.         <xsl:with-param name="cmplib_id" select="libsource/@part"/>
  94.         <xsl:with-param name="cmp_ref" select="@ref"/>
  95.     </xsl:call-template>
  96.     <xsl:text> )&nl;</xsl:text>
  97. </xsl:template>
  99. <!--
  100.     This template search for a given lib component description in list
  101.     lib component descriptions are in /export/libparts,
  102.     and each description start at ./libpart
  103.     We search here for the list of pins of the given component
  104.     This template has 2 parameters:
  105.         "cmplib_id" (reference in libparts)
  106.         "cmp_ref"   (schematic reference of the given component)
  107. -->
  108. <xsl:template name="Search_pin_list" >
  109.     <xsl:param name="cmplib_id" select="0" />
  110.     <xsl:param name="cmp_ref" select="0" />
  111.         <xsl:for-each select="/export/libparts/libpart">
  112.             <xsl:if test = "@part = $cmplib_id ">
  113.                 <xsl:apply-templates name="build_pin_list" select="pins/pin">
  114.                     <xsl:with-param name="cmp_ref" select="$cmp_ref"/>
  115.                 </xsl:apply-templates>
  116.             </xsl:if>
  117.         </xsl:for-each>
  118. </xsl:template>
  121. <!--
  122.     This template writes the pin list of a component
  123.     from the pin list of the library description
  124.     The pin list from library description is something like
  125.           <pins>
  126.             <pin num="1" type="passive"/>
  127.             <pin num="2" type="passive"/>
  128.           </pins>
  129.     Output pin list is ( <pin num> <net name> )
  130.     something like
  131.             ( 1 VCC )
  132.             ( 2 GND )
  133. -->
  134. <xsl:template name="build_pin_list" match="pin">
  135.     <xsl:param name="cmp_ref" select="0" />
  137.     <!-- write pin numner and separator -->
  138.     <xsl:text>  ( </xsl:text>
  139.     <xsl:value-of select="@num"/>
  140.     <xsl:text> </xsl:text>
  142.     <!-- search net name in nets section and write it: -->
  143.     <xsl:variable name="pinNum" select="@num" />
  144.     <xsl:for-each select="/export/nets/net">
  145.         <!-- net name is output only if there is more than one pin in net
  146.              else use "?" as net name, so count items in this net
  147.         -->
  148.         <xsl:variable name="pinCnt" select="count(node)" />
  149.         <xsl:apply-templates name="Search_pin_netname" select="node">
  150.             <xsl:with-param name="cmp_ref" select="$cmp_ref"/>
  151.             <xsl:with-param name="pin_cnt_in_net" select="$pinCnt"/>
  152.             <xsl:with-param name="pin_num"> <xsl:value-of select="$pinNum"/>
  153.             </xsl:with-param>
  154.         </xsl:apply-templates>
  155.     </xsl:for-each>
  157.     <!-- close line -->
  158.     <xsl:text> )&nl;</xsl:text>
  159. </xsl:template>
  161. <!--
  162.     This template writes the pin netname of a given pin of a given component
  163.     from the nets list
  164.     The nets list description is something like
  165.       <nets>
  166.         <net code="1" name="GND">
  167.           <node ref="J1" pin="20"/>
  168.               <node ref="C2" pin="2"/>
  169.         </net>
  170.         <net code="2" name="">
  171.           <node ref="U2" pin="11"/>
  172.         </net>
  173.     </nets>
  174.     This template has 2 parameters:
  175.         "cmp_ref"   (schematic reference of the given component)
  176.         "pin_num"   (pin number)
  177. -->
  179. <xsl:template name="Search_pin_netname" match="node">
  180.     <xsl:param name="cmp_ref" select="0" />
  181.     <xsl:param name="pin_num" select="0" />
  182.     <xsl:param name="pin_cnt_in_net" select="0" />
  184.     <xsl:if test = "@ref = $cmp_ref ">
  185.         <xsl:if test = "@pin = $pin_num">
  186.         <!-- net name is output only if there is more than one pin in net
  187.              else use "?" as net name
  188.         -->
  189.             <xsl:if test = "$pin_cnt_in_net>1">
  190.                 <xsl:choose>
  191.                     <!-- if a net has a name, use it,
  192.                         else build a name from its net code
  193.                     -->
  194.                     <xsl:when test = "../@name != '' ">
  195.                         <xsl:value-of select="../@name"/>
  196.                     </xsl:when>
  197.                     <xsl:otherwise>
  198.                         <xsl:text>$N-0</xsl:text><xsl:value-of select="../@code"/>
  199.                     </xsl:otherwise>
  200.                 </xsl:choose>
  201.             </xsl:if>
  202.             <xsl:if test = "$pin_cnt_in_net &lt;2">
  203.                 <xsl:text>?</xsl:text>
  204.             </xsl:if>
  205.         </xsl:if>
  206.     </xsl:if>
  208. </xsl:template>
  210. </xsl:stylesheet>

Here is the OrcadPCB2 output file.

  1. ( { Eeschema Netlist Version 1.1  29/08/2010 21:07:51
  2. eeschema (2010-08-28 BZR 2458)-unstable}
  3.  ( 4C6E2141 $noname P1 CONN_4
  4.   (  1 VCC )
  5.   (  2 /SIG_OUT )
  6.   (  3 /CLOCK_IN )
  7.   (  4 GND )
  8.  )
  9.  ( 4C6E20BA $noname U2 74LS74
  10.   (  1 VCC )
  11.   (  2 /SIG_OUT )
  12.   (  3 N-04 )
  13.   (  4 VCC )
  14.   (  5 /SIG_OUT )
  15.   (  6 ? )
  16.   (  7 GND )
  17.   (  14 VCC )
  18.  )
  19.  ( 4C6E20A6 $noname U1 74LS04
  20.   (  1 /CLOCK_IN )
  21.   (  2 N-04 )
  22.   (  7 GND )
  23.   (  14 VCC )
  24.  )
  25.  ( 4C6E2094 $noname C1 CP
  26.   (  1 /CLOCK_IN )
  27.   (  2 GND )
  28.  )
  29.  ( 4C6E208A $noname R1 R
  30.   (  1 VCC )
  31.   (  2 /CLOCK_IN )
  32.  )
  33. )
  34. *

14.3.4. Eeschema plugins interface

Intermediate Netlist converters can be automatically launched within Eeschema.

Init the Dialog window

One can add a new netlist plug-in user interface tab by clicking on the Add Plugin button.

eeschema_plugin_add_plugin_png

Here is what the configuration data for the PadsPcb tab looks like:

eeschema_plugin_padspcb_png

Plugin Configuration Parameters

The Eeschema plug-in configuration dialog requires the following information:

  • The title: for instance, the name of the netlist format.
  • The command line to launch the converter.

Once you click on the netlist button the following will happen:

  1. Eeschema creates an intermediate netlist file *.xml, for instance test.xml.
  2. Eeschema runs the plug-in by reading test.xml and creates test.net.

Generate netlist files with the command line

Assuming we are using the program xsltproc.exe to apply the sheet style to the intermediate file, xsltproc.exe is executed with the following command:

xsltproc.exe -o <output filename> < style-sheet filename> <input XML file to convert>

In KiCad under Windows the command line is the following:

f:/kicad/bin/xsltproc.exe -o “%O” f:/kicad/bin/plugins/netlist_form_pads-pcb.xsl “%I”

Under Linux the command becomes as follows:

xsltproc -o “%O” /usr/local/kicad/bin/plugins/netlist_form_pads-pcb.xsl “%I”

Where netlist_form_pads-pcb.xsl is the style-sheet that you are applying. Do not forget the double quotes around the file names, this allows them to have spaces after the substitution by Eeschema.

The command line format accepts parameters for filenames:

The supported formatting parameters are.

  • %B ⇒ base filename and path of selected output file, minus path and extension.
  • %I ⇒ complete filename and path of the temporary input file (the intermediate net file).
  • %O ⇒ complete filename and path of the user chosen output file.

%I will be replaced by the actual intermediate file name

%O will be replaced by the actual output file name.

Command line format: example for xsltproc

The command line format for xsltproc is the following:

<path of xsltproc> xsltproc <xsltproc parameters>

under Windows:

f:/kicad/bin/xsltproc.exe -o “%O” f:/kicad/bin/plugins/netlist_form_pads-pcb.xsl “%I”

under Linux:

xsltproc -o “%O” /usr/local/kicad/bin/plugins/netlist_form_pads-pcb.xsl “%I”

The above examples assume xsltproc is installed on your PC under Windows and all files located in kicad/bin.

14.3.5. Bill of Materials Generation

Because the intermediate netlist file contains all information about used components, a BOM can be extracted from it. Here is the plug-in setup window (on Linux) to create a customized Bill Of Materials (BOM) file:

bom-netlist-tab_png

The path to the style sheet bom2csv.xsl is system dependent. The currently best XSLT style-sheet for BOM generation at this time is called bom2csv.xsl. You are free to modify it according to your needs, and if you develop something generally useful, ask that it become part of the KiCad project.