Exception Handling in LLVM

Introduction

This document is the central repository for all information pertaining toexception handling in LLVM. It describes the format that LLVM exceptionhandling information takes, which is useful for those interested in creatingfront-ends or dealing directly with the information. Further, this documentprovides specific examples of what exception handling information is used for inC and C++.

Itanium ABI Zero-cost Exception Handling

Exception handling for most programming languages is designed to recover fromconditions that rarely occur during general use of an application. To that end,exception handling should not interfere with the main flow of an application’salgorithm by performing checkpointing tasks, such as saving the current pc orregister state.

The Itanium ABI Exception Handling Specification defines a methodology forproviding outlying data in the form of exception tables without inliningspeculative exception handling code in the flow of an application’s mainalgorithm. Thus, the specification is said to add “zero-cost” to the normalexecution of an application.

A more complete description of the Itanium ABI exception handling runtimesupport of can be found at Itanium C++ ABI: Exception Handling. A description of theexception frame format can be found at Exception Frames,with details of the DWARF 4 specification at DWARF 4 Standard. A description for the C++ exceptiontable formats can be found at Exception Handling Tables.

Setjmp/Longjmp Exception Handling

Setjmp/Longjmp (SJLJ) based exception handling uses LLVM intrinsicsllvm.eh.sjlj.setjmp and llvm.eh.sjlj.longjmp to handle control flow forexception handling.

For each function which does exception processing — be it try/catchblocks or cleanups — that function registers itself on a global framelist. When exceptions are unwinding, the runtime uses this list to identifywhich functions need processing.

Landing pad selection is encoded in the call site entry of the functioncontext. The runtime returns to the function via llvm.eh.sjlj.longjmp, wherea switch table transfers control to the appropriate landing pad based on theindex stored in the function context.

In contrast to DWARF exception handling, which encodes exception regions andframe information in out-of-line tables, SJLJ exception handling builds andremoves the unwind frame context at runtime. This results in faster exceptionhandling at the expense of slower execution when no exceptions are thrown. Asexceptions are, by their nature, intended for uncommon code paths, DWARFexception handling is generally preferred to SJLJ.

Windows Runtime Exception Handling

LLVM supports handling exceptions produced by the Windows runtime, but itrequires a very different intermediate representation. It is not based on the“landingpad” instruction like the other two models, and isdescribed later in this document under Exception Handling using the Windows Runtime.

Overview

When an exception is thrown in LLVM code, the runtime does its best to find ahandler suited to processing the circumstance.

The runtime first attempts to find an exception frame corresponding to thefunction where the exception was thrown. If the programming language supportsexception handling (e.g. C++), the exception frame contains a reference to anexception table describing how to process the exception. If the language doesnot support exception handling (e.g. C), or if the exception needs to beforwarded to a prior activation, the exception frame contains information abouthow to unwind the current activation and restore the state of the prioractivation. This process is repeated until the exception is handled. If theexception is not handled and no activations remain, then the application isterminated with an appropriate error message.

Because different programming languages have different behaviors when handlingexceptions, the exception handling ABI provides a mechanism forsupplying personalities. An exception handling personality is defined byway of a personality function (e.g. _gxx_personality_v0 in C++),which receives the context of the exception, an _exception structure_containing the exception object type and value, and a reference to the exceptiontable for the current function. The personality function for the currentcompile unit is specified in a _common exception frame.

The organization of an exception table is language dependent. For C++, anexception table is organized as a series of code ranges defining what to do ifan exception occurs in that range. Typically, the information associated with arange defines which types of exception objects (using C++ type info) that arehandled in that range, and an associated action that should take place. Actionstypically pass control to a landing pad.

A landing pad corresponds roughly to the code found in the catch portion ofa try/catch sequence. When execution resumes at a landing pad, itreceives an exception structure and a selector value corresponding to thetype of exception thrown. The selector is then used to determine which _catch_should actually process the exception.

LLVM Code Generation

From a C++ developer’s perspective, exceptions are defined in terms of thethrow and try/catch statements. In this section we will describe theimplementation of LLVM exception handling in terms of C++ examples.

