Using Signals

In this lesson, we will look at signals. They are messages that nodes emit when something specific happens to them, like a button being pressed. Other nodes can connect to that signal and call a function when the event occurs.

It is a delegation mechanism built into Godot that allows one game object to react to a change in another without them referencing one another. Using signals limits coupling) and keeps your code flexible.

For example, you might have a life bar on the screen that represents the player’s health. When the player takes damage or uses a healing potion, you want the bar to reflect the change. To do so, in Godot, you would use signals.

注解

As mentioned in the introduction, signals are Godot’s version of the observer pattern. You can learn more about it here: https://gameprogrammingpatterns.com/observer.html

We will now use a signal to make our Godot icon from last part move and stop by pressing a button.

场景设置

Create a new scene by going to the menu Scene -> New Scene.

../../_images/signals_01_new_scene.png

In the Scene dock, click the 2D Scene button. This will add a Node2D as our root.

../../_images/signals_02_2d_scene.png

In the FileSystem dock, click and drag the Sprite2D.tscn file you saved previously onto the Node2D to instantiate it.

../../_images/signals_03_dragging_scene.png

We want to add another node as a sibling of the Sprite2D. To do so, right-click on Node2D and select Add Child Node.

../../_images/signals_04_add_child_node.png

Search for the Button node type and add it.

../../_images/signals_05_add_button.png

The node is small by default. Click and drag on the bottom-right handle of the Button in the viewport to resize it.

../../_images/signals_06_drag_button.png

If you don’t see the handles, ensure the select tool is active in the toolbar.

../../_images/signals_07_select_tool.png

Click and drag on the button itself to move it closer to the sprite.

You can also write a label on the Button by editing its Text property in the Inspector.

../../_images/signals_08_toggle_motion_text.png

Your scene tree and viewport should look like this.

../../_images/signals_09_scene_setup.png

Connecting a signal in the editor

Here, we want to connect the Button’s “pressed” signal to our Sprite2D, and we want to call a new function that will toggle its motion on and off. We need to have a script attached to the Sprite2D node, which we do from the previous lesson.

You can connect signals in the Node dock. Select the Button node and, on the right side of the editor, click on the tab named “Node” next to the Inspector.

../../_images/signals_10_node_dock.png

The dock displays a list of signals available on the selected node.

../../_images/signals_11_pressed_signals.png

Double-click the “pressed” signal to open the node connection window.

../../_images/signals_12_node_connection.png

There, you can connect the signal to the Sprite2D node. The node needs a receiver method, a function that Godot will call when the Button emits the signal. The editor generates one for you. By convention, we name these callback methods “_on_NodeName_signal_name”. Here, it’ll be “_on_Button_pressed”.

注解

When connecting signals via the editor’s Node dock, you can use two modes. The simple one only allows you to connect to nodes that have a script attached to them and creates a new callback function on them.

../../_images/signals_advanced_connection_window.png

The advanced view lets you connect to any node and any built-in function, add arguments to the callback, and set options. You can toggle the mode in the window’s bottom-right by clicking the radio button.

Click the connect button to complete the signal connection and jump to the Script workspace. You should see the new method with a connection icon in the left margin.

../../_images/signals_13_signals_connection_icon.png

If you click the icon, a window pops up and displays information about the connection. This feature is only available when connecting nodes in the editor.

../../_images/signals_14_signals_connection_info.png

Let’s replace the line with the pass keyword with code that’ll toggle the node’s motion.

Our Sprite2D moves thanks to code in the _process() function. Godot provides a method to toggle processing on and off: Node.set_process(). Another method of the Node class, is_processing(), returns true if idle processing is active. We can use the not keyword to invert the value.

GDScript

  1. func _on_Button_pressed():
  2.     set_process(not is_processing())

This function will toggle processing and, in turn, the icon’s motion on and off upon pressing the button.

Before trying the game, we need to simplify our _process() function to move the node automatically and not wait for user input. Replace it with the following code, which we saw two lessons ago:

GDScript

  1. func _process(delta: float) -> void:
  2.     rotation += angular_speed * delta
  3.     var velocity = Vector2.UP.rotated(rotation) * speed
  4.     position += velocity * delta

Your complete Sprite2D.gd code should look like the following.

