Grammar

This is the complete syntax grammar for Luau in EBNF. More information about the terminal nodes String and Number is available in the syntax section.

  1. chunk = block
  2. block = {stat [';']} [laststat [';']]
  3. stat = varlist '=' explist |
  4.     var compoundop exp |
  5.     functioncall |
  6.     'do' block 'end' |
  7.     'while' exp 'do' block 'end' |
  8.     'repeat' block 'until' exp |
  9.     'if' exp 'then' block {'elseif' exp 'then' block} ['else' block] 'end' |
  10.     'for' binding '=' exp ',' exp [',' exp] 'do' block 'end' |
  11.     'for' bindinglist 'in' explist 'do' block 'end' |
  12.     'function' funcname funcbody |
  13.     'local' 'function' NAME funcbody |
  14.     'local' bindinglist ['=' explist] |
  15.     ['export'] 'type' NAME ['<' GenericTypeParameterList '>'] '=' Type
  17. laststat = 'return' [explist] | 'break' | 'continue'
  19. funcname = NAME {'.' NAME} [':' NAME]
  20. funcbody = ['<' GenericTypeParameterList '>'] '(' [parlist] ')' [':' ReturnType] block 'end'
  21. parlist = bindinglist [',' '...'] | '...'
  23. explist = {exp ','} exp
  24. namelist = NAME {',' NAME}
  26. binding = NAME [':' TypeAnnotation]
  27. bindinglist = binding [',' bindinglist] (* equivalent of Lua 5.1 'namelist', except with optional type annotations *)
  29. var = NAME | prefixexp '[' exp ']' | prefixexp '.' Name
  30. varlist = var {',' var}
  31. prefixexp = var | functioncall | '(' exp ')'
  32. functioncall = prefixexp funcargs | prefixexp ':' NAME funcargs
  34. exp = (asexp | unop exp) { binop exp }
  35. ifelseexp = 'if' exp 'then' exp {'elseif' exp 'then' exp} 'else' exp
  36. asexp = simpleexp ['::' Type]
  37. simpleexp = NUMBER | STRING | 'nil' | 'true' | 'false' | '...' | tableconstructor | 'function' body | prefixexp | ifelseexp
  38. funcargs =  '(' [explist] ')' | tableconstructor | STRING
  40. tableconstructor = '{' [fieldlist] '}'
  41. fieldlist = field {fieldsep field} [fieldsep]
  42. field = '[' exp ']' '=' exp | NAME '=' exp | exp
  43. fieldsep = ',' | ';'
  45. compoundop :: '+=' | '-=' | '*=' | '/=' | '%=' | '^=' | '..='
  46. binop = '+' | '-' | '*' | '/' | '^' | '%' | '..' | '<' | '<=' | '>' | '>=' | '==' | '~=' | 'and' | 'or'
  47. unop = '-' | 'not' | '#'
  49. SimpleType =
  50.     'nil' |
  51.     SingletonType |
  52.     NAME ['.' NAME] [ '<' [TypeParams] '>' ] |
  53.     'typeof' '(' exp ')' |
  54.     TableType |
  55.     FunctionType
  57. SingletonType = STRING | 'true' | 'false'
  59. Type =
  60.     SimpleType ['?'] |
  61.     Type ['|' Type] |
  62.     Type ['&' Type]
  64. GenericTypePackParameter = NAME '...' ['=' (TypePack | VariadicTypePack | GenericTypePack)]
  65. GenericTypeParameterList = NAME ['=' Type] [',' GenericTypeParameterList] | GenericTypePackParameter {',' GenericTypePackParameter}
  66. TypeList = Type [',' TypeList] | '...' Type
  67. TypeParams = (Type | TypePack | VariadicTypePack | GenericTypePack) [',' TypeParams]
  68. TypePack = '(' [TypeList] ')'
  69. GenericTypePack = NAME '...'
  70. VariadicTypePack = '...' Type
  71. ReturnType = Type | TypePack
  72. TableIndexer = '[' Type ']' ':' Type
  73. TableProp = NAME ':' Type
  74. TablePropOrIndexer = TableProp | TableIndexer
  75. PropList = TablePropOrIndexer {fieldsep TablePropOrIndexer} [fieldsep]
  76. TableType = '{' PropList '}'
  77. FunctionType = ['<' GenericTypeList '>'] '(' [TypeList] ')' '->' ReturnType