Events and interaction

Making objects interactive is done creating a h2d.Interactive instance. You provide it an interaction area and attach it to a sprite.

  1. var interaction = new h2d.Interactive(300, 100, mySprite);
  2. interaction.onOver = function(event : hxd.Event) {
  3.     mySprite.alpha = 0.7;
  4. }
  5. interaction.onOut = function(event : hxd.Event) {
  6.     mySprite.alpha = 1;
  7. }
  8. interaction.onPush = function(event : hxd.Event) {
  9.     trace("down!");
  10. }
  11. interaction.onRelease = function(event : hxd.Event) {
  12.     trace("up!");
  13. }
  14. interaction.onClick = function(event : hxd.Event) {
  15.     trace("click!");
  16. }

Global events

You can listen to global events (keyboard, touch, mouse, window) by adding event listener to the hxd.Window instance.

  1. function onEvent(event : hxd.Event) {
  2.     trace(event.toString());
  3. }
  4. hxd.Window.getInstance().addEventTarget(onEvent);

Don’t forget to remove the event using removeEventTarget when disposing your objects.

Keyboard events

Keyboard events can be observerd using the global event, check if the event.kind is EKeyDown or EKeyUp.

  1. function onEvent(event : hxd.Event) {
  2.     switch(event.kind) {
  3.         case EKeyDown: trace('DOWN keyCode: ${event.keyCode}, charCode: ${event.charCode}');
  4.         case EKeyUp: trace('UP keyCode: ${event.keyCode}, charCode: ${event.charCode}');
  5.         case _:
  6.     }
  7. }
  8. hxd.Window.getInstance().addEventTarget(onEvent);

You can use the static functions hxd.Key.isPressed, hxd.Key.isDown and hxd.Key.isReleased.

  1. if (Key.isPressed(Key.SPACE)) {
  2.     trace("shoot!");
  3. }

Resize events

You can listen to resize events by adding addResizeEvent listener to the hxd.Window instance.

  1. function onResize() {
  2.     var stage = hxd.Window.getInstance();
  3.     trace('Resized to ${stage.width}px * ${stage.height}px');
  4. }
  5. hxd.Window.getInstance().addResizeEvent(onResize);

Don’t forget to remove the event using removeEventTarget when disposing your objects.

All events callbacks in Heaps receive a hxd.Event instance, which contains info about the event.