Casting

A type cast converts a value of one type to another. Zig has Type Coercion for conversions that are known to be completely safe and unambiguous, and Explicit Casts for conversions that one would not want to happen on accident. There is also a third kind of type conversion called Peer Type Resolution for the case when a result type must be decided given multiple operand types.

Type Coercion

Type coercion occurs when one type is expected, but different type is provided:

test.zig

  1. test "type coercion - variable declaration" {
  2.     var a: u8 = 1;
  3.     var b: u16 = a;
  4. }
  6. test "type coercion - function call" {
  7.     var a: u8 = 1;
  8.     foo(a);
  9. }
  11. fn foo(b: u16) void {}
  13. test "type coercion - @as builtin" {
  14.     var a: u8 = 1;
  15.     var b = @as(u16, a);
  16. }
  1. $ zig test test.zig
  2. 1/3 test "type coercion - variable declaration"... OK
  3. 2/3 test "type coercion - function call"... OK
  4. 3/3 test "type coercion - @as builtin"... OK
  5. All 3 tests passed.

Type coercions are only allowed when it is completely unambiguous how to get from one type to another, and the transformation is guaranteed to be safe. There is one exception, which is C Pointers.

Type Coercion: Stricter Qualification

Values which have the same representation at runtime can be cast to increase the strictness of the qualifiers, no matter how nested the qualifiers are:

  • const - non-const to const is allowed
  • volatile - non-volatile to volatile is allowed
  • align - bigger to smaller alignment is allowed
  • error sets to supersets is allowed

These casts are no-ops at runtime since the value representation does not change.

test.zig

  1. test "type coercion - const qualification" {
  2.     var a: i32 = 1;
  3.     var b: *i32 = &a;
  4.     foo(b);
  5. }
  7. fn foo(a: *const i32) void {}
  1. $ zig test test.zig
  2. 1/1 test "type coercion - const qualification"... OK
  3. All 1 tests passed.

In addition, pointers coerce to const optional pointers:

test.zig

  1. const std = @import("std");
  2. const expect = std.testing.expect;
  3. const mem = std.mem;
  5. test "cast *[1][*]const u8 to [*]const ?[*]const u8" {
  6.     const window_name = [1][*]const u8{"window name"};
  7.     const x: [*]const ?[*]const u8 = &window_name;
  8.     expect(mem.eql(u8, std.mem.spanZ(@ptrCast([*:0]const u8, x[0].?)), "window name"));
  9. }
  1. $ zig test test.zig
  2. 1/1 test "cast *[1][*]const u8 to [*]const ?[*]const u8"... OK
  3. All 1 tests passed.

Type Coercion: Integer and Float Widening

Integers coerce to integer types which can represent every value of the old type, and likewise Floats coerce to float types which can represent every value of the old type.

test.zig

  1. const std = @import("std");
  2. const expect = std.testing.expect;
  3. const mem = std.mem;
  5. test "integer widening" {
  6.     var a: u8 = 250;
  7.     var b: u16 = a;
  8.     var c: u32 = b;
  9.     var d: u64 = c;
  10.     var e: u64 = d;
  11.     var f: u128 = e;
  12.     expect(f == a);
  13. }
  15. test "implicit unsigned integer to signed integer" {
  16.     var a: u8 = 250;
  17.     var b: i16 = a;
  18.     expect(b == 250);
  19. }
  21. test "float widening" {
  22.     // Note: there is an open issue preventing this from working on aarch64:
  23.     // https://github.com/ziglang/zig/issues/3282
  24.     if (std.Target.current.cpu.arch == .aarch64) return error.SkipZigTest;
  26.     var a: f16 = 12.34;
  27.     var b: f32 = a;
  28.     var c: f64 = b;
  29.     var d: f128 = c;
  30.     expect(d == a);
  31. }
  1. $ zig test test.zig
  2. 1/3 test "integer widening"... OK
  3. 2/3 test "implicit unsigned integer to signed integer"... OK
  4. 3/3 test "float widening"... OK
  5. All 3 tests passed.

Type Coercion: Coercion Float to Int

A compiler error is appropriate because this ambiguous expression leaves the compiler two choices about the coercion.

  • Cast 54.0 to comptime_int resulting in @as(comptime_int, 10), which is casted to @as(f32, 10)
  • Cast 5 to comptime_float resulting in @as(comptime_float, 10.8), which is casted to @as(f32, 10.8)

