利用服务器进行优化

Engines like Godot provide increased ease of use thanks to their high level constructs and features. Most of them are accessed and used via the Scene System. Using nodes and resources simplifies project organization and asset management in complex games.

There are, of course, always drawbacks:

  • There is an extra layer of complexity
  • Performance is lower than using simple APIs directly
  • It is not possible to use multiple threads to control them
  • 需要更多的内存。

In many cases, this is not really a problem (Godot is very optimized, and most operations are handled with signals, so no polling is required). Still, sometimes it can be. For example, dealing with tens of thousands of instances for something that needs to be processed every frame can be a bottleneck.

This type of situation makes programmers regret they are using a game engine and wish they could go back to a more handcrafted, low level implementation of game code.

Still, Godot is designed to work around this problem.

Servers

One of the most interesting design decisions for Godot, is the fact that the whole scene system is optional. While it is not currently possible to compile it out, it can be completely bypassed.

At the core, Godot uses the concept of Servers. They are very low level APIs to control rendering, physics, sound, etc. The scene system is built on top of them and uses them directly. The most common servers are:

Just explore their APIs and you will realize that the all functions provided are low-level implementations of everything Godot allows you to do.

RIDs (Resource ID)

The key to using servers is understanding Resource ID (RID) objects. These are opaque handles to the server implementation. They are allocated and freed manually. Almost every function in the servers requires RIDs to access the actual resource.

Most Godot nodes and resources contain these RIDs from the servers internally, and they can be obtained with different functions. In fact, anything that inherits Resource can be directly casted to an RID (not all resources contain an RID, though, in such cases the RID will be empty). In fact, resources can be passed to server APIs as RIDs. Just make sure to keep references to the resources outside the server, because if the resource is erased, the internal RID is erased too.

For nodes, there are many functions available:

  • 对于CanvasItem，：ref：`CanvasItem.get_canvas_item（）<class_CanvasItem_method_get_canvas_item>`方法将在服务器中返回画布项目RID。
  • For CanvasLayer, the CanvasLayer.get_canvas() method will return the canvas RID in the server.
  • For Viewport, the Viewport.get_viewport_rid() method will return the viewport RID in the server.
  • For 3D, the World resource (obtainable in the Viewport and Spatial nodes) contains functions to get the VisualServer Scenario, and the PhysicsServer Space. This allows creating 3D objects directly with the server API and using them.
  • For 2D, the World2D resource (obtainable in the Viewport and CanvasItem nodes) contains functions to get the VisualServer Canvas, and the Physics2DServer Space. This allows creating 2D objects directly with the server API and using them.
  • The VisualInstance class, allows getting the scenario instance and instance base via the VisualInstance.get_instance() and VisualInstance.get_base() respectively.

Just explore the nodes and resources you are familiar with and find the functions to obtain the server RIDs.

It is not advised to control RIDs from objects that already have a node associated. Instead, server functions should always be used for creating and controlling new ones and interacting with the existing ones.

Creating a sprite

This is a simple example of how to create a sprite from code and move it using the low-level CanvasItem API.

GDScript

  1. extends Node2D
  4. # VisualServer expects references to be kept around.
  5. var sprite
  8. func _ready():
  9.     # Create a canvas item, child of this node.
  10.     var ci_rid = VisualServer.canvas_item_create()
  11.     # Make this node the parent.
  12.     VisualServer.canvas_item_set_parent(ci_rid, get_canvas_item())
  13.     # Draw a sprite on it.
  14.     # Remember, keep this reference.
  15.     sprite = load("res://mysprite.png")
  16.     # Add it, centered.
  17.     VisualServer.canvas_item_add_texture_rect(ci_rid, Rect2(sprite.get_size() / 2, sprite.get_size()), sprite)
  18.     # Add the item, rotated 45 degrees and translated.
  19.     var xform = Transform2D().rotated(deg2rad(45)).translated(Vector2(20, 30))
  20.     VisualServer.canvas_item_set_transform(ci_rid, xform)

The Canvas Item API in the server allows you to add draw primitives to it. Once added, they can’t be modified. The Item needs to be cleared and the primitives re-added (this is not the case for setting the transform, which can be done as many times as desired).

Primitives are cleared this way:

GDScript

  1. VisualServer.canvas_item_clear(ci_rid)

Instantiating a Mesh into 3D space

The 3D APIs are different from the 2D ones, so the instantiation API must be used.

GDScript

  1. extends Spatial
  4. # VisualServer expects references to be kept around.
  5. var mesh
  8. func _ready():
  9.     # Create a visual instance (for 3D).
  10.     var instance = VisualServer.instance_create()
  11.     # Set the scenario from the world, this ensures it
  12.     # appears with the same objects as the scene.
  13.     var scenario = get_world().scenario
  14.     VisualServer.instance_set_scenario(instance, scenario)
  15.     # Add a mesh to it.
  16.     # Remember, keep the reference.
  17.     mesh = load("res://mymesh.obj")
  18.     VisualServer.instance_set_base(instance, mesh)
  19.     # Move the mesh around.
  20.     var xform = Transform(Basis(), Vector3(20, 100, 0))
  21.     VisualServer.instance_set_transform(instance, xform)

Creating a 2D RigidBody and moving a sprite with it

This creates a RigidBody2D using the Physics2DServer API, and moves a CanvasItem when the body moves.

GDScript

  1. # Physics2DServer expects references to be kept around.
  2. var body
  3. var shape
  6. func _body_moved(state, index):
  7.     # Created your own canvas item, use it here.
  8.     VisualServer.canvas_item_set_transform(canvas_item, state.transform)
  11. func _ready():
  12.     # Create the body.
  13.     body = Physics2DServer.body_create()
  14.     Physics2DServer.body_set_mode(body, Physics2DServer.BODY_MODE_RIGID)
  15.     # Add a shape.
  16.     shape = RectangleShape2D.new()
  17.     shape.extents = Vector2(10, 10)
  18.     # Make sure to keep the shape reference!
  19.     Physics2DServer.body_add_shape(body, shape)
  20.     # Set space, so it collides in the same space as current scene.
  21.     Physics2DServer.body_set_space(body, get_world_2d().space)
  22.     # Move initial position.
  23.     Physics2DServer.body_set_state(body, Physics2DServer.BODY_STATE_TRANSFORM, Transform2D(0, Vector2(10, 20)))
  24.     # Add the transform callback, when body moves
  25.     # The last parameter is optional, can be used as index
  26.     # if you have many bodies and a single callback.
  27.     Physics2DServer.body_set_force_integration_callback(body, self, "_body_moved", 0)

The 3D version should be very similar, as 2D and 3D physics servers are identical (using RigidBody and PhysicsServer respectively).

Getting data from the servers

Try to never request any information from VisualServer, PhysicsServer or Physics2DServer by calling functions unless you know what you are doing. These servers will often run asynchronously for performance and calling any function that returns a value will stall them and force them to process anything pending until the function is actually called. This will severely decrease performance if you call them every frame (and it won’t be obvious why).

Because of this, most APIs in such servers are designed so it’s not even possible to request information back, until it’s actual data that can be saved.