Frequently Asked Questions

Sessions and the REPL

How do I delete an object in memory?

Julia does not have an analog of MATLAB’s clear function; once a name is defined in a Julia session (technically, in module Main), it is always present.

If memory usage is your concern, you can always replace objects with ones that consume less memory. For example, if A is a gigabyte-sized array that you no longer need, you can free the memory with A = nothing. The memory will be released the next time the garbage collector runs; you can force this to happen with gc(). Moreover, an attempt to use A will likely result in an error, because most methods are not defined on type Nothing.

How can I modify the declaration of a type in my session?

Perhaps you’ve defined a type and then realize you need to add a new field. If you try this at the REPL, you get the error:

  1. ERROR: invalid redefinition of constant MyType

Types in module Main cannot be redefined.

While this can be inconvenient when you are developing new code, there’s an excellent workaround. Modules can be replaced by redefining them, and so if you wrap all your new code inside a module you can redefine types and constants. You can’t import the type names into Main and then expect to be able to redefine them there, but you can use the module name to resolve the scope. In other words, while developing you might use a workflow something like this:

  1. include("mynewcode.jl")              # this defines a module MyModule
  2. obj1 = MyModule.ObjConstructor(a, b)
  3. obj2 = MyModule.somefunction(obj1)
  4. # Got an error. Change something in "mynewcode.jl"
  5. include("mynewcode.jl")              # reload the module
  6. obj1 = MyModule.ObjConstructor(a, b) # old objects are no longer valid, must reconstruct
  7. obj2 = MyModule.somefunction(obj1)   # this time it worked!
  8. obj3 = MyModule.someotherfunction(obj2, c)
  9. ...

Scripting

How do I check if the current file is being run as the main script?

When a file is run as the main script using julia file.jl one might want to activate extra functionality like command line argument handling. A way to determine that a file is run in this fashion is to check if abspath(PROGRAM_FILE) == @__FILE__ is true.

How do I catch CTRL-C in a script?

Running a Julia script using julia file.jl does not throw InterruptException when you try to terminate it with CTRL-C (SIGINT). To run a certain code before terminating a Julia script, which may or may not be caused by CTRL-C, use atexit. Alternatively, you can use julia -e 'include(popfirst!(ARGS))' file.jl to execute a script while being able to catch InterruptException in the try block.

How do I pass options to julia using #!/usr/bin/env?

Passing options to julia in so-called shebang by, e.g., #!/usr/bin/env julia --startup-file=no may not work in some platforms such as Linux. This is because argument parsing in shebang is platform-dependent and not well-specified. In a Unix-like environment, a reliable way to pass options to julia in an executable script would be to start the script as a bash script and use exec to replace the process to julia:

  1. #!/bin/bash
  2. #=
  3. exec julia --color=yes --startup-file=no -e 'include(popfirst!(ARGS))' \
  4.     "${BASH_SOURCE[0]}" "$@"
  5. =#
  7. @show ARGS  # put any Julia code here

In the example above, the code between #= and =# is run as a bash script. Julia ignores this part since it is a multi-line comment for Julia. The Julia code after =# is ignored by bash since it stops parsing the file once it reaches to the exec statement.

Functions

I passed an argument x to a function, modified it inside that function, but on the outside, the variable x is still unchanged. Why?

Suppose you call a function like this:

  1. julia> x = 10
  2. 10
  4. julia> function change_value!(y)
  5.            y = 17
  6.        end
  7. change_value! (generic function with 1 method)
  9. julia> change_value!(x)
  10. 17
  12. julia> x # x is unchanged!
  13. 10

In Julia, the binding of a variable x cannot be changed by passing x as an argument to a function. When calling change_value!(x) in the above example, y is a newly created variable, bound initially to the value of x, i.e. 10; then y is rebound to the constant 17, while the variable x of the outer scope is left untouched.