Throw

Languages that support exception handling typically provide a throwoperation to initiate the exception process. Internally, a throw operationbreaks down into two steps.

  • A request is made to allocate exception space for an exception structure.This structure needs to survive beyond the current activation. This structurewill contain the type and value of the object being thrown.
  • A call is made to the runtime to raise the exception, passing the exceptionstructure as an argument.In C++, the allocation of the exception structure is done by thecxa_allocate_exception runtime function. The exception raising is handledby cxa_throw. The type of the exception is represented using a C++ RTTIstructure.

Try/Catch

A call within the scope of a try statement can potentially raise anexception. In those circumstances, the LLVM C++ front-end replaces the call withan invoke instruction. Unlike a call, the invoke has two potentialcontinuation points:

  • where to continue when the call succeeds as per normal, and
  • where to continue if the call raises an exception, either by a throw or theunwinding of a throwThe term used to define the place where an invoke continues after anexception is called a landing pad. LLVM landing pads are conceptuallyalternative function entry points where an exception structure reference and atype info index are passed in as arguments. The landing pad saves the exceptionstructure reference and then proceeds to select the catch block that correspondsto the type info of the exception object.

The LLVM ‘landingpad’ Instruction is used to convey information about the landingpad to the back end. For C++, the landingpad instruction returns a pointerand integer pair corresponding to the pointer to the exception structure andthe selector value respectively.

The landingpad instruction looks for a reference to the personalityfunction to be used for this try/catch sequence in the parentfunction’s attribute list. The instruction contains a list of cleanup,catch, and filter clauses. The exception is tested against the clausessequentially from first to last. The clauses have the following meanings:

  • catch <type> @ExcType

    • This clause means that the landingpad block should be entered if theexception being thrown is of type @ExcType or a subtype of@ExcType. For C++, @ExcType is a pointer to the std::type_infoobject (an RTTI object) representing the C++ exception type.
    • If @ExcType is null, any exception matches, so the landingpadshould always be entered. This is used for C++ catch-all blocks (“catch(…)”).
    • When this clause is matched, the selector value will be equal to the valuereturned by “@llvm.eh.typeid.for(i8* @ExcType)”. This will always be apositive value.

  • filter <type> [<type> @ExcType1, …, <type> @ExcTypeN]

    • This clause means that the landingpad should be entered if the exceptionbeing thrown does not match any of the types in the list (which, for C++,are again specified as std::type_info pointers).
    • C++ front-ends use this to implement C++ exception specifications, such as“void foo() throw (ExcType1, …, ExcTypeN) { … }”.
    • When this clause is matched, the selector value will be negative.
    • The array argument to filter may be empty; for example, “[0 x i8*]undef”. This means that the landingpad should always be entered. (Notethat such a filter would not be equivalent to “catch i8 null”,because filter and catch produce negative and positive selectorvalues respectively.)

  • cleanup

    • This clause means that the landingpad should always be entered.

    • C++ front-ends use this for calling objects’ destructors.

    • When this clause is matched, the selector value will be zero.

    • The runtime may treat “cleanup” differently from “catch <type>null”.

In C++, if an unhandled exception occurs, the language runtime will callstd::terminate(), but it is implementation-defined whether the runtimeunwinds the stack and calls object destructors first. For example, the GNUC++ unwinder does not call object destructors when an unhandled exceptionoccurs. The reason for this is to improve debuggability: it ensures thatstd::terminate() is called from the context of the throw, so thatthis context is not lost by unwinding the stack. A runtime will typicallyimplement this by searching for a matching non-cleanup clause, andaborting if it does not find one, before entering any landingpad blocks.

Once the landing pad has the type info selector, the code branches to the codefor the first catch. The catch then checks the value of the type info selectoragainst the index of type info for that catch. Since the type info index is notknown until all the type infos have been gathered in the backend, the catch codemust call the llvm.eh.typeid.for intrinsic to determine the index for a giventype info. If the catch fails to match the selector then control is passed on tothe next catch.

