Dynamic, a.k.a. Special, Variables

Lexically scoped bindings help keep code understandable by limiting the scope, literally, in which a given name has meaning. This is why most modern languages use lexical scoping for local variables. Sometimes, however, you really want a global variable—a variable that you can refer to from anywhere in your program. While it’s true that indiscriminate use of global variables can turn code into spaghetti nearly as quickly as unrestrained use of goto, global variables do have legitimate uses and exist in one form or another in almost every programming language.7 And as you’ll see in a moment, Lisp’s version of global variables, dynamic variables, are both more useful and more manageable.

Common Lisp provides two ways to create global variables: **DEFVAR** and **DEFPARAMETER**. Both forms take a variable name, an initial value, and an optional documentation string. After it has been **DEFVAR**ed or **DEFPARAMETER**ed, the name can be used anywhere to refer to the current binding of the global variable. As you’ve seen in previous chapters, global variables are conventionally named with names that start and end with *. You’ll see later in this section why it’s quite important to follow that naming convention. Examples of **DEFVAR** and **DEFPARAMETER** look like this:

  1. (defvar *count* 0
  2.   "Count of widgets made so far.")
  4. (defparameter *gap-tolerance* 0.001
  5.   "Tolerance to be allowed in widget gaps.")

The difference between the two forms is that **DEFPARAMETER** always assigns the initial value to the named variable while **DEFVAR** does so only if the variable is undefined. A **DEFVAR** form can also be used with no initial value to define a global variable without giving it a value. Such a variable is said to be unbound.

Practically speaking, you should use **DEFVAR** to define variables that will contain data you’d want to keep even if you made a change to the source code that uses the variable. For instance, suppose the two variables defined previously are part of an application for controlling a widget factory. It’s appropriate to define the *count* variable with **DEFVAR** because the number of widgets made so far isn’t invalidated just because you make some changes to the widget-making code.8

On the other hand, the variable *gap-tolerance* presumably has some effect on the behavior of the widget-making code itself. If you decide you need a tighter or looser tolerance and change the value in the **DEFPARAMETER** form, you’d like the change to take effect when you recompile and reload the file.

After defining a variable with **DEFVAR** or **DEFPARAMETER**, you can refer to it from anywhere. For instance, you might define this function to increment the count of widgets made:

  1. (defun increment-widget-count () (incf *count*))

The advantage of global variables is that you don’t have to pass them around. Most languages store the standard input and output streams in global variables for exactly this reason—you never know when you’re going to want to print something to standard out, and you don’t want every function to have to accept and pass on arguments containing those streams just in case someone further down the line needs them.

However, once a value, such as the standard output stream, is stored in a global variable and you have written code that references that global variable, it’s tempting to try to temporarily modify the behavior of that code by changing the variable’s value.

For instance, suppose you’re working on a program that contains some low-level logging functions that print to the stream in the global variable *standard-output*. Now suppose that in part of the program you want to capture all the output generated by those functions into a file. You might open a file and assign the resulting stream to *standard-output*. Now the low-level functions will send their output to the file.

This works fine until you forget to set *standard-output* back to the original stream when you’re done. If you forget to reset *standard-output*, all the other code in the program that uses *standard-output* will also send its output to the file.9

What you really want, it seems, is a way to wrap a piece of code in something that says, “All code below here—all the functions it calls, all the functions they call, and so on, down to the lowest-level functions—should use this value for the global variable *standard-output*.” Then when the high-level function returns, the old value of *standard-output* should be automatically restored.

It turns out that that’s exactly what Common Lisp’s other kind of variable—dynamic variables—let you do. When you bind a dynamic variable—for example, with a **LET** variable or a function parameter—the binding that’s created on entry to the binding form replaces the global binding for the duration of the binding form. Unlike a lexical binding, which can be referenced by code only within the lexical scope of the binding form, a dynamic binding can be referenced by any code that’s invoked during the execution of the binding form.10 And it turns out that all global variables are, in fact, dynamic variables.

Thus, if you want to temporarily redefine *standard-output*, the way to do it is simply to rebind it, say, with a **LET**.

  1. (let ((*standard-output* *some-other-stream*))
  2.   (stuff))