But here is a thing you should pay attention to: suppose x is bound to an object of type Array (or any other mutable type). From within the function, you cannot “unbind” x from this Array, but you can change its content. For example:

  1. julia> x = [1,2,3]
  2. 3-element Array{Int64,1}:
  3.  1
  4.  2
  5.  3
  7. julia> function change_array!(A)
  8.            A[1] = 5
  9.        end
  10. change_array! (generic function with 1 method)
  12. julia> change_array!(x)
  13. 5
  15. julia> x
  16. 3-element Array{Int64,1}:
  17.  5
  18.  2
  19.  3

Here we created a function change_array!, that assigns 5 to the first element of the passed array (bound to x at the call site, and bound to A within the function). Notice that, after the function call, x is still bound to the same array, but the content of that array changed: the variables A and x were distinct bindings referring to the same mutable Array object.

Can I use using or import inside a function?

No, you are not allowed to have a using or import statement inside a function. If you want to import a module but only use its symbols inside a specific function or set of functions, you have two options:

  1. Use import:

    1. import Foo
    2. function bar(...)
    3.     # ... refer to Foo symbols via Foo.baz ...
    4. end

    This loads the module Foo and defines a variable Foo that refers to the module, but does not import any of the other symbols from the module into the current namespace. You refer to the Foo symbols by their qualified names Foo.bar etc.

  2. Wrap your function in a module:

    1. module Bar
    2. export bar
    3. using Foo
    4. function bar(...)
    5.     # ... refer to Foo.baz as simply baz ....
    6. end
    7. end
    8. using Bar

    This imports all the symbols from Foo, but only inside the module Bar.

What does the … operator do?

The two uses of the … operator: slurping and splatting

Many newcomers to Julia find the use of ... operator confusing. Part of what makes the ... operator confusing is that it means two different things depending on context.

… combines many arguments into one argument in function definitions

In the context of function definitions, the ... operator is used to combine many different arguments into a single argument. This use of ... for combining many different arguments into a single argument is called slurping:

  1. julia> function printargs(args...)
  2.            println(typeof(args))
  3.            for (i, arg) in enumerate(args)
  4.                println("Arg #$i = $arg")
  5.            end
  6.        end
  7. printargs (generic function with 1 method)
  9. julia> printargs(1, 2, 3)
  10. Tuple{Int64,Int64,Int64}
  11. Arg #1 = 1
  12. Arg #2 = 2
  13. Arg #3 = 3

If Julia were a language that made more liberal use of ASCII characters, the slurping operator might have been written as <-... instead of ....

… splits one argument into many different arguments in function calls

In contrast to the use of the ... operator to denote slurping many different arguments into one argument when defining a function, the ... operator is also used to cause a single function argument to be split apart into many different arguments when used in the context of a function call. This use of ... is called splatting:

  1. julia> function threeargs(a, b, c)
  2.            println("a = $a::$(typeof(a))")
  3.            println("b = $b::$(typeof(b))")
  4.            println("c = $c::$(typeof(c))")
  5.        end
  6. threeargs (generic function with 1 method)
  8. julia> x = [1, 2, 3]
  9. 3-element Array{Int64,1}:
  10.  1
  11.  2
  12.  3
  14. julia> threeargs(x...)
  15. a = 1::Int64
  16. b = 2::Int64
  17. c = 3::Int64

If Julia were a language that made more liberal use of ASCII characters, the splatting operator might have been written as ...-> instead of ....

What is the return value of an assignment?

The operator = always returns the right-hand side, therefore:

  1. julia> function threeint()
  2.            x::Int = 3.0
  3.            x # returns variable x
  4.        end
  5. threeint (generic function with 1 method)
  7. julia> function threefloat()
  8.            x::Int = 3.0 # returns 3.0
  9.        end
  10. threefloat (generic function with 1 method)
  12. julia> threeint()
  13. 3
  15. julia> threefloat()
  16. 3.0

and similarly:

  1. julia> function threetup()
  2.            x, y = [3, 3]
  3.            x, y # returns a tuple
  4.        end
  5. threetup (generic function with 1 method)
  7. julia> function threearr()
  8.            x, y = [3, 3] # returns an array
  9.        end
  10. threearr (generic function with 1 method)
  12. julia> threetup()
  13. (3, 3)
  15. julia> threearr()
  16. 2-element Array{Int64,1}:
  17.  3
  18.  3