Finally, the entry and exit of catch code is bracketed with calls tocxa_begin_catch and cxa_end_catch.

  • __cxa_begin_catch takes an exception structure reference as an argumentand returns the value of the exception object.

  • __cxa_end_catch takes no arguments. This function:

    • Locates the most recently caught exception and decrements its handlercount,
    • Removes the exception from the caught stack if the handler count goes tozero, and
    • Destroys the exception if the handler count goes to zero and the exceptionwas not re-thrown by throw.

Note

a rethrow from within the catch may replace this call with a__cxa_rethrow.

Cleanups

A cleanup is extra code which needs to be run as part of unwinding a scope. C++destructors are a typical example, but other languages and language extensionsprovide a variety of different kinds of cleanups. In general, a landing pad mayneed to run arbitrary amounts of cleanup code before actually entering a catchblock. To indicate the presence of cleanups, a ‘landingpad’ Instruction should havea cleanup clause. Otherwise, the unwinder will not stop at the landing pad ifthere are no catches or filters that require it to.

Note

Do not allow a new exception to propagate out of the execution of acleanup. This can corrupt the internal state of the unwinder. Differentlanguages describe different high-level semantics for these situations: forexample, C++ requires that the process be terminated, whereas Ada cancels bothexceptions and throws a third.

When all cleanups are finished, if the exception is not handled by the currentfunction, resume unwinding by calling the resume instruction,passing in the result of the landingpad instruction for the originallanding pad.

Throw Filters

C++ allows the specification of which exception types may be thrown from afunction. To represent this, a top level landing pad may exist to filter outinvalid types. To express this in LLVM code the ‘landingpad’ Instruction will have afilter clause. The clause consists of an array of type infos.landingpad will return a negative valueif the exception does not match any of the type infos. If no match is found thena call to __cxa_call_unexpected should be made, otherwise_Unwind_Resume. Each of these functions requires a reference to theexception structure. Note that the most general form of a landingpadinstruction can have any number of catch, cleanup, and filter clauses (thoughhaving more than one cleanup is pointless). The LLVM C++ front-end can generatesuch landingpad instructions due to inlining creating nested exceptionhandling scopes.

Restrictions

The unwinder delegates the decision of whether to stop in a call frame to thatcall frame’s language-specific personality function. Not all unwinders guaranteethat they will stop to perform cleanups. For example, the GNU C++ unwinderdoesn’t do so unless the exception is actually caught somewhere further up thestack.

In order for inlining to behave correctly, landing pads must be prepared tohandle selector results that they did not originally advertise. Suppose that afunction catches exceptions of type A, and it’s inlined into a function thatcatches exceptions of type B. The inliner will update the landingpadinstruction for the inlined landing pad to include the fact that B is alsocaught. If that landing pad assumes that it will only be entered to catch anA, it’s in for a rude awakening. Consequently, landing pads must test forthe selector results they understand and then resume exception propagation withthe resume instruction if none of the conditionsmatch.

Exception Handling Intrinsics

In addition to the landingpad and resume instructions, LLVM uses severalintrinsic functions (name prefixed with llvm.eh) to provide exceptionhandling information at various points in generated code.

llvm.eh.typeid.for

  1. i32 @llvm.eh.typeid.for(i8* %type_info)

This intrinsic returns the type info index in the exception table of the currentfunction. This value can be used to compare against the result oflandingpad instruction. The single argument is a reference to a type info.

Uses of this intrinsic are generated by the C++ front-end.

llvm.eh.begincatch

  1. void @llvm.eh.begincatch(i8* %ehptr, i8* %ehobj)

This intrinsic marks the beginning of catch handling code within the blocksfollowing a landingpad instruction. The exact behavior of this functiondepends on the compilation target and the personality function associatedwith the landingpad instruction.

The first argument to this intrinsic is a pointer that was previously extractedfrom the aggregate return value of the landingpad instruction. The secondargument to the intrinsic is a pointer to stack space where the exception objectshould be stored. The runtime handles the details of copying the exceptionobject into the slot. If the second parameter is null, no copy occurs.

