DO

While **DOLIST** and **DOTIMES** are convenient and easy to use, they aren’t flexible enough to use for all loops. For instance, what if you want to step multiple variables in parallel? Or use an arbitrary expression to test for the end of the loop? If neither **DOLIST** nor **DOTIMES** meet your needs, you still have access to the more general **DO** loop.

Where **DOLIST** and **DOTIMES** provide only one loop variable, **DO** lets you bind any number of variables and gives you complete control over how they change on each step through the loop. You also get to define the test that determines when to end the loop and can provide a form to evaluate at the end of the loop to generate a return value for the **DO** expression as a whole. The basic template looks like this:

(do (variable-definition*)
    (end-test-form result-form*)
  statement*)

Each variable-definition introduces a variable that will be in scope in the body of the loop. The full form of a single variable definition is a list containing three elements.

(var init-form step-form)

The init-form will be evaluated at the beginning of the loop and the resulting values bound to the variable var. Before each subsequent iteration of the loop, the step-form will be evaluated and the new value assigned to var. The step-form is optional; if it’s left out, the variable will keep its value from iteration to iteration unless you explicitly assign it a new value in the loop body. As with the variable definitions in a **LET**, if the init-form is left out, the variable is bound to **NIL**. Also as with **LET**, you can use a plain variable name as shorthand for a list containing just the name.

At the beginning of each iteration, after all the loop variables have been given their new values, the end-test-form is evaluated. As long as it evaluates to **NIL**, the iteration proceeds, evaluating the statements in order.

When the end-test-form evaluates to true, the result-forms are evaluated, and the value of the last result form is returned as the value of the **DO** expression.

At each step of the iteration the step forms for all the variables are evaluated before assigning any of the values to the variables. This means you can refer to any of the other loop variables in the step forms.6 That is, in a loop like this:

(do ((n 0 (1+ n))
     (cur 0 next)
     (next 1 (+ cur next)))
    ((= 10 n) cur))

the step forms (1+ n), next, and (+ cur next) are all evaluated using the old values of n, cur, and next. Only after all the step forms have been evaluated are the variables given their new values. (Mathematically inclined readers may notice that this is a particularly efficient way of computing the eleventh Fibonacci number.)

This example also illustrates another characteristic of **DO**--because you can step multiple variables, you often don’t need a body at all. Other times, you may leave out the result form, particularly if you’re just using the loop as a control construct. This flexibility, however, is the reason that **DO** expressions can be a bit cryptic. Where exactly do all the parentheses go? The best way to understand a **DO** expression is to keep in mind the basic template.

(do (variable-definition*)
    (end-test-form result-form*)
  statement*)

The six parentheses in that template are the only ones required by the **DO** itself. You need one pair to enclose the variable declarations, one pair to enclose the end test and result forms, and one pair to enclose the whole expression. Other forms within the **DO** may require their own parentheses—variable definitions are usually lists, for instance. And the test form is often a function call. But the skeleton of a **DO** loop will always be the same. Here are some example **DO** loops with the skeleton in bold:

(do ((i 0 (1+ i)))
    ((>= i 4))
  (print i))

Notice that the result form has been omitted. This is, however, not a particularly idiomatic use of **DO**, as this loop is much more simply written using **DOTIMES**.7

(dotimes (i 4) (print i))

As another example, here’s the bodiless Fibonacci-computing loop:

(do ((n 0 (1+ n))
     (cur 0 next)
     (next 1 (+ cur next)))
    ((= 10 n) cur))

Finally, the next loop demonstrates a **DO** loop that binds no variables. It loops while the current time is less than the value of a global variable, printing “Waiting” once a minute. Note that even with no loop variables, you still need the empty variables list.

(do ()
    ((> (get-universal-time) *some-future-date*))
  (format t "Waiting~%")
  (sleep 60))