Source Edit

This module contains the interface to the compiler’s abstract syntax tree (AST). Macros operate on this tree.

See also:

• macros tutorial
• macros section in Nim manual

The AST in Nim

This section describes how the AST is modelled with Nim’s type system. The AST consists of nodes (NimNode) with a variable number of children. Each node has a field named kind which describes what the node contains:

type
  NimNodeKind = enum     ## kind of a node; only explanatory
    nnkNone,             ## invalid node kind
    nnkEmpty,            ## empty node
    nnkIdent,            ## node contains an identifier
    nnkIntLit,           ## node contains an int literal (example: 10)
    nnkStrLit,           ## node contains a string literal (example: "abc")
    nnkNilLit,           ## node contains a nil literal (example: nil)
    nnkCaseStmt,         ## node represents a case statement
    ...                  ## many more
  NimNode = ref NimNodeObj
  NimNodeObj = object
    case kind: NimNodeKind           ## the node's kind
    of nnkNone, nnkEmpty, nnkNilLit:
      discard                        ## node contains no additional fields
    of nnkCharLit..nnkUInt64Lit:
      intVal: BiggestInt             ## the int literal
    of nnkFloatLit..nnkFloat64Lit:
      floatVal: BiggestFloat         ## the float literal
    of nnkStrLit..nnkTripleStrLit, nnkCommentStmt, nnkIdent, nnkSym:
      strVal: string                 ## the string literal
    else:
      sons: seq[NimNode]             ## the node's sons (or children)

For the NimNode type, the [] operator has been overloaded: n[i] is n’s i-th child.

To specify the AST for the different Nim constructs, the notation nodekind(son1, son2, …) or nodekind(value) or nodekind(field=value) is used.

Some child may be missing. A missing child is a node of kind nnkEmpty; a child can never be nil.

Leaf nodes/Atoms

A leaf of the AST often corresponds to a terminal symbol in the concrete syntax. Note that the default float in Nim maps to float64 such that the default AST for a float is nnkFloat64Lit as below.

Identifiers are nnkIdent nodes. After the name lookup pass these nodes get transferred into nnkSym nodes.

Calls/expressions

Command call

Concrete syntax:

echo "abc", "xyz"

AST:

nnkCommand(
  nnkIdent("echo"),
  nnkStrLit("abc"),
  nnkStrLit("xyz")
)

Call with ()

Concrete syntax:

echo("abc", "xyz")

AST:

nnkCall(
  nnkIdent("echo"),
  nnkStrLit("abc"),
  nnkStrLit("xyz")
)

Infix operator call

Concrete syntax:

"abc" & "xyz"

AST:

nnkInfix(
  nnkIdent("&"),
  nnkStrLit("abc"),
  nnkStrLit("xyz")
)

Note that with multiple infix operators, the command is parsed by operator precedence.

Concrete syntax:

5 + 3 * 4

AST:

nnkInfix(
  nnkIdent("+"),
  nnkIntLit(5),
  nnkInfix(
    nnkIdent("*"),
    nnkIntLit(3),
    nnkIntLit(4)
  )
)

As a side note, if you choose to use infix operators in a prefix form, the AST behaves as a parenthetical function call with nnkAccQuoted, as follows:

Concrete syntax:

`+`(3, 4)

AST:

nnkCall(
  nnkAccQuoted(
    nnkIdent("+")
  ),
  nnkIntLit(3),
  nnkIntLit(4)
)

Prefix operator call

Concrete syntax:

? "xyz"

AST:

nnkPrefix(
  nnkIdent("?"),
  nnkStrLit("abc")
)

Postfix operator call

Note: There are no postfix operators in Nim. However, the nnkPostfix node is used for the asterisk export marker *:

Concrete syntax:

identifier*

AST:

nnkPostfix(
  nnkIdent("*"),
  nnkIdent("identifier")
)

Call with named arguments

Concrete syntax:

writeLine(file=stdout, "hallo")

AST:

nnkCall(
  nnkIdent("writeLine"),
  nnkExprEqExpr(
    nnkIdent("file"),
    nnkIdent("stdout")
  ),
  nnkStrLit("hallo")
)

Call with raw string literal

This is used, for example, in the bindSym examples here and with re”some regexp” in the regular expression module.

Concrete syntax:

echo"abc"

AST:

nnkCallStrLit(
  nnkIdent("echo"),
  nnkRStrLit("hello")
)

Dereference operator []

Concrete syntax:

x[]

AST:

nnkDerefExpr(nnkIdent("x"))

Addr operator

Concrete syntax:

addr(x)

AST:

nnkAddr(nnkIdent("x"))

Cast operator

Concrete syntax:

cast[T](x)

AST:

nnkCast(nnkIdent("T"), nnkIdent("x"))

Object access operator .

Concrete syntax:

x.y

AST:

nnkDotExpr(nnkIdent("x"), nnkIdent("y"))

If you use Nim’s flexible calling syntax (as in x.len()), the result is the same as above but wrapped in an nnkCall.

Array access operator []

Concrete syntax:

x[y]

AST:

nnkBracketExpr(nnkIdent("x"), nnkIdent("y"))

Parentheses

Parentheses for affecting operator precedence use the nnkPar node.

Concrete syntax:

(a + b) * c

AST:

nnkInfix(nnkIdent("*"),
  nnkPar(
    nnkInfix(nnkIdent("+"), nnkIdent("a"), nnkIdent("b"))),
  nnkIdent("c"))

Tuple Constructors

Nodes for tuple construction are built with the nnkTupleConstr node.

Concrete syntax:

(1, 2, 3)
(a: 1, b: 2, c: 3)
()

AST:

nnkTupleConstr(nnkIntLit(1), nnkIntLit(2), nnkIntLit(3))
nnkTupleConstr(
  nnkExprColonExpr(nnkIdent("a"), nnkIntLit(1)),
  nnkExprColonExpr(nnkIdent("b"), nnkIntLit(2)),
  nnkExprColonExpr(nnkIdent("c"), nnkIntLit(3)))
nnkTupleConstr()

Since the one tuple would be syntactically identical to parentheses with an expression in them, the parser expects a trailing comma for them. For tuple constructors with field names, this is not necessary.

(1,)
(a: 1)

AST:

