WebSocket

HTML5 与 WebSocket

The WebSocket protocol was standardized in 2011 with the original goal of allowing browsers to create stable and bidirectional connections with a server. Before that, browsers used to only support HTTPRequests, which is not well-suited for bidirectional communication.

The protocol is quite simple, message based, and a very powerful tool to send push notifications to browsers, and has been used to implement chats, turn-based games, etc. It still uses a TCP connection, which is good for reliability but not for latency, so not good for real-time applications like VoIP and fast-paced games (see WebRTC for those use cases).

Due to its simplicity, its wide compatibility, and being easier to use than a raw TCP connection, WebSocket soon started to spread outside the browsers, in native applications as a mean to communicate with network servers.

Godot supports WebSocket in both native and HTML5 exports.

Using WebSocket in Godot

WebSocket is implemented in Godot via three main classes WebSocketClient, WebSocketServer, and WebSocketPeer. The WebSocket implementation is compatible with the High Level Multiplayer. See section on high-level multiplayer for more details.

Minimal client example

This example will show you how to create a WebSocket connection to a remote server, and how to send and receive data.

  1. extends Node
  3. # The URL we will connect to
  4. export var websocket_url = "ws://echo.websocket.org"
  6. # Our WebSocketClient instance
  7. var _client = WebSocketClient.new()
  9. func _ready():
  10.     # Connect base signals to get notified of connection open, close, and errors.
  11.     _client.connect("connection_closed", self, "_closed")
  12.     _client.connect("connection_error", self, "_closed")
  13.     _client.connect("connection_established", self, "_connected")
  14.     # This signal is emitted when not using the Multiplayer API every time
  15.     # a full packet is received.
  16.     # Alternatively, you could check get_peer(1).get_available_packets() in a loop.
  17.     _client.connect("data_received", self, "_on_data")
  19.     # Initiate connection to the given URL.
  20.     var err = _client.connect_to_url(websocket_url)
  21.     if err != OK:
  22.         print("Unable to connect")
  23.         set_process(false)
  25. func _closed(was_clean = false):
  26.     # was_clean will tell you if the disconnection was correctly notified
  27.     # by the remote peer before closing the socket.
  28.     print("Closed, clean: ", was_clean)
  29.     set_process(false)
  31. func _connected(proto = ""):
  32.     # This is called on connection, "proto" will be the selected WebSocket
  33.     # sub-protocol (which is optional)
  34.     print("Connected with protocol: ", proto)
  35.     # You MUST always use get_peer(1).put_packet to send data to server,
  36.     # and not put_packet directly when not using the MultiplayerAPI.
  37.     _client.get_peer(1).put_packet("Test packet".to_utf8())
  39. func _on_data():
  40.     # Print the received packet, you MUST always use get_peer(1).get_packet
  41.     # to receive data from server, and not get_packet directly when not
  42.     # using the MultiplayerAPI.
  43.     print("Got data from server: ", _client.get_peer(1).get_packet().get_string_from_utf8())
  45. func _process(delta):
  46.     # Call this in _process or _physics_process. Data transfer, and signals
  47.     # emission will only happen when calling this function.
  48.     _client.poll()

This will print:

  1. Connected with protocol:
  2. Got data from server: Test packet

Minimal server example

This example will show you how to create a WebSocket server that listen for remote connections, and how to send and receive data.

  1. extends Node
  3. # The port we will listen to
  4. const PORT = 9080
  5. # Our WebSocketServer instance
  6. var _server = WebSocketServer.new()
  8. func _ready():
  9.     # Connect base signals to get notified of new client connections,
  10.     # disconnections, and disconnect requests.
  11.     _server.connect("client_connected", self, "_connected")
  12.     _server.connect("client_disconnected", self, "_disconnected")
  13.     _server.connect("client_close_request", self, "_close_request")
  14.     # This signal is emitted when not using the Multiplayer API every time a
  15.     # full packet is received.
  16.     # Alternatively, you could check get_peer(PEER_ID).get_available_packets()
  17.     # in a loop for each connected peer.
  18.     _server.connect("data_received", self, "_on_data")
  19.     # Start listening on the given port.
  20.     var err = _server.listen(PORT)
  21.     if err != OK:
  22.         print("Unable to start server")
  23.         set_process(false)
  25. func _connected(id, proto):
  26.     # This is called when a new peer connects, "id" will be the assigned peer id,
  27.     # "proto" will be the selected WebSocket sub-protocol (which is optional)
  28.     print("Client %d connected with protocol: %s" % [id, proto])
  30. func _close_request(id, code, reason):
  31.     # This is called when a client notifies that it wishes to close the connection,
  32.     # providing a reason string and close code.
  33.     print("Client %d disconnecting with code: %d, reason: %s" % [id, code, reason])
  35. func _disconnected(id, was_clean = false):
  36.     # This is called when a client disconnects, "id" will be the one of the
  37.     # disconnecting client, "was_clean" will tell you if the disconnection
  38.     # was correctly notified by the remote peer before closing the socket.
  39.     print("Client %d disconnected, clean: %s" % [id, str(was_clean)])
  41. func _on_data(id):
  42.     # Print the received packet, you MUST always use get_peer(id).get_packet to receive data,
  43.     # and not get_packet directly when not using the MultiplayerAPI.
  44.     var pkt = _server.get_peer(id).get_packet()
  45.     print("Got data from client %d: %s ... echoing" % [id, pkt.get_string_from_utf8()])
  46.     _server.get_peer(id).put_packet(pkt)
  48. func _process(delta):
  49.     # Call this in _process or _physics_process.
  50.     # Data transfer, and signals emission will only happen when calling this function.
  51.     _server.poll()

This will print (when a client connects) something similar to this:

  1. Client 1348090059 connected with protocol: selected-protocol
  2. Got data from client 1348090059: Test packet ... echoing

Advanced chat demo

A more advanced chat demo which optionally uses the multiplayer mid-level abstraction and a high level multiplayer demo are available in the godot demo projects under networking/websocket_chat and networking/websocket_multiplayer.