In any code that runs as a result of the call to stuff, references to *standard-output* will use the binding established by the **LET**. And when stuff returns and control leaves the **LET**, the new binding of *standard-output* will go away and subsequent references to *standard-output* will see the binding that was current before the **LET**. At any given time, the most recently established binding shadows all other bindings. Conceptually, each new binding for a given dynamic variable is pushed onto a stack of bindings for that variable, and references to the variable always use the most recent binding. As binding forms return, the bindings they created are popped off the stack, exposing previous bindings.11

A simple example shows how this works.

  1. (defvar *x* 10)
  2. (defun foo () (format t "X: ~d~%" *x*))

The **DEFVAR** creates a global binding for the variable *x* with the value 10. The reference to *x* in foo will look up the current binding dynamically. If you call foo from the top level, the global binding created by the **DEFVAR** is the only binding available, so it prints 10.

  1. CL-USER> (foo)
  2. X: 10
  3. NIL

But you can use **LET** to create a new binding that temporarily shadows the global binding, and foo will print a different value.

  1. CL-USER> (let ((*x* 20)) (foo))
  2. X: 20
  3. NIL

Now call foo again, with no **LET**, and it again sees the global binding.

  1. CL-USER> (foo)
  2. X: 10
  3. NIL

Now define another function.

  1. (defun bar ()
  2.   (foo)
  3.   (let ((*x* 20)) (foo))
  4.   (foo))

Note that the middle call to foo is wrapped in a **LET** that binds *x* to the new value 20. When you run bar, you get this result:

  1. CL-USER> (bar)
  2. X: 10
  3. X: 20
  4. X: 10
  5. NIL

As you can see, the first call to foo sees the global binding, with its value of 10. The middle call, however, sees the new binding, with the value 20. But after the **LET**, foo once again sees the global binding.

As with lexical bindings, assigning a new value affects only the current binding. To see this, you can redefine foo to include an assignment to *x*.

  1. (defun foo ()
  2.   (format t "Before assignment~18tX: ~d~%" *x*)
  3.   (setf *x* (+ 1 *x*))
  4.   (format t "After assignment~18tX: ~d~%" *x*))

Now foo prints the value of *x*, increments it, and prints it again. If you just run foo, you’ll see this:

  1. CL-USER> (foo)
  2. Before assignment X: 10
  3. After assignment  X: 11
  4. NIL

Not too surprising. Now run bar.

  1. CL-USER> (bar)
  2. Before assignment X: 11
  3. After assignment  X: 12
  4. Before assignment X: 20
  5. After assignment  X: 21
  6. Before assignment X: 12
  7. After assignment  X: 13
  8. NIL

Notice that *x* started at 11—the earlier call to foo really did change the global value. The first call to foo from bar increments the global binding to 12. The middle call doesn’t see the global binding because of the **LET**. Then the last call can see the global binding again and increments it from 12 to 13.

So how does this work? How does **LET** know that when it binds *x* it’s supposed to create a dynamic binding rather than a normal lexical binding? It knows because the name has been declared special.12 The name of every variable defined with **DEFVAR** and **DEFPARAMETER** is automatically declared globally special. This means whenever you use such a name in a binding form—in a **LET** or as a function parameter or any other construct that creates a new variable binding—the binding that’s created will be a dynamic binding. This is why the *naming* *convention* is so important—it’d be bad news if you used a name for what you thought was a lexical variable and that variable happened to be globally special. On the one hand, code you call could change the value of the binding out from under you; on the other, you might be shadowing a binding established by code higher up on the stack. If you always name global variables according to the * naming convention, you’ll never accidentally use a dynamic binding where you intend to establish a lexical binding.

It’s also possible to declare a name locally special. If, in a binding form, you declare a name special, then the binding created for that variable will be dynamic rather than lexical. Other code can locally declare a name special in order to refer to the dynamic binding. However, locally special variables are relatively rare, so you needn’t worry about them.13

Dynamic bindings make global variables much more manageable, but it’s important to notice they still allow action at a distance. Binding a global variable has two at a distance effects—it can change the behavior of downstream code, and it also opens the possibility that downstream code will assign a new value to a binding established higher up on the stack. You should use dynamic variables only when you need to take advantage of one or both of these characteristics.