nnkTupleConstr(nnkIntLit(1))
nnkTupleConstr(
  nnkExprColonExpr(nnkIdent("a"), nnkIntLit(1)))

Curly braces

Curly braces are used as the set constructor.

Concrete syntax:

{1, 2, 3}

AST:

nnkCurly(nnkIntLit(1), nnkIntLit(2), nnkIntLit(3))

When used as a table constructor, the syntax is different.

Concrete syntax:

{a: 3, b: 5}

AST:

nnkTableConstr(
  nnkExprColonExpr(nnkIdent("a"), nnkIntLit(3)),
  nnkExprColonExpr(nnkIdent("b"), nnkIntLit(5))
)

Brackets

Brackets are used as the array constructor.

Concrete syntax:

[1, 2, 3]

AST:

nnkBracket(nnkIntLit(1), nnkIntLit(2), nnkIntLit(3))

Ranges

Ranges occur in set constructors, case statement branches, or array slices. Internally, the node kind nnkRange is used, but when constructing the AST, construction with .. as an infix operator should be used instead.

Concrete syntax:

1..3

AST:

nnkInfix(
  nnkIdent(".."),
  nnkIntLit(1),
  nnkIntLit(3)
)

Example code:

macro genRepeatEcho() =
  result = newNimNode(nnkStmtList)
  var forStmt = newNimNode(nnkForStmt) # generate a for statement
  forStmt.add(ident("i")) # use the variable `i` for iteration
  var rangeDef = newNimNode(nnkInfix).add(
    ident("..")).add(
    newIntLitNode(3),newIntLitNode(5)) # iterate over the range 3..5
  forStmt.add(rangeDef)
  forStmt.add(newCall(ident("echo"), newIntLitNode(3))) # meat of the loop
  result.add(forStmt)
genRepeatEcho() # gives:
                # 3
                # 3
                # 3

If expression

The representation of the if expression is subtle, but easy to traverse.

Concrete syntax:

if cond1: expr1 elif cond2: expr2 else: expr3

AST:

nnkIfExpr(
  nnkElifExpr(cond1, expr1),
  nnkElifExpr(cond2, expr2),
  nnkElseExpr(expr3)
)

Documentation Comments

