Environment variables for configuration

There’s a recent move, perhaps most prominently advocated by the twelve-factor app, to store all app configuration in environment variables, instead of using config files or hard-coding them into the application source code (you don’t do that, right?).

Yesod’s scaffolding comes built in with some support for this, most specifically for respecting the APPROOT environment variable to indicate how URLs should be generated, the PORT environment variable for which port to listen for requests on, and database connection settings. (Incidentally, this ties in nicely with the Keter deployment manager.)

The technique for doing this is quite easy: just do the environment variable lookup in your main funciton. This example demonstrates this technique, along with the slightly special handling necessary for setting the application root.

  1. {-# LANGUAGE OverloadedStrings #-}
  2. {-# LANGUAGE QuasiQuotes       #-}
  3. {-# LANGUAGE RecordWildCards   #-}
  4. {-# LANGUAGE TemplateHaskell   #-}
  5. {-# LANGUAGE TypeFamilies      #-}
  6. import           Data.Text          (Text, pack)
  7. import           System.Environment
  8. import           Yesod
  10. data App = App
  11.     { myApproot      :: Text
  12.     , welcomeMessage :: Text
  13.     }
  15. mkYesod "App" [parseRoutes|
  16. / HomeR GET
  17. |]
  19. instance Yesod App where
  20.     approot = ApprootMaster myApproot
  22. getHomeR :: Handler Html
  23. getHomeR = defaultLayout $ do
  24.     App {..} <- getYesod
  25.     setTitle "Environment variables"
  26.     [whamlet|
  27.         <p>Here's the welcome message: #{welcomeMessage}
  28.         <p>
  29.             <a href=@{HomeR}>And a link to: @{HomeR}
  30.     |]
  32. main :: IO ()
  33. main = do
  34.     myApproot <- fmap pack $ getEnv "APPROOT"
  35.     welcomeMessage <- fmap pack $ getEnv "WELCOME_MESSAGE"
  36.     warp 3000 App {..}

The only tricky things here are:

  1. You need to convert the String value returned by getEnv into a Text by using pack.

  2. We use the ApprootMaster constructor for approot, which says “apply this function to the foundation datatype to get the actual applicaiton root.”