Types, type declarations, and constructors

What does “type-stable” mean?

It means that the type of the output is predictable from the types of the inputs. In particular, it means that the type of the output cannot vary depending on the values of the inputs. The following code is not type-stable:

  1. julia> function unstable(flag::Bool)
  2.            if flag
  3.                return 1
  4.            else
  5.                return 1.0
  6.            end
  7.        end
  8. unstable (generic function with 1 method)

It returns either an Int or a Float64 depending on the value of its argument. Since Julia can’t predict the return type of this function at compile-time, any computation that uses it will have to guard against both types possibly occurring, making generation of fast machine code difficult.

Why does Julia give a DomainError for certain seemingly-sensible operations?

Certain operations make mathematical sense but result in errors:

  1. julia> sqrt(-2.0)
  2. ERROR: DomainError with -2.0:
  3. sqrt will only return a complex result if called with a complex argument. Try sqrt(Complex(x)).
  4. Stacktrace:
  5. [...]

This behavior is an inconvenient consequence of the requirement for type-stability. In the case of sqrt, most users want sqrt(2.0) to give a real number, and would be unhappy if it produced the complex number 1.4142135623730951 + 0.0im. One could write the sqrt function to switch to a complex-valued output only when passed a negative number (which is what sqrt does in some other languages), but then the result would not be type-stable and the sqrt function would have poor performance.

In these and other cases, you can get the result you want by choosing an input type that conveys your willingness to accept an output type in which the result can be represented:

  1. julia> sqrt(-2.0+0im)
  2. 0.0 + 1.4142135623730951im

Why does Julia use native machine integer arithmetic?

Julia uses machine arithmetic for integer computations. This means that the range of Int values is bounded and wraps around at either end so that adding, subtracting and multiplying integers can overflow or underflow, leading to some results that can be unsettling at first:

  1. julia> typemax(Int)
  2. 9223372036854775807
  4. julia> ans+1
  5. -9223372036854775808
  7. julia> -ans
  8. -9223372036854775808
  10. julia> 2*ans
  11. 0

Clearly, this is far from the way mathematical integers behave, and you might think it less than ideal for a high-level programming language to expose this to the user. For numerical work where efficiency and transparency are at a premium, however, the alternatives are worse.

One alternative to consider would be to check each integer operation for overflow and promote results to bigger integer types such as Int128 or BigInt in the case of overflow. Unfortunately, this introduces major overhead on every integer operation (think incrementing a loop counter) – it requires emitting code to perform run-time overflow checks after arithmetic instructions and branches to handle potential overflows. Worse still, this would cause every computation involving integers to be type-unstable. As we mentioned above, type-stability is crucial for effective generation of efficient code. If you can’t count on the results of integer operations being integers, it’s impossible to generate fast, simple code the way C and Fortran compilers do.

A variation on this approach, which avoids the appearance of type instability is to merge the Int and BigInt types into a single hybrid integer type, that internally changes representation when a result no longer fits into the size of a machine integer. While this superficially avoids type-instability at the level of Julia code, it just sweeps the problem under the rug by foisting all of the same difficulties onto the C code implementing this hybrid integer type. This approach can be made to work and can even be made quite fast in many cases, but has several drawbacks. One problem is that the in-memory representation of integers and arrays of integers no longer match the natural representation used by C, Fortran and other languages with native machine integers. Thus, to interoperate with those languages, we would ultimately need to introduce native integer types anyway. Any unbounded representation of integers cannot have a fixed number of bits, and thus cannot be stored inline in an array with fixed-size slots – large integer values will always require separate heap-allocated storage. And of course, no matter how clever a hybrid integer implementation one uses, there are always performance traps – situations where performance degrades unexpectedly. Complex representation, lack of interoperability with C and Fortran, the inability to represent integer arrays without additional heap storage, and unpredictable performance characteristics make even the cleverest hybrid integer implementations a poor choice for high-performance numerical work.