Uses of this intrinsic are generated by the C++ front-end. Many targets willuse implementation-specific functions (such as __cxa_begin_catch) insteadof this intrinsic. The intrinsic is provided for targets that require a moreabstract interface.

When used in the native Windows C++ exception handling implementation, thisintrinsic serves as a placeholder to delimit code before a catch handler isoutlined. When the handler is outlined, this intrinsic will be replacedby instructions that retrieve the exception object pointer from the frameallocation block.

llvm.eh.endcatch

  1. void @llvm.eh.endcatch()

This intrinsic marks the end of catch handling code within the current block,which will be a successor of a block which called llvm.eh.begincatch''.The exact behavior of this function depends on the compilation target and thepersonality function associated with the corresponding ``landingpadinstruction.

There may be more than one call to llvm.eh.endcatch for any given call tollvm.eh.begincatch with each llvm.eh.endcatch call corresponding to theend of a different control path. All control paths following a call tollvm.eh.begincatch must reach a call to llvm.eh.endcatch.

Uses of this intrinsic are generated by the C++ front-end. Many targets willuse implementation-specific functions (such as __cxa_begin_catch) insteadof this intrinsic. The intrinsic is provided for targets that require a moreabstract interface.

When used in the native Windows C++ exception handling implementation, thisintrinsic serves as a placeholder to delimit code before a catch handler isoutlined. After the handler is outlined, this intrinsic is simply removed.

llvm.eh.exceptionpointer

  1. i8 addrspace(N)* @llvm.eh.padparam.pNi8(token %catchpad)

This intrinsic retrieves a pointer to the exception caught by the givencatchpad.

SJLJ Intrinsics

The llvm.eh.sjlj intrinsics are used internally within LLVM’sbackend. Uses of them are generated by the backend’sSjLjEHPrepare pass.

llvm.eh.sjlj.setjmp

  1. i32 @llvm.eh.sjlj.setjmp(i8* %setjmp_buf)

For SJLJ based exception handling, this intrinsic forces register saving for thecurrent function and stores the address of the following instruction for use asa destination address by llvm.eh.sjlj.longjmp. The buffer format and theoverall functioning of this intrinsic is compatible with the GCC__builtin_setjmp implementation allowing code built with the clang and GCCto interoperate.

The single parameter is a pointer to a five word buffer in which the callingcontext is saved. The front end places the frame pointer in the first word, andthe target implementation of this intrinsic should place the destination addressfor a llvm.eh.sjlj.longjmp in the second word. The following three words areavailable for use in a target-specific manner.

llvm.eh.sjlj.longjmp

  1. void @llvm.eh.sjlj.longjmp(i8* %setjmp_buf)

For SJLJ based exception handling, the llvm.eh.sjlj.longjmp intrinsic isused to implement __builtin_longjmp(). The single parameter is a pointer toa buffer populated by llvm.eh.sjlj.setjmp. The frame pointer and stackpointer are restored from the buffer, then control is transferred to thedestination address.

llvm.eh.sjlj.lsda

  1. i8* @llvm.eh.sjlj.lsda()

For SJLJ based exception handling, the llvm.eh.sjlj.lsda intrinsic returnsthe address of the Language Specific Data Area (LSDA) for the currentfunction. The SJLJ front-end code stores this address in the exception handlingfunction context for use by the runtime.

llvm.eh.sjlj.callsite

  1. void @llvm.eh.sjlj.callsite(i32 %call_site_num)

For SJLJ based exception handling, the llvm.eh.sjlj.callsite intrinsicidentifies the callsite value associated with the following invokeinstruction. This is used to ensure that landing pad entries in the LSDA aregenerated in matching order.

Asm Table Formats

There are two tables that are used by the exception handling runtime todetermine which actions should be taken when an exception is thrown.

Exception Handling Frame

An exception handling frame eh_frame is very similar to the unwind frameused by DWARF debug info. The frame contains all the information necessary totear down the current frame and restore the state of the prior frame. There isan exception handling frame for each function in a compile unit, plus a commonexception handling frame that defines information common to all functions in theunit.

