Send alert email

This page documents an earlier version of InfluxDB. InfluxDB v2.7 is the latest stable version. View this page in the v2.7 documentation.

Send an alert email using a third-party service, such as SendGrid, Amazon Simple Email Service (SES), Mailjet, or Mailgun. To send an alert email, complete the following steps:

  1. Create a check to identify the data to monitor and the status to alert on.
  2. Set up your preferred email service (sign up, retrieve API credentials, and send test email):
  3. Create an alert email task to call your email service and send an alert email.

In the procedure below, we use the Task page in the InfluxDB UI (user interface) to create a task. Explore other ways to create a task.

Create an alert email task

  1. In the InfluxDB UI, select Tasks in the navigation menu on the left.

    Tasks

  2. Click Create Task.

  3. In the Name field, enter a descriptive name, for example, Send alert email, and then enter how often to run the task in the Every field, for example, 10m. For more detail, such as using cron syntax or including an offset, see Task configuration options.

  4. In the right panel, enter the following detail in your task script (see examples below):

    • Import the Flux HTTP package.
    • (Optional) Store your API key as a secret for reuse. First, add your API key as a secret, and then import the Flux InfluxDB Secrets package.
    • Query the statuses measurement in the _monitoring bucket to retrieve all statuses generated by your check.
    • Set the time range to monitor; use the same interval that the task is scheduled to run. For example, range (start: -task.every).
    • Set the _level to alert on, for example, crit, warn, info, or ok.
    • Use the map() function to evaluate the criteria to send an alert using http.post().
    • Specify your email service url (endpoint), include applicable request headers, and verify your request data format follows the format specified for your email service.

Examples

SendGrid AWS SES Mailjet Mailgun

The example below uses the SendGrid API to send an alert email when more than 3 critical statuses occur since the previous task run.

  1. import "http"
  2. import "json"
  3. // Import the Secrets package if you store your API key as a secret.
  4. // For detail on how to do this, see Step 4 above.
  5. import "influxdata/influxdb/secrets"
  7. // Retrieve the secret if applicable. Otherwise, skip this line
  8. // and add the API key as the Bearer token in the Authorization header.
  9. SENDGRID_APIKEY = secrets.get(key: "SENDGRID_APIKEY")
  11. numberOfCrits = from(bucket: "_monitoring")
  12.     |> range(start: -task.every)
  13.     |> filter(fn: (r) => r._measurement == "statuses" and r._level == "crit")
  14.     |> count()
  16. numberOfCrits
  17.     |> map(
  18.         fn: (r) => if r._value > 3 then
  19.             {r with _value: http.post(
  20.                 url: "https://api.sendgrid.com/v3/mail/send",
  21.                 headers: {"Content-Type": "application/json", "Authorization": "Bearer ${SENDGRID_APIKEY}"},
  22.                 data: json.encode(
  23.                     v: {
  24.                         "personalizations": [
  25.                             {
  26.                                 "to": [
  27.                                     {
  28.                                         "email": "jane.doe@example.com"
  29.                                     }
  30.                                 ]
  31.                             }
  32.                         ],
  33.                         "from": {
  34.                             "email": "john.doe@example.com"
  35.                         },
  36.                         "subject": "InfluxDB critical alert",
  37.                         "content": [
  38.                             {
  39.                                 "type": "text/plain",
  40.                                 "value": "There have been ${r._value} critical statuses."
  41.                             }
  42.                         ]
  43.                     }
  44.                 )
  45.             )}
  46.         else
  47.             {r with _value: 0},
  48.     )

The example below uses the AWS SES API v2 to send an alert email when more than 3 critical statuses occur since the last task run.

Your AWS SES request, including the url (endpoint), authentication, and the structure of the request may vary. For more information, see Amazon SES API requests and Authenticating requests to the Amazon SES API. We recommend signing your AWS API requests using the Signature Version 4 signing process.

  1. import "http"
  2. import "json"
  3. // Import the Secrets package if you store your API credentials as secrets.
  4. // For detail on how to do this, see Step 4 above.
  5. import "influxdata/influxdb/secrets"
  7. // Retrieve the secrets if applicable. Otherwise, skip this line
  8. // and add the API key as the Bearer token in the Authorization header.
  9. AWS_AUTH_ALGORITHM = secrets.get(key: "AWS_AUTH_ALGORITHM")
  10. AWS_CREDENTIAL = secrets.get(key: "AWS_CREDENTIAL")
  11. AWS_SIGNED_HEADERS = secrets.get(key: "AWS_SIGNED_HEADERS")
  12. AWS_CALCULATED_SIGNATURE = secrets.get(key: "AWS_CALCULATED_SIGNATURE")
  14. numberOfCrits = from(bucket: "_monitoring")
  15.     |> range(start: -task.every)
  16.     |> filter(fn: (r) => r.measurement == "statuses" and r._level == "crit")
  17.     |> count()
  19. numberOfCrits
  20.     |> map(
  21.         fn: (r) => if r._value > 3 then
  22.             {r with _value: http.post(
  23.                 url: "https://email.your-aws-region.amazonaws.com/sendemail/v2/email/outbound-emails",
  24.                 headers: {
  25.                     "Content-Type": "application/json",
  26.                     "Authorization": "Bearer ${AWS_AUTH_ALGORITHM}${AWS_CREDENTIAL}${AWS_SIGNED_HEADERS}${AWS_CALCULATED_SIGNATURE}"},
  27.                 data: json.encode(v: {
  28.                         "Content": {
  29.                             "Simple": {
  30.                                 "Body": {
  31.                                     "Text": {
  32.                                         "Charset": "UTF-8",
  33.                                         "Data": "There have been ${r._value} critical statuses."
  34.                                     }
  35.                                 },
  36.                                 "Subject": {
  37.                                     "Charset": "UTF-8",
  38.                                     "Data": "InfluxDB critical alert"
  39.                                 }
  40.                             }
  41.                         },
  42.                         "Destination": {
  43.                             "ToAddresses": [
  44.                                 "john.doe@example.com"
  45.                             ]
  46.                         }
  47.                     }
  48.                 )
  49.             )}
  50.         else
  51.             {r with _value: 0},
  52.     )