test.zig

  1. // Compile time coercion of float to int
  2. test "implicit cast to comptime_int" {
  3.     var f: f32 = 54.0 / 5;
  4. }
  1. $ zig test test.zig
  2. ./docgen_tmp/test.zig:3:18: error: float value 54.000000 cannot be coerced to type 'comptime_int'
  3.     var f: f32 = 54.0 / 5;
  4.                  ^
  5. ./docgen_tmp/test.zig:3:23: note: referenced here
  6.     var f: f32 = 54.0 / 5;
  7.                       ^

Type Coercion: Arrays and Pointers

coerce_arrays_and_ptrs.zig

  1. const std = @import("std");
  2. const expect = std.testing.expect;
  4. // This cast exists primarily so that string literals can be
  5. // passed to functions that accept const slices. However
  6. // it is probably going to be removed from the language when
  7. // https://github.com/ziglang/zig/issues/265 is implemented.
  8. test "[N]T to []const T" {
  9.     var x1: []const u8 = "hello";
  10.     var x2: []const u8 = &[5]u8{ 'h', 'e', 'l', 'l', 111 };
  11.     expect(std.mem.eql(u8, x1, x2));
  13.     var y: []const f32 = &[2]f32{ 1.2, 3.4 };
  14.     expect(y[0] == 1.2);
  15. }
  17. // Likewise, it works when the destination type is an error union.
  18. test "[N]T to E![]const T" {
  19.     var x1: anyerror![]const u8 = "hello";
  20.     var x2: anyerror![]const u8 = &[5]u8{ 'h', 'e', 'l', 'l', 111 };
  21.     expect(std.mem.eql(u8, try x1, try x2));
  23.     var y: anyerror![]const f32 = &[2]f32{ 1.2, 3.4 };
  24.     expect((try y)[0] == 1.2);
  25. }
  27. // Likewise, it works when the destination type is an optional.
  28. test "[N]T to ?[]const T" {
  29.     var x1: ?[]const u8 = "hello";
  30.     var x2: ?[]const u8 = &[5]u8{ 'h', 'e', 'l', 'l', 111 };
  31.     expect(std.mem.eql(u8, x1.?, x2.?));
  33.     var y: ?[]const f32 = &[2]f32{ 1.2, 3.4 };
  34.     expect(y.?[0] == 1.2);
  35. }
  37. // In this cast, the array length becomes the slice length.
  38. test "*[N]T to []T" {
  39.     var buf: [5]u8 = "hello".*;
  40.     const x: []u8 = &buf;
  41.     expect(std.mem.eql(u8, x, "hello"));
  43.     const buf2 = [2]f32{ 1.2, 3.4 };
  44.     const x2: []const f32 = &buf2;
  45.     expect(std.mem.eql(f32, x2, &[2]f32{ 1.2, 3.4 }));
  46. }
  48. // Single-item pointers to arrays can be coerced to
  49. // unknown length pointers.
  50. test "*[N]T to [*]T" {
  51.     var buf: [5]u8 = "hello".*;
  52.     const x: [*]u8 = &buf;
  53.     expect(x[4] == 'o');
  54.     // x[5] would be an uncaught out of bounds pointer dereference!
  55. }
  57. // Likewise, it works when the destination type is an optional.
  58. test "*[N]T to ?[*]T" {
  59.     var buf: [5]u8 = "hello".*;
  60.     const x: ?[*]u8 = &buf;
  61.     expect(x.?[4] == 'o');
  62. }
  64. // Single-item pointers can be cast to len-1 single-item arrays.
  65. test "*T to *[1]T" {
  66.     var x: i32 = 1234;
  67.     const y: *[1]i32 = &x;
  68.     const z: [*]i32 = y;
  69.     expect(z[0] == 1234);
  70. }
  1. $ zig test coerce_arrays_and_ptrs.zig
  2. 1/7 test "[N]T to []const T"... OK
  3. 2/7 test "[N]T to E![]const T"... OK
  4. 3/7 test "[N]T to ?[]const T"... OK
  5. 4/7 test "*[N]T to []T"... OK
  6. 5/7 test "*[N]T to [*]T"... OK
  7. 6/7 test "*[N]T to ?[*]T"... OK
  8. 7/7 test "*T to *[1]T"... OK
  9. All 7 tests passed.

See also:

Type Coercion: Optionals

The payload type of Optionals, as well as null, coerce to the optional type.

test.zig

  1. const std = @import("std");
  2. const expect = std.testing.expect;
  4. test "coerce to optionals" {
  5.     const x: ?i32 = 1234;
  6.     const y: ?i32 = null;
  8.     expect(x.? == 1234);
  9.     expect(y == null);
  10. }
  1. $ zig test test.zig
  2. 1/1 test "coerce to optionals"... OK
  3. All 1 tests passed.

