Accessor Functions

Between **MAKE-INSTANCE** and **SLOT-VALUE**, you have all the tools you need for creating and manipulating instances of your classes. Everything else you might want to do can be implemented in terms of those two functions. However, as anyone familiar with the principles of good object-oriented programming practices knows, directly accessing the slots (or fields or member variables) of an object can lead to fragile code. The problem is that directly accessing slots ties your code too tightly to the concrete structure of your class. For example, suppose you decide to change the definition of bank-account so that, instead of storing the current balance as a number, you store a list of time-stamped withdrawals and deposits. Code that directly accesses the balance slot will likely break if you change the class definition to remove the slot or to store the new list in the old slot. On the other hand, if you define a function, balance, that accesses the slot, you can redefine it later to preserve its behavior even if the internal representation changes. And code that uses such a function will continue to work without modification.

Another advantage to using accessor functions rather than direct access to slots via **SLOT-VALUE** is that they let you limit the ways outside code can modify a slot.8 It may be fine for users of the bank-account class to get the current balance, but you may want all modifications to the balance to go through other functions you’ll provide, such as deposit and withdraw. If clients know they’re supposed to manipulate objects only through the published functional API, you can provide a balance function but not make it **SETF**able if you want the balance to be read-only.

Finally, using accessor functions makes your code tidier since it helps you avoid lots of uses of the rather verbose **SLOT-VALUE** function.

It’s trivial to define a function that reads the value of the balance slot.

  1. (defun balance (account)
  2.   (slot-value account 'balance))

However, if you know you’re going to define subclasses of bank-account, it might be a good idea to define balance as a generic function. That way, you can provide different methods on balance for those subclasses or extend its definition with auxiliary methods. So you might write this instead:

  1. (defgeneric balance (account))
  3. (defmethod balance ((account bank-account))
  4.   (slot-value account 'balance))

As I just discussed, you don’t want callers to be able to directly set the balance, but for other slots, such as customer-name, you may also want to provide a function to set them. The cleanest way to define such a function is as a **SETF** function.

A **SETF** function is a way to extend **SETF**, defining a new kind of place that it knows how to set. The name of a **SETF** function is a two-item list whose first element is the symbol setf and whose second element is a symbol, typically the name of a function used to access the place the **SETF** function will set. A **SETF** function can take any number of arguments, but the first argument is always the value to be assigned to the place.9 You could, for instance, define a **SETF** function to set the customer-name slot in a bank-account like this:

  1. (defun (setf customer-name) (name account)
  2.   (setf (slot-value account 'customer-name) name))

After evaluating that definition, an expression like the following one:

  1. (setf (customer-name my-account) "Sally Sue")

will be compiled as a call to the **SETF** function you just defined with “Sally Sue” as the first argument and the value of my-account as the second argument.

Of course, as with reader functions, you’ll probably want your **SETF** function to be generic, so you’d actually define it like this:

  1. (defgeneric (setf customer-name) (value account))
  3. (defmethod (setf customer-name) (value (account bank-account))
  4.   (setf (slot-value account 'customer-name) value))

And of course you’ll also want to define a reader function for customer-name.

  1. (defgeneric customer-name (account))
  3. (defmethod customer-name ((account bank-account))
  4.   (slot-value account 'customer-name))

This allows you to write the following:

  1. (setf (customer-name *account*) "Sally Sue") ==> "Sally Sue"
  3. (customer-name *account*)                    ==> "Sally Sue"

There’s nothing hard about writing these accessor functions, but it wouldn’t be in keeping with The Lisp Way to have to write them all by hand. Thus, **DEFCLASS** supports three slot options that allow you to automatically create reader and writer functions for a specific slot.

The :reader option specifies a name to be used as the name of a generic function that accepts an object as its single argument. When the **DEFCLASS** is evaluated, the generic function is created, if it doesn’t already exist. Then a method specializing its single argument on the new class and returning the value of the slot is added to the generic function. The name can be anything, but it’s typical to name it the same as the slot itself. Thus, instead of explicitly writing the balance generic function and method as shown previously, you could change the slot specifier for the balance slot in the definition of bank-account to this:

  1. (balance
  2.  :initarg :balance
  3.  :initform 0
  4.  :reader balance)

The :writer option is used to create a generic function and method for setting the value of a slot. The function and method created follow the requirements for a **SETF** function, taking the new value as the first argument and returning it as the result, so you can define a **SETF** function by providing a name such as (setf customer-name). For instance, you could provide reader and writer methods for customer-name equivalent to the ones you just wrote by changing the slot specifier to this:

  1. (customer-name
  2.  :initarg :customer-name
  3.  :initform (error "Must supply a customer name.")
  4.  :reader customer-name
  5.  :writer (setf customer-name))

Since it’s quite common to want both reader and writer functions, **DEFCLASS** also provides an option, :accessor, that creates both a reader function and the corresponding **SETF** function. So instead of the slot specifier just shown, you’d typically write this:

  1. (customer-name
  2.  :initarg :customer-name
  3.  :initform (error "Must supply a customer name.")
  4.  :accessor customer-name)

Finally, one last slot option you should know about is the :documentation option, which you can use to provide a string that documents the purpose of the slot. Putting it all together and adding a reader method for the account-number and account-type slots, the **DEFCLASS** form for the bank-account class would look like this:

  1. (defclass bank-account ()
  2.   ((customer-name
  3.     :initarg :customer-name
  4.     :initform (error "Must supply a customer name.")
  5.     :accessor customer-name
  6.     :documentation "Customer's name")
  7.    (balance
  8.     :initarg :balance
  9.     :initform 0
  10.     :reader balance
  11.     :documentation "Current account balance")
  12.    (account-number
  13.     :initform (incf *account-numbers*)
  14.     :reader account-number
  15.     :documentation "Account number, unique within a bank.")
  16.    (account-type
  17.     :reader account-type
  18.     :documentation "Type of account, one of :gold, :silver, or :bronze.")))