Query Parameters​

EdgeQL queries can reference parameters with $ notation. The value of these parameters are supplied externally.

select <str>$var;
select <int64>$a + <int64>$b;
select BlogPost filter .id = <uuid>$blog_id;

Note that we provided an explicit type cast before the parameter. This is required, as it enables EdgeDB to enforce the provided types at runtime.

Usage with clients​

REPL​

When you include a parameter reference in an EdgeDB REPL, you’ll be prompted interactively to provide a value or values.

select 'I ❤️ ' ++ <str>$var ++ '!';

Parameter <str>$var: EdgeDB
{'I ❤️ EdgeDB!'}

Python​

await client.query(
    "select 'I ❤️ ' ++ <str>$var ++ '!';",
    var="lamp")
await client.query(
    "select <datetime>$date;",
    date=datetime.today())

JavaScript​

await client.query("select 'I ❤️ ' ++ <str>$var ++ '!';", {
  name: "rock and roll"
});
await client.query("select <datetime>$date;", {
  date: new Date()
});

Go​

var result string
err = db.QuerySingle(ctx,
  `select 'I ❤️ ' ++ <str>$var ++ '!';"`,
  &result, "Golang")
var date time.Time
err = db.QuerySingle(ctx,
  `select <datetime>$date;`,
  &date, time.Now())

Refer to the Datatypes page of your preferred client library to learn more about mapping between EdgeDB types and language-native types.

Parameter types and JSON​

Parameters can only be scalars or arrays of scalars. This may seem limiting at first, but in actuality this doesn’t impose any practical limitation on what can be parameterized. To pass complex structures as parameters, use EdgeDB’s built-in JSON functionality.

with data := <json>$data
insert User {
  name := <str>data['name'],
  age := <int64>data['age'],
};

Parameter <json>$data: {"name":"Fido", "legs": 4}
{default::Dog {id: 8d286cfe-3c0a-11ec-aa68-3f3076ebd97f}}

Optional parameters​

By default, query parameters are required; the query would fail if parameter value is an empty set. You can use optional modifier inside the type cast if the parameter is optional.

select <optional str>$name;

Parameter <str>$name (Ctrl+D for empty set `{}`):
{}

When using a client library, pass the idiomatic null pointer for your language: null, None, nil, etc.

The <required foo> type cast is also valid (though redundant) syntax.

select <required str>$name;

What can be parametrized?​

Any data manipulation language (DML) statement can be parametrized: select, insert, update, and delete.

Schema definition language (SDL) and configure statements cannot be parametrized. Data definition language (DDL) has limited support for parameters, but it’s not a recommended pattern. Some of the limitations might be lifted in the future versions.