An alternative to using hybrid integers or promoting to BigInts is to use saturating integer arithmetic, where adding to the largest integer value leaves it unchanged and likewise for subtracting from the smallest integer value. This is precisely what Matlab™ does:

  1. >> int64(9223372036854775807)
  3. ans =
  5.   9223372036854775807
  7. >> int64(9223372036854775807) + 1
  9. ans =
  11.   9223372036854775807
  13. >> int64(-9223372036854775808)
  15. ans =
  17.  -9223372036854775808
  19. >> int64(-9223372036854775808) - 1
  21. ans =
  23.  -9223372036854775808

At first blush, this seems reasonable enough since 9223372036854775807 is much closer to 9223372036854775808 than -9223372036854775808 is and integers are still represented with a fixed size in a natural way that is compatible with C and Fortran. Saturated integer arithmetic, however, is deeply problematic. The first and most obvious issue is that this is not the way machine integer arithmetic works, so implementing saturated operations requires emitting instructions after each machine integer operation to check for underflow or overflow and replace the result with typemin(Int) or typemax(Int) as appropriate. This alone expands each integer operation from a single, fast instruction into half a dozen instructions, probably including branches. Ouch. But it gets worse – saturating integer arithmetic isn’t associative. Consider this Matlab computation:

  1. >> n = int64(2)^62
  2. 4611686018427387904
  4. >> n + (n - 1)
  5. 9223372036854775807
  7. >> (n + n) - 1
  8. 9223372036854775806

This makes it hard to write many basic integer algorithms since a lot of common techniques depend on the fact that machine addition with overflow is associative. Consider finding the midpoint between integer values lo and hi in Julia using the expression (lo + hi) >>> 1:

  1. julia> n = 2^62
  2. 4611686018427387904
  4. julia> (n + 2n) >>> 1
  5. 6917529027641081856

See? No problem. That’s the correct midpoint between 2^62 and 2^63, despite the fact that n + 2n is -4611686018427387904. Now try it in Matlab:

  1. >> (n + 2*n)/2
  3. ans =
  5.   4611686018427387904

Oops. Adding a >>> operator to Matlab wouldn’t help, because saturation that occurs when adding n and 2n has already destroyed the information necessary to compute the correct midpoint.

Not only is lack of associativity unfortunate for programmers who cannot rely it for techniques like this, but it also defeats almost anything compilers might want to do to optimize integer arithmetic. For example, since Julia integers use normal machine integer arithmetic, LLVM is free to aggressively optimize simple little functions like f(k) = 5k-1. The machine code for this function is just this:

  1. julia> code_native(f, Tuple{Int})
  2.   .text
  3. Filename: none
  4.   pushq %rbp
  5.   movq  %rsp, %rbp
  6. Source line: 1
  7.   leaq  -1(%rdi,%rdi,4), %rax
  8.   popq  %rbp
  9.   retq
  10.   nopl  (%rax,%rax)

The actual body of the function is a single leaq instruction, which computes the integer multiply and add at once. This is even more beneficial when f gets inlined into another function:

  1. julia> function g(k, n)
  2.            for i = 1:n
  3.                k = f(k)
  4.            end
  5.            return k
  6.        end
  7. g (generic function with 1 methods)
  9. julia> code_native(g, Tuple{Int,Int})
  10.   .text
  11. Filename: none
  12.   pushq %rbp
  13.   movq  %rsp, %rbp
  14. Source line: 2
  15.   testq %rsi, %rsi
  16.   jle L26
  17.   nopl  (%rax)
  18. Source line: 3
  19. L16:
  20.   leaq  -1(%rdi,%rdi,4), %rdi
  21. Source line: 2
  22.   decq  %rsi
  23.   jne L16
  24. Source line: 5
  25. L26:
  26.   movq  %rdi, %rax
  27.   popq  %rbp
  28.   retq
  29.   nop

Since the call to f gets inlined, the loop body ends up being just a single leaq instruction. Next, consider what happens if we make the number of loop iterations fixed:

  1. julia> function g(k)
  2.            for i = 1:10
  3.                k = f(k)
  4.            end
  5.            return k
  6.        end
  7. g (generic function with 2 methods)
  9. julia> code_native(g,(Int,))
  10.   .text
  11. Filename: none
  12.   pushq %rbp
  13.   movq  %rsp, %rbp
  14. Source line: 3
  15.   imulq $9765625, %rdi, %rax    # imm = 0x9502F9
  16.   addq  $-2441406, %rax         # imm = 0xFFDABF42
  17. Source line: 5
  18.   popq  %rbp
  19.   retq
  20.   nopw  %cs:(%rax,%rax)