For details on the request syntax, see SendEmail API v2 reference.

The example below uses the Mailjet Send API to send an alert email when more than 3 critical statuses occur since the last task run.

To view your Mailjet API credentials, sign in to Mailjet and open the API Key Management page.

  1. import "http"
  2. import "json"
  3. // Import the Secrets package if you store your API keys as secrets.
  4. // For detail on how to do this, see Step 4 above.
  5. import "influxdata/influxdb/secrets"
  7. // Retrieve the secrets if applicable. Otherwise, skip this line
  8. // and add the API keys as Basic credentials in the Authorization header.
  9. MAILJET_APIKEY = secrets.get(key: "MAILJET_APIKEY")
  10. MAILJET_SECRET_APIKEY = secrets.get(key: "MAILJET_SECRET_APIKEY")
  12. numberOfCrits = from(bucket: "_monitoring")
  13.     |> range(start: -task.every)
  14.     |> filter(fn: (r) => r.measurement == "statuses" and "r.level" == "crit")
  15.     |> count()
  17. numberOfCrits
  18.     |> map(
  19.         fn: (r) => if r._value > 3 then
  20.             {r with
  21.                 _value: http.post(
  22.                     url: "https://api.mailjet.com/v3.1/send",
  23.                     headers: {
  24.                         "Content-type": "application/json",
  25.                         "Authorization": "Basic ${MAILJET_APIKEY}:${MAILJET_SECRET_APIKEY}"
  26.                     },
  27.                     data: json.encode(
  28.                         v: {
  29.                             "Messages": [
  30.                                 {
  31.                                     "From": {"Email": "jane.doe@example.com"},
  32.                                     "To": [{"Email": "john.doe@example.com"}],
  33.                                     "Subject": "InfluxDB critical alert",
  34.                                     "TextPart": "There have been ${r._value} critical statuses.",
  35.                                     "HTMLPart": "<h3>${r._value} critical statuses</h3><p>There have been ${r._value} critical statuses.",
  36.                                 },
  37.                             ],
  38.                         },
  39.                     ),
  40.                 ),
  41.             }
  42.         else
  43.             {r with _value: 0},
  44.     )

The example below uses the Mailgun API to send an alert email when more than 3 critical statuses occur since the last task run.

To view your Mailgun API keys, sign in to Mailjet and open Account Security - API security. Mailgun requires that a domain be specified via Mailgun. A domain is automatically created for you when you first set up your account. You must include this domain in your url endpoint (for example, https://api.mailgun.net/v3/YOUR_DOMAIN or https://api.eu.mailgun.net/v3/YOUR_DOMAIN. If you’re using a free version of Mailgun, you can set up a maximum of five authorized recipients (to receive email alerts) for your domain. To view your Mailgun domains, sign in to Mailgun and view the Domains page.

  1. import "http"
  2. import "json"
  3. // Import the Secrets package if you store your API key as a secret.
  4. // For detail on how to do this, see Step 4 above.
  5. import "influxdata/influxdb/secrets"
  7. // Retrieve the secret if applicable. Otherwise, skip this line
  8. // and add the API key as the Bearer token in the Authorization header.
  9. MAILGUN_APIKEY = secrets.get(key: "MAILGUN_APIKEY")
  11. numberOfCrits = from(bucket: "_monitoring")
  12.     |> range(start: -task.every)
  13.     |> filter(fn: (r) => r["_measurement"] == "statuses")
  14.     |> filter(fn: (r) => r["_level"] == "crit")
  15.     |> count()
  17. numberOfCrits
  18.     |> map(
  19.         fn: (r) => if r._value > 1 then
  20.             {r with _value: http.post(
  21.                 url: "https://api.mailgun.net/v3/YOUR_DOMAIN/messages",
  22.                 headers: {
  23.                     "Content-type": "application/json",
  24.                     "Authorization": "Basic api:${MAILGUN_APIKEY}"
  25.                 },
  26.                 data: json.encode(v: {
  27.                         "from": "Username <mailgun@YOUR_DOMAIN_NAME>",
  28.                         "to": "email@example.com",
  29.                         "subject": "InfluxDB critical alert",
  30.                         "text": "There have been ${r._value} critical statuses."
  31.                     }                
  32.                 )
  33.             )}
  34.         else
  35.             {r with _value: 0},
  36.     )

alert email notifications check