The format of this call frame information (CFI) is often platform-dependent,however. ARM, for example, defines their own format. Apple has their own compactunwind info format. On Windows, another format is used for all architecturessince 32-bit x86. LLVM will emit whatever information is required by thetarget.

Exception Tables

An exception table contains information about what actions to take when anexception is thrown in a particular part of a function’s code. This is typicallyreferred to as the language-specific data area (LSDA). The format of the LSDAtable is specific to the personality function, but the majority of personalitiesout there use a variation of the tables consumed by __gxx_personality_v0.There is one exception table per function, except leaf functions and functionsthat have calls only to non-throwing functions. They do not need an exceptiontable.

Exception Handling using the Windows Runtime

Background on Windows exceptions

Interacting with exceptions on Windows is significantly more complicated thanon Itanium C++ ABI platforms. The fundamental difference between the two modelsis that Itanium EH is designed around the idea of “successive unwinding,” whileWindows EH is not.

Under Itanium, throwing an exception typically involes allocating thread localmemory to hold the exception, and calling into the EH runtime. The runtimeidentifies frames with appropriate exception handling actions, and successivelyresets the register context of the current thread to the most recently activeframe with actions to run. In LLVM, execution resumes at a landingpadinstruction, which produces register values provided by the runtime. If afunction is only cleaning up allocated resources, the function is responsiblefor calling _Unwind_Resume to transition to the next most recently activeframe after it is finished cleaning up. Eventually, the frame responsible forhandling the exception calls __cxa_end_catch to destroy the exception,release its memory, and resume normal control flow.

The Windows EH model does not use these successive register context resets.Instead, the active exception is typically described by a frame on the stack.In the case of C++ exceptions, the exception object is allocated in stack memoryand its address is passed to CxxThrowException. General purpose structuredexceptions (SEH) are more analogous to Linux signals, and they are dispatched byuserspace DLLs provided with Windows. Each frame on the stack has an assigned EHpersonality routine, which decides what actions to take to handle the exception.There are a few major personalities for C and C++ code: the C++ personality(CxxFrameHandler3) and the SEH personalities (_except_handler3,_except_handler4, and __C_specific_handler). All of them implementcleanups by calling back into a “funclet” contained in the parent function.

Funclets, in this context, are regions of the parent function that can be calledas though they were a function pointer with a very special calling convention.The frame pointer of the parent frame is passed into the funclet either usingthe standard EBP register or as the first parameter register, depending on thearchitecture. The funclet implements the EH action by accessing local variablesin memory through the frame pointer, and returning some appropriate value,continuing the EH process. No variables live in to or out of the funclet can beallocated in registers.

The C++ personality also uses funclets to contain the code for catch blocks(i.e. all user code between the braces in catch (Type obj) { … }). Theruntime must use funclets for catch bodies because the C++ exception object isallocated in a child stack frame of the function handling the exception. If theruntime rewound the stack back to frame of the catch, the memory holding theexception would be overwritten quickly by subsequent function calls. The use offunclets also allows CxxFrameHandler3 to implement rethrow withoutresorting to TLS. Instead, the runtime throws a special exception, and then usesSEH (try / __except) to resume execution with new information in the childframe.

In other words, the successive unwinding approach is incompatible with VisualC++ exceptions and general purpose Windows exception handling. Because the C++exception object lives in stack memory, LLVM cannot provide a custom personalityfunction that uses landingpads. Similarly, SEH does not provide any mechanismto rethrow an exception or continue unwinding. Therefore, LLVM must use the IRconstructs described later in this document to implement compatible exceptionhandling.

SEH filter expressions

The SEH personality functions also use funclets to implement filter expressions,which allow executing arbitrary user code to decide which exceptions to catch.Filter expressions should not be confused with the filter clause of the LLVMlandingpad instruction. Typically filter expressions are used to determineif the exception came from a particular DLL or code region, or if code faultedwhile accessing a particular memory address range. LLVM does not currently haveIR to represent filter expressions because it is difficult to represent theircontrol dependencies. Filter expressions run during the first phase of EH,before cleanups run, making it very difficult to build a faithful control flowgraph. For now, the new EH instructions cannot represent SEH filterexpressions, and frontends must outline them ahead of time. Local variables ofthe parent function can be escaped and accessed using the llvm.localescapeand llvm.localrecover intrinsics.

