HTTP客户端类

HTTPClient provides low-level access to HTTP communication. For a higher-level interface, you may want to take a look at HTTPRequest first, which has a tutorial available here.

这是使用 HTTPClient 类的示例。 它只是一个脚本，因此它可以通过执行以下命令来运行:

  1. c:\godot> godot -s http_test.gd

它将连接并获取一个网站。

  1. extends SceneTree
  3. # HTTPClient demo
  4. # This simple class can do HTTP requests; it will not block, but it needs to be polled.
  6. func _init():
  7.     var err = 0
  8.     var http = HTTPClient.new() # Create the Client.
  10.     err = http.connect_to_host("www.php.net", 80) # Connect to host/port.
  11.     assert(err == OK) # Make sure connection was OK.
  13.     # Wait until resolved and connected.
  14.     while http.get_status() == HTTPClient.STATUS_CONNECTING or http.get_status() == HTTPClient.STATUS_RESOLVING:
  15.         http.poll()
  16.         print("Connecting...")
  17.         OS.delay_msec(500)
  19.     assert(http.get_status() == HTTPClient.STATUS_CONNECTED) # Could not connect
  21.     # Some headers
  22.     var headers = [
  23.         "User-Agent: Pirulo/1.0 (Godot)",
  24.         "Accept: */*"
  25.     ]
  27.     err = http.request(HTTPClient.METHOD_GET, "/ChangeLog-5.php", headers) # Request a page from the site (this one was chunked..)
  28.     assert(err == OK) # Make sure all is OK.
  30.     while http.get_status() == HTTPClient.STATUS_REQUESTING:
  31.         # Keep polling for as long as the request is being processed.
  32.         http.poll()
  33.         print("Requesting...")
  34.         if not OS.has_feature("web"):
  35.             OS.delay_msec(500)
  36.         else:
  37.             # Synchronous HTTP requests are not supported on the web,
  38.             # so wait for the next main loop iteration.
  39.             yield(Engine.get_main_loop(), "idle_frame")
  41.     assert(http.get_status() == HTTPClient.STATUS_BODY or http.get_status() == HTTPClient.STATUS_CONNECTED) # Make sure request finished well.
  43.     print("response? ", http.has_response()) # Site might not have a response.
  45.     if http.has_response():
  46.         # If there is a response...
  48.         headers = http.get_response_headers_as_dictionary() # Get response headers.
  49.         print("code: ", http.get_response_code()) # Show response code.
  50.         print("**headers:\\n", headers) # Show headers.
  52.         # Getting the HTTP Body
  54.         if http.is_response_chunked():
  55.             # Does it use chunks?
  56.             print("Response is Chunked!")
  57.         else:
  58.             # Or just plain Content-Length
  59.             var bl = http.get_response_body_length()
  60.             print("Response Length: ", bl)
  62.         # This method works for both anyway
  64.         var rb = PoolByteArray() # Array that will hold the data.
  66.         while http.get_status() == HTTPClient.STATUS_BODY:
  67.             # While there is body left to be read
  68.             http.poll()
  69.             var chunk = http.read_response_body_chunk() # Get a chunk.
  70.             if chunk.size() == 0:
  71.                 # Got nothing, wait for buffers to fill a bit.
  72.                 OS.delay_usec(1000)
  73.             else:
  74.                 rb = rb + chunk # Append to read buffer.
  76.         # Done!
  78.         print("bytes got: ", rb.size())
  79.         var text = rb.get_string_from_ascii()
  80.         print("Text: ", text)
  82.     quit()