Double-hash (##) comments in the code actually have their own format, using strVal to get and set the comment text. Single-hash (#) comments are ignored.

Concrete syntax:

## This is a comment
## This is part of the first comment
stmt1
## Yet another

AST:

nnkCommentStmt() # only appears once for the first two lines!
stmt1
nnkCommentStmt() # another nnkCommentStmt because there is another comment
                 # (separate from the first)

Pragmas

One of Nim’s cool features is pragmas, which allow fine-tuning of various aspects of the language. They come in all types, such as adorning procs and objects, but the standalone emit pragma shows the basics with the AST.

Concrete syntax:

{.emit: "#include <stdio.h>".}

AST:

nnkPragma(
  nnkExprColonExpr(
    nnkIdent("emit"),
    nnkStrLit("#include <stdio.h>") # the "argument"
  )
)

As many nnkIdent appear as there are pragmas between {..}. Note that the declaration of new pragmas is essentially the same:

Concrete syntax:

{.pragma: cdeclRename, cdecl.}

AST:

nnkPragma(
  nnkExprColonExpr(
    nnkIdent("pragma"), # this is always first when declaring a new pragma
    nnkIdent("cdeclRename") # the name of the pragma
  ),
  nnkIdent("cdecl")
)

Statements

If statement

The representation of the if statement is subtle, but easy to traverse. If there is no else branch, no nnkElse child exists.

Concrete syntax:

if cond1:
  stmt1
elif cond2:
  stmt2
elif cond3:
  stmt3
else:
  stmt4

AST:

nnkIfStmt(
  nnkElifBranch(cond1, stmt1),
  nnkElifBranch(cond2, stmt2),
  nnkElifBranch(cond3, stmt3),
  nnkElse(stmt4)
)

When statement

Like the if statement, but the root has the kind nnkWhenStmt.

Assignment

Concrete syntax:

x = 42

AST:

nnkAsgn(nnkIdent("x"), nnkIntLit(42))

This is not the syntax for assignment when combined with var, let, or const.

Statement list

Concrete syntax:

stmt1
stmt2
stmt3

AST:

nnkStmtList(stmt1, stmt2, stmt3)

Case statement

Concrete syntax:

case expr1
of expr2, expr3..expr4:
  stmt1
of expr5:
  stmt2
elif cond1:
  stmt3
else:
  stmt4

AST:

nnkCaseStmt(
  expr1,
  nnkOfBranch(expr2, nnkRange(expr3, expr4), stmt1),
  nnkOfBranch(expr5, stmt2),
  nnkElifBranch(cond1, stmt3),
  nnkElse(stmt4)
)

The nnkElifBranch and nnkElse parts may be missing.

While statement

Concrete syntax:

while expr1:
  stmt1

AST:

nnkWhileStmt(expr1, stmt1)

For statement

Concrete syntax:

for ident1, ident2 in expr1:
  stmt1

AST:

nnkForStmt(ident1, ident2, expr1, stmt1)

Try statement

Concrete syntax:

try:
  stmt1
except e1, e2:
  stmt2
except e3:
  stmt3
except:
  stmt4
finally:
  stmt5

AST:

nnkTryStmt(
  stmt1,
  nnkExceptBranch(e1, e2, stmt2),
  nnkExceptBranch(e3, stmt3),
  nnkExceptBranch(stmt4),
  nnkFinally(stmt5)
)

Return statement

Concrete syntax:

return expr1

AST:

nnkReturnStmt(expr1)

Yield statement

Like return, but with nnkYieldStmt kind.

nnkYieldStmt(expr1)

Discard statement

Like return, but with nnkDiscardStmt kind.

nnkDiscardStmt(expr1)

Continue statement

Concrete syntax:

continue

AST:

nnkContinueStmt()

Break statement

Concrete syntax:

break otherLocation

AST:

nnkBreakStmt(nnkIdent("otherLocation"))

If break is used without a jump-to location, nnkEmpty replaces nnkIdent.

Block statement

Concrete syntax:

block name:

AST:

nnkBlockStmt(nnkIdent("name"), nnkStmtList(...))

A block doesn’t need an name, in which case nnkEmpty is used.

Asm statement

Concrete syntax:

asm """
  some asm
"""

AST:

nnkAsmStmt(
  nnkEmpty(), # for pragmas
  nnkTripleStrLit("some asm"),
)

Import section

Nim’s import statement actually takes different variations depending on what keywords are present. Let’s start with the simplest form.

Concrete syntax:

import math

AST:

nnkImportStmt(nnkIdent("math"))

With except, we get nnkImportExceptStmt.

Concrete syntax:

import math except pow

AST:

nnkImportExceptStmt(nnkIdent("math"),nnkIdent("pow"))

Note that import math as m does not use a different node; rather, we use nnkImportStmt with as as an infix operator.

Concrete syntax:

import strutils as su

AST:

nnkImportStmt(
  nnkInfix(
    nnkIdent("as"),
    nnkIdent("strutils"),
    nnkIdent("su")
  )
)

From statement

If we use from … import, the result is different, too.

Concrete syntax:

from math import pow

AST:

nnkFromStmt(nnkIdent("math"), nnkIdent("pow"))

Using from math as m import pow works identically to the as modifier with the import statement, but wrapped in nnkFromStmt.

Export statement

When you are making an imported module accessible by modules that import yours, the export syntax is pretty straightforward.

Concrete syntax:

export unsigned

AST:

nnkExportStmt(nnkIdent("unsigned"))

Similar to the import statement, the AST is different for export … except.

Concrete syntax:

export math except pow # we're going to implement our own exponentiation

AST:

nnkExportExceptStmt(nnkIdent("math"),nnkIdent("pow"))

Include statement

Like a plain import statement but with nnkIncludeStmt.

Concrete syntax:

include blocks

AST:

nnkIncludeStmt(nnkIdent("blocks"))

Var section

Concrete syntax:

var a = 3

AST:

nnkVarSection(
  nnkIdentDefs(
    nnkIdent("a"),
    nnkEmpty(), # or nnkIdent(...) if the variable declares the type
    nnkIntLit(3),
  )
)

Note that either the second or third (or both) parameters above must exist, as the compiler needs to know the type somehow (which it can infer from the given assignment).

This is not the same AST for all uses of var. See Procedure declaration for details.

Let section

This is equivalent to var, but with nnkLetSection rather than nnkVarSection.

Concrete syntax:

let a = 3

AST:

nnkLetSection(
  nnkIdentDefs(
    nnkIdent("a"),
    nnkEmpty(), # or nnkIdent(...) for the type
    nnkIntLit(3),
  )
)

Const section

Concrete syntax:

const a = 3

AST:

nnkConstSection(
  nnkConstDef( # not nnkConstDefs!
    nnkIdent("a"),
    nnkEmpty(), # or nnkIdent(...) if the variable declares the type
    nnkIntLit(3), # required in a const declaration!
  )
)

Type section

Starting with the simplest case, a type section appears much like var and const.

Concrete syntax:

type A = int

AST:

nnkTypeSection(
  nnkTypeDef(
    nnkIdent("A"),
    nnkEmpty(),
    nnkIdent("int")
  )
)

Declaring distinct types is similar, with the last nnkIdent wrapped in nnkDistinctTy.

Concrete syntax:

type MyInt = distinct int

AST:

# ...
nnkTypeDef(
  nnkIdent("MyInt"),
  nnkEmpty(),
  nnkDistinctTy(
    nnkIdent("int")
  )
)

If a type section uses generic parameters, they are treated here:

Concrete syntax:

type A[T] = expr1

AST:

nnkTypeSection(
  nnkTypeDef(
    nnkIdent("A"),
    nnkGenericParams(
      nnkIdentDefs(
        nnkIdent("T"),
        nnkEmpty(), # if the type is declared with options, like
                    # ``[T: SomeInteger]``, they are given here
        nnkEmpty(),
      )
    )
    expr1,
  )
)

Note that not all nnkTypeDef utilize nnkIdent as their parameter. One of the most common uses of type declarations is to work with objects.

Concrete syntax:

type IO = object of RootObj

AST:

# ...
nnkTypeDef(
  nnkIdent("IO"),
  nnkEmpty(),
  nnkObjectTy(
    nnkEmpty(), # no pragmas here
    nnkOfInherit(
      nnkIdent("RootObj") # inherits from RootObj
    ),
    nnkEmpty()
  )
)

Nim’s object syntax is rich. Let’s take a look at an involved example in its entirety to see some of the complexities.

Concrete syntax:

type Obj[T] {.inheritable.} = object
  name: string
  case isFat: bool
  of true:
    m: array[100_000, T]
  of false:
    m: array[10, T]

AST:

# ...
nnkPragmaExpr(
  nnkIdent("Obj"),
  nnkPragma(nnkIdent("inheritable"))
),
nnkGenericParams(
nnkIdentDefs(
  nnkIdent("T"),
  nnkEmpty(),
  nnkEmpty())
),
nnkObjectTy(
  nnkEmpty(),
  nnkEmpty(),
  nnkRecList( # list of object parameters
    nnkIdentDefs(
      nnkIdent("name"),
      nnkIdent("string"),
      nnkEmpty()
    ),
    nnkRecCase( # case statement within object (not nnkCaseStmt)
      nnkIdentDefs(
        nnkIdent("isFat"),
        nnkIdent("bool"),
        nnkEmpty()
      ),
      nnkOfBranch(
        nnkIdent("true"),
        nnkRecList( # again, a list of object parameters
          nnkIdentDefs(
            nnkIdent("m"),
            nnkBracketExpr(
              nnkIdent("array"),
              nnkIntLit(100000),
              nnkIdent("T")
            ),
            nnkEmpty()
        )
      ),
      nnkOfBranch(
        nnkIdent("false"),
        nnkRecList(
          nnkIdentDefs(
            nnkIdent("m"),
            nnkBracketExpr(
              nnkIdent("array"),
              nnkIntLit(10),
              nnkIdent("T")
            ),
            nnkEmpty()
          )
        )
      )
    )
  )
)

Using an enum is similar to using an object.

Concrete syntax:

type X = enum
  First

AST:

# ...
nnkEnumTy(
  nnkEmpty(),
  nnkIdent("First") # you need at least one nnkIdent or the compiler complains
)

The usage of concept (experimental) is similar to objects.

Concrete syntax:

type Con = concept x,y,z
  (x & y & z) is string

AST:

# ...
nnkTypeClassTy( # note this isn't nnkConceptTy!
  nnkArgList(
    # ... idents for x, y, z
  )
  # ...
)

Static types, like static[int], use nnkIdent wrapped in nnkStaticTy.

Concrete syntax:

type A[T: static[int]] = object

AST:

# ... within nnkGenericParams
nnkIdentDefs(
  nnkIdent("T"),
  nnkStaticTy(
    nnkIdent("int")
  ),
  nnkEmpty()
)
# ...

In general, declaring types mirrors this syntax (i.e., nnkStaticTy for static, etc.). Examples follow (exceptions marked by *):

Take special care when declaring types as proc. The behavior is similar to Procedure declaration, below, but does not treat nnkGenericParams. Generic parameters are treated in the type, not the proc itself.

Concrete syntax:

type MyProc[T] = proc(x: T) {.nimcall.}

AST:

# ...
nnkTypeDef(
  nnkIdent("MyProc"),
  nnkGenericParams( # here, not with the proc
    # ...
  )
  nnkProcTy( # behaves like a procedure declaration from here on
    nnkFormalParams(
      # ...
    ),
    nnkPragma(nnkIdent("nimcall"))
  )
)

The same syntax applies to iterator (with nnkIteratorTy), but does not apply to converter or template.

Type class versions of these nodes generally share the same node kind but without any child nodes. The tuple type class is represented by nnkTupleClassTy, while a proc or iterator type class with pragmas has an nnkEmpty node in place of the nnkFormalParams node of a concrete proc or iterator type node.

type TypeClass = proc {.nimcall.} | ref | tuple

AST:

nnkTypeDef(
  nnkIdent("TypeClass"),
  nnkEmpty(),
  nnkInfix(
    nnkIdent("|"),
    nnkProcTy(
      nnkEmpty(),
      nnkPragma(nnkIdent("nimcall"))
    ),
    nnkInfix(
      nnkIdent("|"),
      nnkRefTy(),
      nnkTupleClassTy()
    )
  )
)

Mixin statement

Concrete syntax:

mixin x

AST:

nnkMixinStmt(nnkIdent("x"))

Bind statement

Concrete syntax:

bind x

AST:

nnkBindStmt(nnkIdent("x"))

Procedure declaration

Let’s take a look at a procedure with a lot of interesting aspects to get a feel for how procedure calls are broken down.

Concrete syntax:

proc hello*[T: SomeInteger](x: int = 3, y: float32): int {.inline.} = discard

AST:

nnkProcDef(
  nnkPostfix(nnkIdent("*"), nnkIdent("hello")), # the exported proc name
  nnkEmpty(), # patterns for term rewriting in templates and macros (not procs)
  nnkGenericParams( # generic type parameters, like with type declaration
    nnkIdentDefs(
      nnkIdent("T"),
      nnkIdent("SomeInteger"),
      nnkEmpty()
    )
  ),
  nnkFormalParams(
    nnkIdent("int"), # the first FormalParam is the return type. nnkEmpty() if there is none
    nnkIdentDefs(
      nnkIdent("x"),
      nnkIdent("int"), # type type (required for procs, not for templates)
      nnkIntLit(3) # a default value
    ),
    nnkIdentDefs(
      nnkIdent("y"),
      nnkIdent("float32"),
      nnkEmpty()
    )
  ),
  nnkPragma(nnkIdent("inline")),
  nnkEmpty(), # reserved slot for future use
  nnkStmtList(nnkDiscardStmt(nnkEmpty())) # the meat of the proc
)

There is another consideration. Nim has flexible type identification for its procs. Even though proc(a: int, b: int) and proc(a, b: int) are equivalent in the code, the AST is a little different for the latter.

Concrete syntax:

proc(a, b: int)

AST:

# ...AST as above...
nnkFormalParams(
  nnkEmpty(), # no return here
  nnkIdentDefs(
    nnkIdent("a"), # the first parameter
    nnkIdent("b"), # directly to the second parameter
    nnkIdent("int"), # their shared type identifier
    nnkEmpty(), # default value would go here
  )
),
# ...

When a procedure uses the special var type return variable, the result is different from that of a var section.

Concrete syntax:

proc hello(): var int

AST:

# ...
nnkFormalParams(
  nnkVarTy(
    nnkIdent("int")
  )
)

Iterator declaration

The syntax for iterators is similar to procs, but with nnkIteratorDef replacing nnkProcDef.

Concrete syntax:

iterator nonsense[T](x: seq[T]): float {.closure.} = ...

AST:

nnkIteratorDef(
  nnkIdent("nonsense"),
  nnkEmpty(),
  ...
)

Converter declaration

A converter is similar to a proc.

Concrete syntax:

converter toBool(x: float): bool

AST:

nnkConverterDef(
  nnkIdent("toBool"),
  # ...
)

Template declaration

Templates (as well as macros, as we’ll see) have a slightly expanded AST when compared to procs and iterators. The reason for this is term-rewriting macros. Notice the nnkEmpty() as the second argument to nnkProcDef and nnkIteratorDef above? That’s where the term-rewriting macros go.

Concrete syntax:

template optOpt{expr1}(a: int): int

AST:

nnkTemplateDef(
  nnkIdent("optOpt"),
  nnkStmtList( # instead of nnkEmpty()
    expr1
  ),
  # follows like a proc or iterator
)

If the template does not have types for its parameters, the type identifiers inside nnkFormalParams just becomes nnkEmpty.

Macro declaration

Macros behave like templates, but nnkTemplateDef is replaced with nnkMacroDef.

Hidden Standard Conversion

var f: float = 1

The type of “f” is float but the type of “1” is actually int. Inserting int into a float is a type error. Nim inserts the nnkHiddenStdConv node around the nnkIntLit node so that the new node has the correct type of float. This works for any auto converted nodes and makes the conversion explicit.

Special node kinds

There are several node kinds that are used for semantic checking or code generation. These are accessible from this module, but should not be used. Other node kinds are especially designed to make AST manipulations easier. These are explained here.

To be written.

Imports

since

Types

BindSymRule = enum
  brClosed,                 ## only the symbols in current scope are bound
  brOpen,                   ## open for overloaded symbols, but may be a single
                             ## symbol if not ambiguous (the rules match that of
                             ## binding in generics)
  brForceOpen                ## same as brOpen, but it will always be open even
                             ## if not ambiguous (this cannot be achieved with
                             ## any other means in the language currently)

Specifies how bindSym behaves. The difference between open and closed symbols can be found in manual.html#symbol-lookup-in-generics-open-and-closed-symbols Source Edit

LineInfo = object
  filename*: string
  line*, column*: int

Source Edit

NimIdent {....deprecated.} = object of RootObj

Deprecated

Represents a Nim identifier in the AST. Note: This is only rarely useful, for identifier construction from a string use ident”abc”. Source Edit

NimNodeKind = enum
  nnkNone, nnkEmpty, nnkIdent, nnkSym, nnkType, nnkCharLit, nnkIntLit,
  nnkInt8Lit, nnkInt16Lit, nnkInt32Lit, nnkInt64Lit, nnkUIntLit, nnkUInt8Lit,
  nnkUInt16Lit, nnkUInt32Lit, nnkUInt64Lit, nnkFloatLit, nnkFloat32Lit,
  nnkFloat64Lit, nnkFloat128Lit, nnkStrLit, nnkRStrLit, nnkTripleStrLit,
  nnkNilLit, nnkComesFrom, nnkDotCall, nnkCommand, nnkCall, nnkCallStrLit,
  nnkInfix, nnkPrefix, nnkPostfix, nnkHiddenCallConv, nnkExprEqExpr,
  nnkExprColonExpr, nnkIdentDefs, nnkVarTuple, nnkPar, nnkObjConstr, nnkCurly,
  nnkCurlyExpr, nnkBracket, nnkBracketExpr, nnkPragmaExpr, nnkRange, nnkDotExpr,
  nnkCheckedFieldExpr, nnkDerefExpr, nnkIfExpr, nnkElifExpr, nnkElseExpr,
  nnkLambda, nnkDo, nnkAccQuoted, nnkTableConstr, nnkBind, nnkClosedSymChoice,
  nnkOpenSymChoice, nnkHiddenStdConv, nnkHiddenSubConv, nnkConv, nnkCast,
  nnkStaticExpr, nnkAddr, nnkHiddenAddr, nnkHiddenDeref, nnkObjDownConv,
  nnkObjUpConv, nnkChckRangeF, nnkChckRange64, nnkChckRange, nnkStringToCString,
  nnkCStringToString, nnkAsgn, nnkFastAsgn, nnkGenericParams, nnkFormalParams,
  nnkOfInherit, nnkImportAs, nnkProcDef, nnkMethodDef, nnkConverterDef,
  nnkMacroDef, nnkTemplateDef, nnkIteratorDef, nnkOfBranch, nnkElifBranch,
  nnkExceptBranch, nnkElse, nnkAsmStmt, nnkPragma, nnkPragmaBlock, nnkIfStmt,
  nnkWhenStmt, nnkForStmt, nnkParForStmt, nnkWhileStmt, nnkCaseStmt,
  nnkTypeSection, nnkVarSection, nnkLetSection, nnkConstSection, nnkConstDef,
  nnkTypeDef, nnkYieldStmt, nnkDefer, nnkTryStmt, nnkFinally, nnkRaiseStmt,
  nnkReturnStmt, nnkBreakStmt, nnkContinueStmt, nnkBlockStmt, nnkStaticStmt,
  nnkDiscardStmt, nnkStmtList, nnkImportStmt, nnkImportExceptStmt,
  nnkExportStmt, nnkExportExceptStmt, nnkFromStmt, nnkIncludeStmt, nnkBindStmt,
  nnkMixinStmt, nnkUsingStmt, nnkCommentStmt, nnkStmtListExpr, nnkBlockExpr,
  nnkStmtListType, nnkBlockType, nnkWith, nnkWithout, nnkTypeOfExpr,
  nnkObjectTy, nnkTupleTy, nnkTupleClassTy, nnkTypeClassTy, nnkStaticTy,
  nnkRecList, nnkRecCase, nnkRecWhen, nnkRefTy, nnkPtrTy, nnkVarTy, nnkConstTy,
  nnkOutTy, nnkDistinctTy, nnkProcTy, nnkIteratorTy, nnkSinkAsgn, nnkEnumTy,
  nnkEnumFieldDef, nnkArgList, nnkPattern, nnkHiddenTryStmt, nnkClosure,
  nnkGotoState, nnkState, nnkBreakState, nnkFuncDef, nnkTupleConstr, nnkError ## erroneous AST node

Source Edit

NimNodeKinds = set[NimNodeKind]

Source Edit

NimSym {....deprecated.} = ref NimSymObj

Deprecated

Represents a Nim symbol in the compiler; a symbol is a looked-up ident. Source Edit

NimSymKind = enum
  nskUnknown, nskConditional, nskDynLib, nskParam, nskGenericParam, nskTemp,
  nskModule, nskType, nskVar, nskLet, nskConst, nskResult, nskProc, nskFunc,
  nskMethod, nskIterator, nskConverter, nskMacro, nskTemplate, nskField,
  nskEnumField, nskForVar, nskLabel, nskStub

Source Edit

NimTypeKind = enum
  ntyNone, ntyBool, ntyChar, ntyEmpty, ntyAlias, ntyNil, ntyExpr, ntyStmt,
  ntyTypeDesc, ntyGenericInvocation, ntyGenericBody, ntyGenericInst,
  ntyGenericParam, ntyDistinct, ntyEnum, ntyOrdinal, ntyArray, ntyObject,
  ntyTuple, ntySet, ntyRange, ntyPtr, ntyRef, ntyVar, ntySequence, ntyProc,
  ntyPointer, ntyOpenArray, ntyString, ntyCString, ntyForward, ntyInt, ntyInt8,
  ntyInt16, ntyInt32, ntyInt64, ntyFloat, ntyFloat32, ntyFloat64, ntyFloat128,
  ntyUInt, ntyUInt8, ntyUInt16, ntyUInt32, ntyUInt64, ntyUnused0, ntyUnused1,
  ntyUnused2, ntyVarargs, ntyUncheckedArray, ntyError, ntyBuiltinTypeClass,
  ntyUserTypeClass, ntyUserTypeClassInst, ntyCompositeTypeClass, ntyInferred,
  ntyAnd, ntyOr, ntyNot, ntyAnything, ntyStatic, ntyFromExpr, ntyOptDeprecated,
  ntyVoid

Source Edit

TNimSymKinds {....deprecated.} = set[NimSymKind]

Deprecated

Source Edit

TNimTypeKinds {....deprecated.} = set[NimTypeKind]

Deprecated

Source Edit

Consts

AtomicNodes = {nnkNone..nnkNilLit}

Source Edit

CallNodes = {nnkCall, nnkInfix, nnkPrefix, nnkPostfix, nnkCommand,
             nnkCallStrLit, nnkHiddenCallConv}

Source Edit

nnkCallKinds = {nnkCall, nnkInfix, nnkPrefix, nnkPostfix, nnkCommand,
                nnkCallStrLit, nnkHiddenCallConv}

Source Edit

nnkLiterals = {nnkCharLit..nnkNilLit}

Source Edit

nnkMutableTy {....deprecated.} = nnkOutTy

Source Edit

nnkSharedTy {....deprecated.} = nnkSinkAsgn

Source Edit

RoutineNodes = {nnkProcDef, nnkFuncDef, nnkMethodDef, nnkDo, nnkLambda,
                nnkIteratorDef, nnkTemplateDef, nnkConverterDef, nnkMacroDef}

Source Edit

Procs

proc `$`(arg: LineInfo): string {....raises: [], tags: [], forbids: [].}

Return a string representation in the form filepath(line, column). Source Edit

proc `$`(i: NimIdent): string {.magic: "NStrVal", noSideEffect, ...deprecated: "Deprecated since version 0.18.1; Use \'strVal\' instead.",
                                raises: [], tags: [], forbids: [].}

Deprecated: Deprecated since version 0.18.1; Use ‘strVal’ instead.

Converts a Nim identifier to a string. Source Edit

proc `$`(node: NimNode): string {....raises: [], tags: [], forbids: [].}

Get the string of an identifier node. Source Edit

proc `$`(s: NimSym): string {.magic: "NStrVal", noSideEffect, ...deprecated: "Deprecated since version 0.18.1; Use \'strVal\' instead.",
                              raises: [], tags: [], forbids: [].}

Deprecated: Deprecated since version 0.18.1; Use ‘strVal’ instead.

Converts a Nim symbol to a string. Source Edit

proc `==`(a, b: NimIdent): bool {.magic: "EqIdent", noSideEffect, ...deprecated: "Deprecated since version 0.18.1; Use \'==\' on \'NimNode\' instead.",
                                  raises: [], tags: [], forbids: [].}

Deprecated: Deprecated since version 0.18.1; Use ‘==’ on ‘NimNode’ instead.

Compares two Nim identifiers. Source Edit

proc `==`(a, b: NimNode): bool {.magic: "EqNimrodNode", noSideEffect,
                                 ...raises: [], tags: [], forbids: [].}

Compare two Nim nodes. Return true if nodes are structurally equivalent. This means two independently created nodes can be equal. Source Edit

proc `==`(a, b: NimSym): bool {.magic: "EqNimrodNode", noSideEffect, ...deprecated: "Deprecated since version 0.18.1; Use \'==(NimNode, NimNode)\' instead.",
                                raises: [], tags: [], forbids: [].}

Deprecated: Deprecated since version 0.18.1; Use ‘==(NimNode, NimNode)’ instead.

Compares two Nim symbols. Source Edit

proc `[]`(n: NimNode; i: BackwardsIndex): NimNode {....raises: [], tags: [],
    forbids: [].}

Get n’s i’th child. Source Edit

proc `[]`(n: NimNode; i: int): NimNode {.magic: "NChild", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Get n’s i’th child. Source Edit

proc `[]`[T, U: Ordinal](n: NimNode; x: HSlice[T, U]): seq[NimNode]

Slice operation for NimNode. Returns a seq of child of n who inclusive range [n[x.a], n[x.b]]. Source Edit

proc `[]=`(n: NimNode; i: BackwardsIndex; child: NimNode) {....raises: [],
    tags: [], forbids: [].}

Set n’s i’th child to child. Source Edit

proc `[]=`(n: NimNode; i: int; child: NimNode) {.magic: "NSetChild",
    noSideEffect, ...raises: [], tags: [], forbids: [].}

Set n’s i’th child to child. Source Edit

proc add(father, child: NimNode): NimNode {.magic: "NAdd", discardable,
    noSideEffect, ...raises: [], tags: [], forbids: [].}

Adds the child to the father node. Returns the father node so that calls can be nested. Source Edit

proc add(father: NimNode; children: varargs[NimNode]): NimNode {.
    magic: "NAddMultiple", discardable, noSideEffect, ...raises: [], tags: [],
    forbids: [].}

Adds each child of children to the father node. Returns the father node so that calls can be nested. Source Edit

proc addIdentIfAbsent(dest: NimNode; ident: string) {....raises: [], tags: [],
    forbids: [].}

Add ident to dest if it is not present. This is intended for use with pragmas. Source Edit

proc addPragma(someProc, pragma: NimNode) {....raises: [], tags: [], forbids: [].}

Adds pragma to routine definition. Source Edit

proc astGenRepr(n: NimNode): string {....gcsafe, raises: [], tags: [], forbids: [].}

Convert the AST n to the code required to generate that AST.

See also system: repr, treeRepr, and lispRepr.

Source Edit

proc basename(a: NimNode): NimNode {....raises: [], tags: [], forbids: [].}

Pull an identifier from prefix/postfix expressions. Source Edit

proc basename=(a: NimNode; val: string) {....raises: [], tags: [], forbids: [].}

Source Edit

proc bindSym(ident: string | NimNode; rule: BindSymRule = brClosed): NimNode {.
    magic: "NBindSym", noSideEffect, ...raises: [], tags: [], forbids: [].}

Creates a node that binds ident to a symbol node. The bound symbol may be an overloaded symbol. if ident is a NimNode, it must have nnkIdent kind. If rule == brClosed either an nnkClosedSymChoice tree is returned or nnkSym if the symbol is not ambiguous. If rule == brOpen either an nnkOpenSymChoice tree is returned or nnkSym if the symbol is not ambiguous. If rule == brForceOpen always an nnkOpenSymChoice tree is returned even if the symbol is not ambiguous.

See the manual for more details.

Source Edit

proc body(someProc: NimNode): NimNode {....raises: [], tags: [], forbids: [].}

Source Edit

proc body=(someProc: NimNode; val: NimNode) {....raises: [], tags: [], forbids: [].}

Source Edit

proc boolVal(n: NimNode): bool {.noSideEffect, ...raises: [], tags: [], forbids: [].}

Source Edit

proc callsite(): NimNode {.magic: "NCallSite", ...gcsafe, deprecated: "Deprecated since v0.18.1; use `varargs[untyped]` in the macro prototype instead",
                           raises: [], tags: [], forbids: [].}

Deprecated: Deprecated since v0.18.1; use `varargs[untyped]` in the macro prototype instead

Returns the AST of the invocation expression that invoked this macro. Source Edit

proc copy(node: NimNode): NimNode {....raises: [], tags: [], forbids: [].}

An alias for copyNimTree. Source Edit

proc copyChildrenTo(src, dest: NimNode) {....raises: [], tags: [], forbids: [].}

Copy all children from src to dest. Source Edit

proc copyLineInfo(arg: NimNode; info: NimNode) {.magic: "NLineInfo",
    noSideEffect, ...raises: [], tags: [], forbids: [].}

Copy lineinfo from info. Source Edit

proc copyNimNode(n: NimNode): NimNode {.magic: "NCopyNimNode", noSideEffect,
                                        ...raises: [], tags: [], forbids: [].}

Creates a new AST node by copying the node n. Note that unlike copyNimTree, child nodes of n are not copied.

Example:

macro foo(x: typed) =
  var s = copyNimNode(x)
  doAssert s.len == 0
  doAssert s.kind == nnkStmtList
foo:
  let x = 12
  echo x

Source Edit

proc copyNimTree(n: NimNode): NimNode {.magic: "NCopyNimTree", noSideEffect,
                                        ...raises: [], tags: [], forbids: [].}

Creates a new AST node by recursively copying the node n. Note that unlike copyNimNode, this copies n, the children of n, etc.

Example:

macro foo(x: typed) =
  var s = copyNimTree(x)
  doAssert s.len == 2
  doAssert s.kind == nnkStmtList
foo:
  let x = 12
  echo x

Source Edit

proc del(father: NimNode; idx = 0; n = 1) {.magic: "NDel", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Deletes n children of father starting at index idx. Source Edit

proc eqIdent(a: NimNode; b: NimNode): bool {.magic: "EqIdent", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Style insensitive comparison. a and b can be an identifier or a symbol. Both may be wrapped in an export marker (nnkPostfix) or quoted with backticks (nnkAccQuoted), these nodes will be unwrapped. Source Edit

proc eqIdent(a: NimNode; b: string): bool {.magic: "EqIdent", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Style insensitive comparison. a can be an identifier or a symbol. a may be wrapped in an export marker (nnkPostfix) or quoted with backticks (nnkAccQuoted), these nodes will be unwrapped. Source Edit

proc eqIdent(a: string; b: NimNode): bool {.magic: "EqIdent", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Style insensitive comparison. b can be an identifier or a symbol. b may be wrapped in an export marker (nnkPostfix) or quoted with backticks (nnkAccQuoted), these nodes will be unwrapped. Source Edit

proc eqIdent(a: string; b: string): bool {.magic: "EqIdent", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Style insensitive comparison. Source Edit

proc error(msg: string; n: NimNode = nil) {.magic: "NError", ...gcsafe, noreturn,
    ...raises: [], tags: [], forbids: [].}

Writes an error message at compile time. The optional n: NimNode parameter is used as the source for file and line number information in the compilation error message. Source Edit

proc expectIdent(n: NimNode; name: string) {....raises: [], tags: [], forbids: [].}

Check that eqIdent(n,name) holds true. If this is not the case, compilation aborts with an error message. This is useful for writing macros that check the AST that is passed to them. Source Edit

proc expectKind(n: NimNode; k: NimNodeKind) {....raises: [], tags: [], forbids: [].}

Checks that n is of kind k. If this is not the case, compilation aborts with an error message. This is useful for writing macros that check the AST that is passed to them. Source Edit

proc expectKind(n: NimNode; k: set[NimNodeKind]) {....raises: [], tags: [],
    forbids: [].}

Checks that n is of kind k. If this is not the case, compilation aborts with an error message. This is useful for writing macros that check the AST that is passed to them. Source Edit

proc expectLen(n: NimNode; len: int) {....raises: [], tags: [], forbids: [].}

Checks that n has exactly len children. If this is not the case, compilation aborts with an error message. This is useful for writing macros that check its number of arguments. Source Edit

proc expectLen(n: NimNode; min, max: int) {....raises: [], tags: [], forbids: [].}

Checks that n has a number of children in the range min..max. If this is not the case, compilation aborts with an error message. This is useful for writing macros that check its number of arguments. Source Edit

proc expectMinLen(n: NimNode; min: int) {....raises: [], tags: [], forbids: [].}

Checks that n has at least min children. If this is not the case, compilation aborts with an error message. This is useful for writing macros that check its number of arguments. Source Edit

proc extractDocCommentsAndRunnables(n: NimNode): NimNode {....raises: [], tags: [],
    forbids: [].}

returns a nnkStmtList containing the top-level doc comments and runnableExamples in a, stopping at the first child that is neither. Example:

import std/macros
macro transf(a): untyped =
  result = quote do:
    proc fun2*() = discard
  let header = extractDocCommentsAndRunnables(a.body)
  # correct usage: rest is appended
  result.body = header
  result.body.add quote do: discard # just an example
  # incorrect usage: nesting inside a nnkStmtList:
  # result.body = quote do: (`header`; discard)
proc fun*() {.transf.} =
  ## first comment
  runnableExamples: discard
  runnableExamples: discard
  ## last comment
  discard # first statement after doc comments + runnableExamples
  ## not docgen'd

Source Edit

proc floatVal(n: NimNode): BiggestFloat {.magic: "NFloatVal", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Returns a float from any floating point literal. Source Edit

proc floatVal=(n: NimNode; val: BiggestFloat) {.magic: "NSetFloatVal",
    noSideEffect, ...raises: [], tags: [], forbids: [].}

Source Edit

proc genSym(kind: NimSymKind = nskLet; ident = ""): NimNode {.magic: "NGenSym",
    noSideEffect, ...raises: [], tags: [], forbids: [].}

Generates a fresh symbol that is guaranteed to be unique. The symbol needs to occur in a declaration context. Source Edit

proc getAlign(arg: NimNode): int {.magic: "NSizeOf", noSideEffect, ...raises: [],
                                   tags: [], forbids: [].}

Returns the same result as system.alignof if the alignment is known by the Nim compiler. It works on NimNode for use in macro context. Returns a negative value if the Nim compiler does not know the alignment. Source Edit

proc getAst(macroOrTemplate: untyped): NimNode {.magic: "ExpandToAst",
    noSideEffect, ...raises: [], tags: [], forbids: [].}

Obtains the AST nodes returned from a macro or template invocation. See also genasts.genAst. Example:

macro FooMacro() =
  var ast = getAst(BarTemplate())

Source Edit

proc getImpl(s: NimSym): NimNode {.magic: "GetImpl", noSideEffect, ...deprecated: "use `getImpl: NimNode -> NimNode` instead",
                                   raises: [], tags: [], forbids: [].}

Deprecated: use `getImpl: NimNode -> NimNode` instead

Source Edit

proc getImpl(symbol: NimNode): NimNode {.magic: "GetImpl", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Returns a copy of the declaration of a symbol or nil. Source Edit

proc getImplTransformed(symbol: NimNode): NimNode {.magic: "GetImplTransf",
    noSideEffect, ...raises: [], tags: [], forbids: [].}

For a typed proc returns the AST after transformation pass; this is useful for debugging how the compiler transforms code (e.g.: defer, for) but note that code transformations are implementation dependent and subject to change. See an example in tests/macros/tmacros_various.nim. Source Edit

proc getOffset(arg: NimNode): int {.magic: "NSizeOf", noSideEffect, ...raises: [],
                                    tags: [], forbids: [].}

Returns the same result as system.offsetof if the offset is known by the Nim compiler. It expects a resolved symbol node from a field of a type. Therefore it only requires one argument instead of two. Returns a negative value if the Nim compiler does not know the offset. Source Edit

proc getProjectPath(): string {....raises: [], tags: [], forbids: [].}

Returns the path to the currently compiling project.

This is not to be confused with system.currentSourcePath which returns the path of the source file containing that template call.

For example, assume a dir1/foo.nim that imports a dir2/bar.nim, have the bar.nim print out both getProjectPath and currentSourcePath outputs.

Now when foo.nim is compiled, the getProjectPath from bar.nim will return the dir1/ path, while the currentSourcePath will return the path to the bar.nim source file.

Now when bar.nim is compiled directly, the getProjectPath will now return the dir2/ path, and the currentSourcePath will still return the same path, the path to the bar.nim source file.

The path returned by this proc is set at compile time.

See also:

• getCurrentDir proc

Source Edit

proc getSize(arg: NimNode): int {.magic: "NSizeOf", noSideEffect, ...raises: [],
                                  tags: [], forbids: [].}

Returns the same result as system.sizeof if the size is known by the Nim compiler. Returns a negative value if the Nim compiler does not know the size. Source Edit

proc getType(n: NimNode): NimNode {.magic: "NGetType", noSideEffect, ...raises: [],
                                    tags: [], forbids: [].}

With ‘getType’ you can access the node’s type. A Nim type is mapped to a Nim AST too, so it’s slightly confusing but it means the same API can be used to traverse types. Recursive types are flattened for you so there is no danger of infinite recursions during traversal. To resolve recursive types, you have to call ‘getType’ again. To see what kind of type it is, call typeKind on getType’s result. Source Edit

proc getType(n: typedesc): NimNode {.magic: "NGetType", noSideEffect,
                                     ...raises: [], tags: [], forbids: [].}

Version of getType which takes a typedesc. Source Edit

proc getTypeImpl(n: NimNode): NimNode {.magic: "NGetType", noSideEffect,
                                        ...raises: [], tags: [], forbids: [].}

Returns the type of a node in a form matching the implementation of the type. Any intermediate aliases are expanded to arrive at the final type implementation. You can instead use getImpl on a symbol if you want to find the intermediate aliases.

Example:

type
  Vec[N: static[int], T] = object
    arr: array[N, T]
  Vec4[T] = Vec[4, T]
  Vec4f = Vec4[float32]
var a: Vec4f
var b: Vec4[float32]
var c: Vec[4, float32]
macro dumpTypeImpl(x: typed): untyped =
  newLit(x.getTypeImpl.repr)
let t = """
object
  arr: array[0 .. 3, float32]"""
doAssert(dumpTypeImpl(a) == t)
doAssert(dumpTypeImpl(b) == t)
doAssert(dumpTypeImpl(c) == t)

Source Edit

proc getTypeImpl(n: typedesc): NimNode {.magic: "NGetType", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Version of getTypeImpl which takes a typedesc. Source Edit

proc getTypeInst(n: NimNode): NimNode {.magic: "NGetType", noSideEffect,
                                        ...raises: [], tags: [], forbids: [].}

Returns the type of a node in a form matching the way the type instance was declared in the code.

Example:

type
  Vec[N: static[int], T] = object
    arr: array[N, T]
  Vec4[T] = Vec[4, T]
  Vec4f = Vec4[float32]
var a: Vec4f
var b: Vec4[float32]
var c: Vec[4, float32]
macro dumpTypeInst(x: typed): untyped =
  newLit(x.getTypeInst.repr)
doAssert(dumpTypeInst(a) == "Vec4f")
doAssert(dumpTypeInst(b) == "Vec4[float32]")
doAssert(dumpTypeInst(c) == "Vec[4, float32]")

Source Edit

proc getTypeInst(n: typedesc): NimNode {.magic: "NGetType", noSideEffect,
    ...raises: [], tags: [], forbids: [].}

Version of getTypeInst which takes a typedesc. Source Edit

proc hasArgOfName(params: NimNode; name: string): bool {....raises: [], tags: [],
    forbids: [].}

Search nnkFormalParams for an argument. Source Edit

proc hint(msg: string; n: NimNode = nil) {.magic: "NHint", ...gcsafe, raises: [],
    tags: [], forbids: [].}