New exception handling instructions

The primary design goal of the new EH instructions is to support funcletgeneration while preserving information about the CFG so that SSA formationstill works. As a secondary goal, they are designed to be generic across MSVCand Itanium C++ exceptions. They make very few assumptions about the datarequired by the personality, so long as it uses the familiar core EH actions:catch, cleanup, and terminate. However, the new instructions are hard to modifywithout knowing details of the EH personality. While they can be used torepresent Itanium EH, the landingpad model is strictly better for optimizationpurposes.

The following new instructions are considered “exception handling pads”, in thatthey must be the first non-phi instruction of a basic block that may be theunwind destination of an EH flow edge:catchswitch, catchpad, and cleanuppad.As with landingpads, when entering a try scope, if thefrontend encounters a call site that may throw an exception, it should emit aninvoke that unwinds to a catchswitch block. Similarly, inside the scope of aC++ object with a destructor, invokes should unwind to a cleanuppad.

New instructions are also used to mark the points where control is transferredout of a catch/cleanup handler (which will correspond to exits from thegenerated funclet). A catch handler which reaches its end by normal executionexecutes a catchret instruction, which is a terminator indicating where inthe function control is returned to. A cleanup handler which reaches its endby normal execution executes a cleanupret instruction, which is a terminatorindicating where the active exception will unwind to next.

Each of these new EH pad instructions has a way to identify which action shouldbe considered after this action. The catchswitch instruction is a terminatorand has an unwind destination operand analogous to the unwind destination of aninvoke. The cleanuppad instruction is nota terminator, so the unwind destination is stored on the cleanupretinstruction instead. Successfully executing a catch handler should resumenormal control flow, so neither catchpad nor catchret instructions canunwind. All of these “unwind edges” may refer to a basic block that contains anEH pad instruction, or they may unwind to the caller. Unwinding to the callerhas roughly the same semantics as the resume instruction in the landingpadmodel. When inlining through an invoke, instructions that unwind to the callerare hooked up to unwind to the unwind destination of the call site.

Putting things together, here is a hypothetical lowering of some C++ that usesall of the new IR instructions:

  1. struct Cleanup {
  2.   Cleanup();
  3.   ~Cleanup();
  4.   int m;
  5. };
  6. void may_throw();
  7. int f() noexcept {
  8.   try {
  9.     Cleanup obj;
  10.     may_throw();
  11.   } catch (int e) {
  12.     may_throw();
  13.     return e;
  14.   }
  15.   return 0;
  16. }
  1. define i32 @f() nounwind personality i32 (...)* @__CxxFrameHandler3 {
  2. entry:
  3.   %obj = alloca %struct.Cleanup, align 4
  4.   %e = alloca i32, align 4
  5.   %call = invoke %struct.Cleanup* @"??0Cleanup@@QEAA@XZ"(%struct.Cleanup* nonnull %obj)
  6.           to label %invoke.cont unwind label %lpad.catch
  7.  
  8. invoke.cont:                                      ; preds = %entry
  9.   invoke void @"?may_throw@@YAXXZ"()
  10.           to label %invoke.cont.2 unwind label %lpad.cleanup
  11.  
  12. invoke.cont.2:                                    ; preds = %invoke.cont
  13.   call void @"??_DCleanup@@QEAA@XZ"(%struct.Cleanup* nonnull %obj) nounwind
  14.   br label %return
  15.  
  16. return:                                           ; preds = %invoke.cont.3, %invoke.cont.2
  17.   %retval.0 = phi i32 [ 0, %invoke.cont.2 ], [ %3, %invoke.cont.3 ]
  18.   ret i32 %retval.0
  19.  
  20. lpad.cleanup:                                     ; preds = %invoke.cont.2
  21.   %0 = cleanuppad within none []
  22.   call void @"??1Cleanup@@QEAA@XZ"(%struct.Cleanup* nonnull %obj) nounwind
  23.   cleanupret %0 unwind label %lpad.catch
  24.  
  25. lpad.catch:                                       ; preds = %lpad.cleanup, %entry
  26.   %1 = catchswitch within none [label %catch.body] unwind label %lpad.terminate
  27.  
  28. catch.body:                                       ; preds = %lpad.catch
  29.   %catch = catchpad within %1 [%rtti.TypeDescriptor2* @"??_R0H@8", i32 0, i32* %e]
  30.   invoke void @"?may_throw@@YAXXZ"()
  31.           to label %invoke.cont.3 unwind label %lpad.terminate
  32.  
  33. invoke.cont.3:                                    ; preds = %catch.body
  34.   %3 = load i32, i32* %e, align 4
  35.   catchret from %catch to label %return
  36.  
  37. lpad.terminate:                                   ; preds = %catch.body, %lpad.catch
  38.   cleanuppad within none []
  39.   call void @"?terminate@@YAXXZ"
  40.   unreachable
  41. }