Because the compiler knows that integer addition and multiplication are associative and that multiplication distributes over addition – neither of which is true of saturating arithmetic – it can optimize the entire loop down to just a multiply and an add. Saturated arithmetic completely defeats this kind of optimization since associativity and distributivity can fail at each loop iteration, causing different outcomes depending on which iteration the failure occurs in. The compiler can unroll the loop, but it cannot algebraically reduce multiple operations into fewer equivalent operations.

The most reasonable alternative to having integer arithmetic silently overflow is to do checked arithmetic everywhere, raising errors when adds, subtracts, and multiplies overflow, producing values that are not value-correct. In this blog post, Dan Luu analyzes this and finds that rather than the trivial cost that this approach should in theory have, it ends up having a substantial cost due to compilers (LLVM and GCC) not gracefully optimizing around the added overflow checks. If this improves in the future, we could consider defaulting to checked integer arithmetic in Julia, but for now, we have to live with the possibility of overflow.

What are the possible causes of an UndefVarError during remote execution?

As the error states, an immediate cause of an UndefVarError on a remote node is that a binding by that name does not exist. Let us explore some of the possible causes.

  1. julia> module Foo
  2.            foo() = remotecall_fetch(x->x, 2, "Hello")
  3.        end
  5. julia> Foo.foo()
  6. ERROR: On worker 2:
  7. UndefVarError: Foo not defined
  8. Stacktrace:
  9. [...]

The closure x->x carries a reference to Foo, and since Foo is unavailable on node 2, an UndefVarError is thrown.

Globals under modules other than Main are not serialized by value to the remote node. Only a reference is sent. Functions which create global bindings (except under Main) may cause an UndefVarError to be thrown later.

  1. julia> @everywhere module Foo
  2.            function foo()
  3.                global gvar = "Hello"
  4.                remotecall_fetch(()->gvar, 2)
  5.            end
  6.        end
  8. julia> Foo.foo()
  9. ERROR: On worker 2:
  10. UndefVarError: gvar not defined
  11. Stacktrace:
  12. [...]

In the above example, @everywhere module Foo defined Foo on all nodes. However the call to Foo.foo() created a new global binding gvar on the local node, but this was not found on node 2 resulting in an UndefVarError error.

Note that this does not apply to globals created under module Main. Globals under module Main are serialized and new bindings created under Main on the remote node.

  1. julia> gvar_self = "Node1"
  2. "Node1"
  4. julia> remotecall_fetch(()->gvar_self, 2)
  5. "Node1"
  7. julia> remotecall_fetch(varinfo, 2)
  8. name          size summary
  9. ––––––––– –––––––– –––––––
  10. Base               Module
  11. Core               Module
  12. Main               Module
  13. gvar_self 13 bytes String

