Visitor counter

Remember back in the good ol’ days of the internet, where no website was complete without a little “you are visitor number 32” thingy? Ahh, those were the good times! Let’s recreate that wonderful experience in Yesod!

Now, if we wanted to do this properly, we’d store this information in some kind of persistent storage layer, like a database, so that the information could be shared across multiple horizontally-scaled web servers, and so that the information would survive an app restart.

But our goal here isn’t to demonstrate good practice (after all, if it was about good practice, I wouldn’t be demonstrating a visitor counter, right?). Instead, this is meant to provide a simple example of sharing some state among multiple handlers. A real-world use case would be caching information across requests. Just remember that when you use the technique we’ll be showing, you need to be careful about multiple app servers and app restarts.

The technique is simple: we create a new field in the foundation datatype for a mutable reference to some data, and then access it in each handler. The technique is so simple, it’s worth just diving into the code:

  1. {-# LANGUAGE OverloadedStrings #-}
  2. {-# LANGUAGE QuasiQuotes       #-}
  3. {-# LANGUAGE TemplateHaskell   #-}
  4. {-# LANGUAGE TypeFamilies      #-}
  5. import           Data.IORef
  6. import           Yesod
  8. data App = App
  9.     { visitors :: IORef Int
  10.     }
  12. mkYesod "App" [parseRoutes|
  13. / HomeR GET
  14. |]
  16. instance Yesod App
  18. getHomeR :: Handler Html
  19. getHomeR = do
  20.     visitorsRef <- fmap visitors getYesod
  21.     visitors <-
  22.         liftIO $ atomicModifyIORef visitorsRef $ \i ->
  23.         (i + 1, i + 1)
  24.     defaultLayout
  25.         [whamlet|
  26.             <p>Welcome, you are visitor number #{visitors}.
  27.         |]
  29. main :: IO ()
  30. main = do
  31.     visitorsRef <- newIORef 0
  32.     warp 3000 App
  33.         { visitors = visitorsRef
  34.         }

I used IORef here, since we didn’t need anything more than it provided, but you’re free to use MVars or TVars as well. In fact, a good exercise for the reader is to modify the above program to store the visitor count in a TVar instead.