It works nested inside the Error Union Type, too:

test.zig

  1. const std = @import("std");
  2. const expect = std.testing.expect;
  4. test "coerce to optionals wrapped in error union" {
  5.     const x: anyerror!?i32 = 1234;
  6.     const y: anyerror!?i32 = null;
  8.     expect((try x).? == 1234);
  9.     expect((try y) == null);
  10. }
  1. $ zig test test.zig
  2. 1/1 test "coerce to optionals wrapped in error union"... OK
  3. All 1 tests passed.

Type Coercion: Error Unions

The payload type of an Error Union Type as well as the Error Set Type coerce to the error union type:

test.zig

  1. const std = @import("std");
  2. const expect = std.testing.expect;
  4. test "coercion to error unions" {
  5.     const x: anyerror!i32 = 1234;
  6.     const y: anyerror!i32 = error.Failure;
  8.     expect((try x) == 1234);
  9.     std.testing.expectError(error.Failure, y);
  10. }
  1. $ zig test test.zig
  2. 1/1 test "coercion to error unions"... OK
  3. All 1 tests passed.

Type Coercion: Compile-Time Known Numbers

When a number is comptime-known to be representable in the destination type, it may be coerced:

test.zig

  1. const std = @import("std");
  2. const expect = std.testing.expect;
  4. test "coercing large integer type to smaller one when value is comptime known to fit" {
  5.     const x: u64 = 255;
  6.     const y: u8 = x;
  7.     expect(y == 255);
  8. }
  1. $ zig test test.zig
  2. 1/1 test "coercing large integer type to smaller one when value is comptime known to fit"... OK
  3. All 1 tests passed.

Type Coercion: unions and enums

Tagged unions can be coerced to enums, and enums can be coerced to tagged unions when they are comptime-known to be a field of the union that has only one possible value, such as void:

test.zig

  1. const std = @import("std");
  2. const expect = std.testing.expect;
  4. const E = enum {
  5.     one,
  6.     two,
  7.     three,
  8. };
  10. const U = union(E) {
  11.     one: i32,
  12.     two: f32,
  13.     three,
  14. };
  16. test "coercion between unions and enums" {
  17.     var u = U{ .two = 12.34 };
  18.     var e: E = u;
  19.     expect(e == E.two);
  21.     const three = E.three;
  22.     var another_u: U = three;
  23.     expect(another_u == E.three);
  24. }
  1. $ zig test test.zig
  2. 1/1 test "coercion between unions and enums"... OK
  3. All 1 tests passed.

See also:

Type Coercion: Zero Bit Types

Zero Bit Types may be coerced to single-item Pointers, regardless of const.

TODO document the reasoning for this

TODO document whether vice versa should work and why

test.zig

  1. test "coercion of zero bit types" {
  2.     var x: void = {};
  3.     var y: *void = x;
  4.     //var z: void = y; // TODO
  5. }
  1. $ zig test test.zig
  2. 1/1 test "coercion of zero bit types"... OK
  3. All 1 tests passed.

Type Coercion: undefined

undefined can be cast to any type.

Explicit Casts

Explicit casts are performed via Builtin Functions. Some explicit casts are safe; some are not. Some explicit casts perform language-level assertions; some do not. Some explicit casts are no-ops at runtime; some are not.

  • @bitCast - change type but maintain bit representation
  • @alignCast - make a pointer have more alignment
  • @boolToInt - convert true to 1 and false to 0
  • @enumToInt - obtain the integer tag value of an enum or tagged union
  • @errSetCast - convert to a smaller error set
  • @errorToInt - obtain the integer value of an error code
  • @floatCast - convert a larger float to a smaller float
  • @floatToInt - obtain the integer part of a float value
  • @intCast - convert between integer types
  • @intToEnum - obtain an enum value based on its integer tag value
  • @intToError - obtain an error code based on its integer value
  • @intToFloat - convert an integer to a float value
  • @intToPtr - convert an address to a pointer
  • @ptrCast - convert between pointer types
  • @ptrToInt - obtain the address of a pointer
  • @truncate - convert between integer types, chopping off bits

Peer Type Resolution

Peer Type Resolution occurs in these places:

This kind of type resolution chooses a type that all peer types can coerce into. Here are some examples:

peer_type_resolution.zig

  1. const std = @import("std");
  2. const expect = std.testing.expect;
  3. const mem = std.mem;
  5. test "peer resolve int widening" {
  6.     var a: i8 = 12;
  7.     var b: i16 = 34;
  8.     var c = a + b;
  9.     expect(c == 46);
  10.     expect(@TypeOf(c) == i16);
  11. }
  13. test "peer resolve arrays of different size to const slice" {
  14.     expect(mem.eql(u8, boolToStr(true), "true"));
  15.     expect(mem.eql(u8, boolToStr(false), "false"));
  16.     comptime expect(mem.eql(u8, boolToStr(true), "true"));
  17.     comptime expect(mem.eql(u8, boolToStr(false), "false"));
  18. }
  19. fn boolToStr(b: bool) []const u8 {
  20.     return if (b) "true" else "false";
  21. }
  23. test "peer resolve array and const slice" {
  24.     testPeerResolveArrayConstSlice(true);
  25.     comptime testPeerResolveArrayConstSlice(true);
  26. }
  27. fn testPeerResolveArrayConstSlice(b: bool) void {
  28.     const value1 = if (b) "aoeu" else @as([]const u8, "zz");
  29.     const value2 = if (b) @as([]const u8, "zz") else "aoeu";
  30.     expect(mem.eql(u8, value1, "aoeu"));
  31.     expect(mem.eql(u8, value2, "zz"));
  32. }
  34. test "peer type resolution: ?T and T" {
  35.     expect(peerTypeTAndOptionalT(true, false).? == 0);
  36.     expect(peerTypeTAndOptionalT(false, false).? == 3);
  37.     comptime {
  38.         expect(peerTypeTAndOptionalT(true, false).? == 0);
  39.         expect(peerTypeTAndOptionalT(false, false).? == 3);
  40.     }
  41. }
  42. fn peerTypeTAndOptionalT(c: bool, b: bool) ?usize {
  43.     if (c) {
  44.         return if (b) null else @as(usize, 0);
  45.     }
  47.     return @as(usize, 3);
  48. }
  50. test "peer type resolution: *[0]u8 and []const u8" {
  51.     expect(peerTypeEmptyArrayAndSlice(true, "hi").len == 0);
  52.     expect(peerTypeEmptyArrayAndSlice(false, "hi").len == 1);
  53.     comptime {
  54.         expect(peerTypeEmptyArrayAndSlice(true, "hi").len == 0);
  55.         expect(peerTypeEmptyArrayAndSlice(false, "hi").len == 1);
  56.     }
  57. }
  58. fn peerTypeEmptyArrayAndSlice(a: bool, slice: []const u8) []const u8 {
  59.     if (a) {
  60.         return &[_]u8{};
  61.     }
  63.     return slice[0..1];
  64. }
  65. test "peer type resolution: *[0]u8, []const u8, and anyerror![]u8" {
  66.     {
  67.         var data = "hi".*;
  68.         const slice = data[0..];
  69.         expect((try peerTypeEmptyArrayAndSliceAndError(true, slice)).len == 0);
  70.         expect((try peerTypeEmptyArrayAndSliceAndError(false, slice)).len == 1);
  71.     }
  72.     comptime {
  73.         var data = "hi".*;
  74.         const slice = data[0..];
  75.         expect((try peerTypeEmptyArrayAndSliceAndError(true, slice)).len == 0);
  76.         expect((try peerTypeEmptyArrayAndSliceAndError(false, slice)).len == 1);
  77.     }
  78. }
  79. fn peerTypeEmptyArrayAndSliceAndError(a: bool, slice: []u8) anyerror![]u8 {
  80.     if (a) {
  81.         return &[_]u8{};
  82.     }
  84.     return slice[0..1];
  85. }
  87. test "peer type resolution: *const T and ?*T" {
  88.     const a = @intToPtr(*const usize, 0x123456780);
  89.     const b = @intToPtr(?*usize, 0x123456780);
  90.     expect(a == b);
  91.     expect(b == a);
  92. }
  1. $ zig test peer_type_resolution.zig
  2. 1/7 test "peer resolve int widening"... OK
  3. 2/7 test "peer resolve arrays of different size to const slice"... OK
  4. 3/7 test "peer resolve array and const slice"... OK
  5. 4/7 test "peer type resolution: ?T and T"... OK
  6. 5/7 test "peer type resolution: *[0]u8 and []const u8"... OK
  7. 6/7 test "peer type resolution: *[0]u8, []const u8, and anyerror![]u8"... OK
  8. 7/7 test "peer type resolution: *const T and ?*T"... OK
  9. All 7 tests passed.