Funclet parent tokens

In order to produce tables for EH personalities that use funclets, it isnecessary to recover the nesting that was present in the source. This funcletparent relationship is encoded in the IR using tokens produced by the new “pad”instructions. The token operand of a “pad” or “ret” instruction indicates whichfunclet it is in, or “none” if it is not nested within another funclet.

The catchpad and cleanuppad instructions establish new funclets, andtheir tokens are consumed by other “pad” instructions to establish membership.The catchswitch instruction does not create a funclet, but it produces atoken that is always consumed by its immediate successor catchpadinstructions. This ensures that every catch handler modelled by a catchpadbelongs to exactly one catchswitch, which models the dispatch point after aC++ try.

Here is an example of what this nesting looks like using some hypotheticalC++ code:

  1. void f() {
  2.   try {
  3.     throw;
  4.   } catch (...) {
  5.     try {
  6.       throw;
  7.     } catch (...) {
  8.     }
  9.   }
  10. }
  1. define void @f() #0 personality i8* bitcast (i32 (...)* @__CxxFrameHandler3 to i8*) {
  2. entry:
  3.   invoke void @_CxxThrowException(i8* null, %eh.ThrowInfo* null) #1
  4.           to label %unreachable unwind label %catch.dispatch
  5.  
  6. catch.dispatch:                                   ; preds = %entry
  7.   %0 = catchswitch within none [label %catch] unwind to caller
  8.  
  9. catch:                                            ; preds = %catch.dispatch
  10.   %1 = catchpad within %0 [i8* null, i32 64, i8* null]
  11.   invoke void @_CxxThrowException(i8* null, %eh.ThrowInfo* null) #1
  12.           to label %unreachable unwind label %catch.dispatch2
  13.  
  14. catch.dispatch2:                                  ; preds = %catch
  15.   %2 = catchswitch within %1 [label %catch3] unwind to caller
  16.  
  17. catch3:                                           ; preds = %catch.dispatch2
  18.   %3 = catchpad within %2 [i8* null, i32 64, i8* null]
  19.   catchret from %3 to label %try.cont
  20.  
  21. try.cont:                                         ; preds = %catch3
  22.   catchret from %1 to label %try.cont6
  23.  
  24. try.cont6:                                        ; preds = %try.cont
  25.   ret void
  26.  
  27. unreachable:                                      ; preds = %catch, %entry
  28.   unreachable
  29. }

The “inner” catchswitch consumes %1 which is produced by the outercatchswitch.

Funclet transitions

The EH tables for personalities that use funclets make implicit use of thefunclet nesting relationship to encode unwind destinations, and so areconstrained in the set of funclet transitions they can represent. The relatedLLVM IR instructions accordingly have constraints that ensure encodability ofthe EH edges in the flow graph.