This does not apply to function or struct declarations. However, anonymous functions bound to global variables are serialized as can be seen below.

  1. julia> bar() = 1
  2. bar (generic function with 1 method)
  4. julia> remotecall_fetch(bar, 2)
  5. ERROR: On worker 2:
  6. UndefVarError: #bar not defined
  7. [...]
  9. julia> anon_bar  = ()->1
  10. (::#21) (generic function with 1 method)
  12. julia> remotecall_fetch(anon_bar, 2)
  13. 1

Why does Julia use * for string concatenation? Why not + or something else?

The main argument against + is that string concatenation is not commutative, while + is generally used as a commutative operator. While the Julia community recognizes that other languages use different operators and * may be unfamiliar for some users, it communicates certain algebraic properties.

Note that you can also use string(...) to concatenate strings (and other values converted to strings); similarly, repeat can be used instead of ^ to repeat strings. The interpolation syntax is also useful for constructing strings.

Packages and Modules

What is the difference between “using” and “import”?

There is only one difference, and on the surface (syntax-wise) it may seem very minor. The difference between using and import is that with using you need to say function Foo.bar(.. to extend module Foo’s function bar with a new method, but with import Foo.bar, you only need to say function bar(... and it automatically extends module Foo’s function bar.

The reason this is important enough to have been given separate syntax is that you don’t want to accidentally extend a function that you didn’t know existed, because that could easily cause a bug. This is most likely to happen with a method that takes a common type like a string or integer, because both you and the other module could define a method to handle such a common type. If you use import, then you’ll replace the other module’s implementation of bar(s::AbstractString) with your new implementation, which could easily do something completely different (and break all/many future usages of the other functions in module Foo that depend on calling bar).

Nothingness and missing values

How does “null”, “nothingness” or “missingness” work in Julia?

Unlike many languages (for example, C and Java), Julia objects cannot be “null” by default. When a reference (variable, object field, or array element) is uninitialized, accessing it will immediately throw an error. This situation can be detected using the isdefined or isassigned functions.

Some functions are used only for their side effects, and do not need to return a value. In these cases, the convention is to return the value nothing, which is just a singleton object of type Nothing. This is an ordinary type with no fields; there is nothing special about it except for this convention, and that the REPL does not print anything for it. Some language constructs that would not otherwise have a value also yield nothing, for example if false; end.

For situations where a value x of type T exists only sometimes, the Union{T, Nothing} type can be used for function arguments, object fields and array element types as the equivalent of Nullable, Option or Maybe in other languages. If the value itself can be nothing (notably, when T is Any), the Union{Some{T}, Nothing} type is more appropriate since x == nothing then indicates the absence of a value, and x == Some(nothing) indicates the presence of a value equal to nothing. The something function allows unwrapping Some objects and using a default value instead of nothing arguments. Note that the compiler is able to generate efficient code when working with Union{T, Nothing} arguments or fields.

To represent missing data in the statistical sense (NA in R or NULL in SQL), use the missing object. See the Missing Values section for more details.

The empty tuple (()) is another form of nothingness. But, it should not really be thought of as nothing but rather a tuple of zero values.

The empty (or “bottom”) type, written as Union{} (an empty union type), is a type with no values and no subtypes (except itself). You will generally not need to use this type.

Memory

Why does x += y allocate memory when x and y are arrays?

In Julia, x += y gets replaced during parsing by x = x + y. For arrays, this has the consequence that, rather than storing the result in the same location in memory as x, it allocates a new array to store the result.

While this behavior might surprise some, the choice is deliberate. The main reason is the presence of immutable objects within Julia, which cannot change their value once created. Indeed, a number is an immutable object; the statements x = 5; x += 1 do not modify the meaning of 5, they modify the value bound to x. For an immutable, the only way to change the value is to reassign it.

To amplify a bit further, consider the following function:

  1. function power_by_squaring(x, n::Int)
  2.     ispow2(n) || error("This implementation only works for powers of 2")
  3.     while n >= 2
  4.         x *= x
  5.         n >>= 1
  6.     end
  7.     x
  8. end

After a call like x = 5; y = power_by_squaring(x, 4), you would get the expected result: x == 5 && y == 625. However, now suppose that *=, when used with matrices, instead mutated the left hand side. There would be two problems:

  • For general square matrices, A = A*B cannot be implemented without temporary storage: A[1,1] gets computed and stored on the left hand side before you’re done using it on the right hand side.
  • Suppose you were willing to allocate a temporary for the computation (which would eliminate most of the point of making *= work in-place); if you took advantage of the mutability of x, then this function would behave differently for mutable vs. immutable inputs. In particular, for immutable x, after the call you’d have (in general) y != x, but for mutable x you’d have y == x.

Because supporting generic programming is deemed more important than potential performance optimizations that can be achieved by other means (e.g., using explicit loops), operators like += and *= work by rebinding new values.

Asynchronous IO and concurrent synchronous writes

Why do concurrent writes to the same stream result in inter-mixed output?

While the streaming I/O API is synchronous, the underlying implementation is fully asynchronous.

Consider the printed output from the following:

  1. julia> @sync for i in 1:3
  2.            @async write(stdout, string(i), " Foo ", " Bar ")
  3.        end
  4. 123 Foo  Foo  Foo  Bar  Bar  Bar

This is happening because, while the write call is synchronous, the writing of each argument yields to other tasks while waiting for that part of the I/O to complete.

print and println “lock” the stream during a call. Consequently changing write to println in the above example results in:

  1. julia> @sync for i in 1:3
  2.            @async println(stdout, string(i), " Foo ", " Bar ")
  3.        end
  4. 1 Foo  Bar
  5. 2 Foo  Bar
  6. 3 Foo  Bar

You can lock your writes with a ReentrantLock like this:

  1. julia> l = ReentrantLock()
  2. ReentrantLock(nothing, Condition(Any[]), 0)
  4. julia> @sync for i in 1:3
  5.            @async begin
  6.                lock(l)
  7.                try
  8.                    write(stdout, string(i), " Foo ", " Bar ")
  9.                finally
  10.                    unlock(l)
  11.                end
  12.            end
  13.        end
  14. 1 Foo  Bar 2 Foo  Bar 3 Foo  Bar

Arrays

What are the differences between zero-dimensional arrays and scalars?

Zero-dimensional arrays are arrays of the form Array{T,0}. They behave similar to scalars, but there are important differences. They deserve a special mention because they are a special case which makes logical sense given the generic definition of arrays, but might be a bit unintuitive at first. The following line defines a zero-dimensional array:

  1. julia> A = zeros()
  2. 0-dimensional Array{Float64,0}:
  3. 0.0

In this example, A is a mutable container that contains one element, which can be set by A[] = 1.0 and retrieved with A[]. All zero-dimensional arrays have the same size (size(A) == ()), and length (length(A) == 1). In particular, zero-dimensional arrays are not empty. If you find this unintuitive, here are some ideas that might help to understand Julia’s definition.

  • Zero-dimensional arrays are the “point” to vector’s “line” and matrix’s “plane”. Just as a line has no area (but still represents a set of things), a point has no length or any dimensions at all (but still represents a thing).
  • We define prod(()) to be 1, and the total number of elements in an array is the product of the size. The size of a zero-dimensional array is (), and therefore its length is 1.
  • Zero-dimensional arrays don’t natively have any dimensions into which you index – they’re just A[]. We can apply the same “trailing one” rule for them as for all other array dimensionalities, so you can indeed index them as A[1], A[1,1], etc.

It is also important to understand the differences to ordinary scalars. Scalars are not mutable containers (even though they are iterable and define things like length, getindex, e.g. 1[] == 1). In particular, if x = 0.0 is defined as a scalar, it is an error to attempt to change its value via x[] = 1.0. A scalar x can be converted into a zero-dimensional array containing it via fill(x), and conversely, a zero-dimensional array a can be converted to the contained scalar via a[]. Another difference is that a scalar can participate in linear algebra operations such as 2 * rand(2,2), but the analogous operation with a zero-dimensional array fill(2) * rand(2,2) is an error.

Julia Releases

Do I want to use a release, beta, or nightly version of Julia?

You may prefer the release version of Julia if you are looking for a stable code base. Releases generally occur every 6 months, giving you a stable platform for writing code.

You may prefer the beta version of Julia if you don’t mind being slightly behind the latest bugfixes and changes, but find the slightly faster rate of changes more appealing. Additionally, these binaries are tested before they are published to ensure they are fully functional.

You may prefer the nightly version of Julia if you want to take advantage of the latest updates to the language, and don’t mind if the version available today occasionally doesn’t actually work.

Finally, you may also consider building Julia from source for yourself. This option is mainly for those individuals who are comfortable at the command line, or interested in learning. If this describes you, you may also be interested in reading our guidelines for contributing.

Links to each of these download types can be found on the download page at https://julialang.org/downloads/. Note that not all versions of Julia are available for all platforms.

When are deprecated functions removed?

Deprecated functions are removed after the subsequent release. For example, functions marked as deprecated in the 0.1 release will not be available starting with the 0.2 release.