GDScript

  1. extends Sprite2D
  3. var speed = 400
  4. var angular_speed = PI
  6. func _process(delta: float) -> void:
  7.     rotation += angular_speed * delta
  8.     var velocity = Vector2.UP.rotated(rotation) * speed
  9.     position += velocity * delta
  11. func _on_Button_pressed():
  12.     set_process(not is_processing())

Run the scene now and click the button to see the sprite start and stop.

Connecting a signal via code

You can connect signals via code instead of using the editor. This is necessary when you create nodes or instantiate scenes inside of a script.

Let’s use a different node here. Godot has a Timer node that’s useful to implement skill cooldown times, weapon reloading, and more.

Head back to the 2D workspace. You can either click the “2D” text at the top of the window or press Ctrl + F2 (Alt + 2 on macOS).

In the Scene dock, right-click on the Sprite2D node and add a new node. Search for Timer and add the corresponding node. Your scene should now look like this.

../../_images/signals_15_scene_tree.png

With the Timer node selected, go to the Inspector and check the Autostart property.

../../_images/signals_18_timer_autostart.png

Click the script icon next to Sprite2D to jump back to the scripting workspace.

../../_images/signals_16_click_script.png

We need to do two operations to connect the nodes via code:

  1. Get a reference to the Timer from the Sprite2D.

  2. Call the Timer’s connect() method.

注解

To connect to a signal via code, you need to call the connect() method of the node you want to listen to. In this case, we want to listen to the Timer’s “timeout” signal.

To get a reference to a node relative to the current one, we use the method Node.get_node(). We can store the reference in a variable.

GDScript

  1. extends Sprite2D
  3. #...
  5. func _ready():
  6.     var timer = get_node("Timer")

The function get_node() looks at the Sprite2D’s children and gets nodes by their name. For example, if you renamed the Timer node to “BlinkingTimer” in the editor, you would have to change the call to get_node("BlinkingTimer").

We can now connect the Timer to the Sprite2D in the _ready() function.

GDScript

  1. func _ready():
  2.     var timer = get_node("Timer")
  3.     timer.connect("timeout", self, "_on_Timer_timeout")

The line reads like so: we connect the Timer’s “timeout” signal to the node to which the script is attached (self). When the Timer emits “timeout”, we want to call the function “_on_Timer_timeout”, that we need to define. Let’s add it at the bottom of our script and use it to toggle our sprite’s visibility.

GDScript

  1. func _on_Timer_timeout():
  2.     visible = not visible

The visible property is a boolean that controls the visibility of our node. The line visible = not visible toggles the value. If visible is true, it becomes false, and vice-versa.

自定义信号

You can define custom signals in a script. Say, for example, that you want to show a game over screen when the player’s health reaches zero. To do so, you could define a signal named “died” or “health_depleted” when their health reaches 0.

GDScript

  1. extends Node2D
  3. signal health_depleted
  5. var health = 10

注解

As signals represent events that just occurred, we generally use an action verb in the past tense in their names.

Your signals work the same way as built-in ones: they appear in the Node tab and you can connect to them like any other.

../../_images/signals_17_custom_signal.png

To emit a signal in your scripts, call emit_signal().

GDScript

  1. func take_damage(amount):
  2.     health -= amount
  3.     if health <= 0:
  4.         emit_signal("health_depleted")

A signal can optionally declare one or more arguments. Specify the argument names between parentheses:

GDScript

  1. extends Node
  3. signal health_changed(old_value, new_value)

注解

这些信号参数显示在编辑器的节点停靠面板中,Godot可以使用它们为您生成回调函数. 但是, 发出信号时仍然可以发出任意数量的参数；所以由你来决定是否发出正确的值.

To emit values along with the signal, add them as extra arguments to the emit_signal() function:

GDScript

  1. func take_damage(amount):
  2.     var old_health = health
  3.     health -= amount
  4.     emit_signal("health_changed", old_health, health)

总结

Any node in Godot emits signals when something specific happens to them, like a button being pressed. Other nodes can connect to individual signals and react to selected events.

Signals have many uses. With them, you can react to a node entering or exiting the game world, to a collision, to a character entering or leaving an area, to an element of the interface changing size, and much more.

For example, an Area2D representing a coin emits a body_entered signal whenever the player’s physics body enters its collision shape, allowing you to know when the player collected it.

In the next section, Your first 2D game, you’ll create a complete 2D game and put everything you learned so far into practice.