A catchswitch, catchpad, or cleanuppad is said to be “entered”when it executes. It may subsequently be “exited” by any of the followingmeans:

  • A catchswitch is immediately exited when none of its constituentcatchpads are appropriate for the in-flight exception and it unwindsto its unwind destination or the caller.
  • A catchpad and its parent catchswitch are both exited when acatchret from the catchpad is executed.
  • A cleanuppad is exited when a cleanupret from it is executed.
  • Any of these pads is exited when control unwinds to the function’s caller,either by a call which unwinds all the way to the function’s caller,a nested catchswitch marked “unwinds to caller”, or a nestedcleanuppad’s cleanupret marked “unwinds to caller".
  • Any of these pads is exited when an unwind edge (from an invoke,nested catchswitch, or nested cleanuppad’s cleanupret)unwinds to a destination pad that is not a descendant of the given pad.

Note that the ret instruction is not a valid way to exit a funclet pad;it is undefined behavior to execute a ret when a pad has been entered butnot exited.

A single unwind edge may exit any number of pads (with the restrictions thatthe edge from a catchswitch must exit at least itself, and the edge froma cleanupret must exit at least its cleanuppad), and then must enterexactly one pad, which must be distinct from all the exited pads. The parentof the pad that an unwind edge enters must be the most-recently-enterednot-yet-exited pad (after exiting from any pads that the unwind edge exits),or “none” if there is no such pad. This ensures that the stack of executingfunclets at run-time always corresponds to some path in the funclet pad treethat the parent tokens encode.

All unwind edges which exit any given funclet pad (including cleanupretedges exiting their cleanuppad and catchswitch edges exiting theircatchswitch) must share the same unwind destination. Similarly, anyfunclet pad which may be exited by unwind to caller must not be exited byany exception edges which unwind anywhere other than the caller. Thisensures that each funclet as a whole has only one unwind destination, whichEH tables for funclet personalities may require. Note that any unwind edgewhich exits a catchpad also exits its parent catchswitch, so thisimplies that for any given catchswitch, its unwind destination must alsobe the unwind destination of any unwind edge that exits any of its constituentcatchpads. Because catchswitch has no nounwind variant, andbecause IR producers are not required to annotate calls which will notunwind as nounwind, it is legal to nest a call or an “unwind tocaller” catchswitch within a funclet pad that has an unwinddestination other than caller; it is undefined behavior for such a callor catchswitch to unwind.

Finally, the funclet pads’ unwind destinations cannot form a cycle. Thisensures that EH lowering can construct “try regions” with a tree-likestructure, which funclet-based personalities may require.

Exception Handling support on the target

In order to support exception handling on particular target, there are a fewitems need to be implemented.

  • CFI directives

First, you have to assign each target register with a unique DWARF number.Then in TargetFrameLowering’s emitPrologue, you have to emit CFIdirectivesto specify how to calculate the CFA (Canonical Frame Address) and how registeris restored from the address pointed by the CFA with an offset. The assembleris instructed by CFI directives to build .eh_frame section, which is usedby th unwinder to unwind stack during exception handling.

  • getExceptionPointerRegister and getExceptionSelectorRegister

TargetLowering must implement both functions. The personality function_passes the _exception structure (a pointer) and selector value (an integer)to the landing pad through the registers specified by getExceptionPointerRegisterand getExceptionSelectorRegister respectively. On most platforms, theywill be GPRs and will be the same as the ones specified in the calling convention.

  • EH_RETURN

The ISD node represents the undocumented GCC extension builtin_eh_return (offset, handler),which adjusts the stack by offset and then jumps to the handler. builtin_eh_returnis used in GCC unwinder (libgcc),but not in LLVM unwinder (libunwind).If you are on the top of libgcc and have particular requirement on your target,you have to handle EH_RETURN in TargetLowering.

If you don’t leverage the existing runtime (libstdc++ and libgcc),you have to take a look on libc++ andlibunwindto see what have to be done there. For libunwind, you have to do the following

  • __libunwind_config.h

Define macros for your target.

  • include/libunwind.h

Define enum for the target registers.

  • src/Registers.hpp

Define Registers class for your target, implement setter and getter functions.

  • src/UnwindCursor.hpp

Define dwarfEncoding and stepWithCompactEncoding for your Registersclass.

  • src/UnwindRegistersRestore.S

Write an assembly function to restore all your target registers from the memory.

  • src/UnwindRegistersSave.S

Write an assembly function to save all your target registers on the memory.