@GDScript

Built-in GDScript functions.

Description

List of core built-in GDScript functions. Math functions and other utilities. Everything else is provided by objects. (Keywords: builtin, built in, global functions.)

Methods

Constants

• PI = 3.141593 —- Constant that represents how many times the diameter of a circle fits around its perimeter. This is equivalent to TAU / 2.

• TAU = 6.283185 —- The circle constant, the circumference of the unit circle in radians.

• INF = inf —- Positive infinity. For negative infinity, use -INF.

• NAN = nan —- “Not a Number”, an invalid value. NaN has special properties, including that it is not equal to itself. It is output by some invalid operations, such as dividing zero by zero.

Method Descriptions

• Color Color8 ( int r8, int g8, int b8, int a8=255 )

Returns a color constructed from integer red, green, blue, and alpha channels. Each channel should have 8 bits of information ranging from 0 to 255.

r8 red channel

g8 green channel

b8 blue channel

a8 alpha channel

red = Color8(255, 0, 0)

• Color ColorN ( String name, float alpha=1.0 )

Returns a color according to the standardized name with alpha ranging from 0 to 1.

red = ColorN("red", 1)

Supported color names are the same as the constants defined in Color.

• float abs ( float s )

Returns the absolute value of parameter s (i.e. positive value).

a = abs(-1) # a is 1

• float acos ( float s )

Returns the arc cosine of s in radians. Use to get the angle of cosine s. s must be between -1.0 and 1.0 (inclusive), otherwise, acos will return NAN.

# c is 0.523599 or 30 degrees if converted with rad2deg(s)
c = acos(0.866025)

• float asin ( float s )

Returns the arc sine of s in radians. Use to get the angle of sine s. s must be between -1.0 and 1.0 (inclusive), otherwise, asin will return NAN.

# s is 0.523599 or 30 degrees if converted with rad2deg(s)
s = asin(0.5)

• void assert ( bool condition, String message=”” )

Asserts that the condition is true. If the condition is false, an error is generated. When running from the editor, the running project will also be paused until you resume it. This can be used as a stronger form of push_error for reporting errors to project developers or add-on users.

Note: For performance reasons, the code inside assert is only executed in debug builds or when running the project from the editor. Don’t include code that has side effects in an assert call. Otherwise, the project will behave differently when exported in release mode.

The optional message argument, if given, is shown in addition to the generic “Assertion failed” message. You can use this to provide additional details about why the assertion failed.

# Imagine we always want speed to be between 0 and 20.
var speed = -10
assert(speed < 20) # True, the program will continue
assert(speed >= 0) # False, the program will stop
assert(speed >= 0 and speed < 20) # You can also combine the two conditional statements in one check
assert(speed < 20, "speed = %f, but the speed limit is 20" % speed) # Show a message with clarifying details

• float atan ( float s )

Returns the arc tangent of s in radians. Use it to get the angle from an angle’s tangent in trigonometry: atan(tan(angle)) == angle.

The method cannot know in which quadrant the angle should fall. See atan2 if you have both y and x.

a = atan(0.5) # a is 0.463648

• float atan2 ( float y, float x )

Returns the arc tangent of y/x in radians. Use to get the angle of tangent y/x. To compute the value, the method takes into account the sign of both arguments in order to determine the quadrant.

Important note: The Y coordinate comes first, by convention.

a = atan2(0, -1) # a is 3.141593

• Variant bytes2var ( PoolByteArray bytes, bool allow_objects=false )

Decodes a byte array back to a value. When allow_objects is true decoding objects is allowed.

WARNING: Deserialized object can contain code which gets executed. Do not use this option if the serialized object comes from untrusted sources to avoid potential security threats (remote code execution).

• Vector2 cartesian2polar ( float x, float y )

Converts a 2D point expressed in the cartesian coordinate system (X and Y axis) to the polar coordinate system (a distance from the origin and an angle).

• float ceil ( float s )

Rounds s upward (towards positive infinity), returning the smallest whole number that is not less than s.

a = ceil(1.45)  # a is 2.0
a = ceil(1.001) # a is 2.0

See also floor, round, stepify, and int.

• String char ( int code )

Returns a character as a String of the given Unicode code point (which is compatible with ASCII code).

a = char(65)      # a is "A"
a = char(65 + 32) # a is "a"
a = char(8364)    # a is "€"

This is the inverse of ord.

• float clamp ( float value, float min, float max )

Clamps value and returns a value not less than min and not more than max.

a = clamp(1000, 1, 20) # a is 20
a = clamp(-10, 1, 20)  # a is 1
a = clamp(15, 1, 20)   # a is 15

• Variant convert ( Variant what, int type )

Converts from a type to another in the best way possible. The type parameter uses the Variant.Type values.

a = Vector2(1, 0)
# Prints 1
print(a.length())
a = convert(a, TYPE_STRING)
# Prints 6 as "(1, 0)" is 6 characters
print(a.length())

• float cos ( float s )

Returns the cosine of angle s in radians.

a = cos(TAU) # a is 1.0
a = cos(PI)  # a is -1.0

• float cosh ( float s )

Returns the hyperbolic cosine of s in radians.

print(cosh(1)) # Prints 1.543081

• float db2linear ( float db )

Converts from decibels to linear energy (audio).

• int decimals ( float step )

Deprecated alias for step_decimals.

• float dectime ( float value, float amount, float step )

Returns the result of value decreased by step * amount.

a = dectime(60, 10, 0.1)) # a is 59.0

• float deg2rad ( float deg )

Converts an angle expressed in degrees to radians.

r = deg2rad(180) # r is 3.141593

• Object dict2inst ( Dictionary dict )

Converts a dictionary (previously created with inst2dict) back to an instance. Useful for deserializing.

• float ease ( float s, float curve )

Easing function, based on exponent. The curve values are: 0 is constant, 1 is linear, 0 to 1 is ease-in, 1+ is ease out. Negative values are in-out/out in.

• float exp ( float s )

The natural exponential function. It raises the mathematical constant e to the power of s and returns it.

e has an approximate value of 2.71828, and can be obtained with exp(1).

For exponents to other bases use the method pow.

a = exp(2) # Approximately 7.39

• float floor ( float s )

Rounds s downward (towards negative infinity), returning the largest whole number that is not more than s.

a = floor(2.45)  # a is 2.0
a = floor(2.99)  # a is 2.0
a = floor(-2.99) # a is -3.0

See also ceil, round, stepify, and int.

Note: This method returns a float. If you need an integer and s is a non-negative number, you can use int(s) directly.

• float fmod ( float a, float b )

Returns the floating-point remainder of a/b, keeping the sign of a.

r = fmod(7, 5.5) # r is 1.5

For the integer remainder operation, use the % operator.

• float fposmod ( float a, float b )

Returns the floating-point modulus of a/b that wraps equally in positive and negative.

for i in 7:
    var x = 0.5 * i - 1.5
    print("%4.1f %4.1f %4.1f" % [x, fmod(x, 1.5), fposmod(x, 1.5)])

Produces:

-1.5 -0.0  0.0
-1.0 -1.0  0.5
-0.5 -0.5  1.0
 0.0  0.0  0.0
 0.5  0.5  0.5
 1.0  1.0  1.0
 1.5  0.0  0.0

• FuncRef funcref ( Object instance, String funcname )

Returns a reference to the specified function funcname in the instance node. As functions aren’t first-class objects in GDscript, use funcref to store a FuncRef in a variable and call it later.

func foo():
    return("bar")
a = funcref(self, "foo")
print(a.call_func()) # Prints bar

• Array get_stack ( )

Returns an array of dictionaries representing the current call stack.

func _ready():
    foo()
func foo():
    bar()
func bar():
    print(get_stack())

would print

[{function:bar, line:12, source:res://script.gd}, {function:foo, line:9, source:res://script.gd}, {function:_ready, line:6, source:res://script.gd}]

• int hash ( Variant var )

Returns the integer hash of the variable passed.

print(hash("a")) # Prints 177670

• Dictionary inst2dict ( Object inst )

Returns the passed instance converted to a dictionary (useful for serializing).

var foo = "bar"
func _ready():
    var d = inst2dict(self)
    print(d.keys())
    print(d.values())

Prints out:

[@subpath, @path, foo]
[, res://test.gd, bar]

• Object instance_from_id ( int instance_id )

Returns the Object that corresponds to instance_id. All Objects have a unique instance ID.

var foo = "bar"
func _ready():
    var id = get_instance_id()
    var inst = instance_from_id(id)
    print(inst.foo) # Prints bar

• float inverse_lerp ( float from, float to, float weight )

Returns a normalized value considering the given range. This is the opposite of lerp.

var middle = lerp(20, 30, 0.75)
# `middle` is now 27.5.
# Now, we pretend to have forgotten the original ratio and want to get it back.
var ratio = inverse_lerp(20, 30, 27.5)
# `ratio` is now 0.75.

• bool is_equal_approx ( float a, float b )

Returns true if a and b are approximately equal to each other.

Here, approximately equal means that a and b are within a small internal epsilon of each other, which scales with the magnitude of the numbers.

Infinity values of the same sign are considered equal.

• bool is_inf ( float s )

Returns whether s is an infinity value (either positive infinity or negative infinity).

• bool is_instance_valid ( Object instance )

Returns whether instance is a valid object (e.g. has not been deleted from memory).

• bool is_nan ( float s )

Returns whether s is a NaN (“Not a Number” or invalid) value.

• bool is_zero_approx ( float s )

Returns true if s is zero or almost zero.

This method is faster than using is_equal_approx with one value as zero.

• int len ( Variant var )

Returns length of Variant var. Length is the character count of String, element count of Array, size of Dictionary, etc.

Note: Generates a fatal error if Variant can not provide a length.

a = [1, 2, 3, 4]
len(a) # Returns 4

• Variant lerp ( Variant from, Variant to, float weight )

Linearly interpolates between two values by a normalized value. This is the opposite of inverse_lerp.

If the from and to arguments are of type int or float, the return value is a float.

If both are of the same vector type (Vector2, Vector3 or Color), the return value will be of the same type (lerp then calls the vector type’s linear_interpolate method).

lerp(0, 4, 0.75) # Returns 3.0
lerp(Vector2(1, 5), Vector2(3, 2), 0.5) # Returns Vector2(2, 3.5)

• float lerp_angle ( float from, float to, float weight )

Linearly interpolates between two angles (in radians) by a normalized value.

Similar to lerp, but interpolates correctly when the angles wrap around TAU.

extends Sprite
var elapsed = 0.0
func _process(delta):
    var min_angle = deg2rad(0.0)
    var max_angle = deg2rad(90.0)
    rotation = lerp_angle(min_angle, max_angle, elapsed)
    elapsed += delta

• float linear2db ( float nrg )

Converts from linear energy to decibels (audio). This can be used to implement volume sliders that behave as expected (since volume isn’t linear). Example:

# "Slider" refers to a node that inherits Range such as HSlider or VSlider.
# Its range must be configured to go from 0 to 1.
# Change the bus name if you'd like to change the volume of a specific bus only.
AudioServer.set_bus_volume_db(AudioServer.get_bus_index("Master"), linear2db($Slider.value))

• Resource load ( String path )

Loads a resource from the filesystem located at path. The resource is loaded on the method call (unless it’s referenced already elsewhere, e.g. in another script or in the scene), which might cause slight delay, especially when loading scenes. To avoid unnecessary delays when loading something multiple times, either store the resource in a variable or use preload.

Note: Resource paths can be obtained by right-clicking on a resource in the FileSystem dock and choosing “Copy Path” or by dragging the file from the FileSystem dock into the script.

# Load a scene called main located in the root of the project directory and cache it in a variable.
var main = load("res://main.tscn") # main will contain a PackedScene resource.

Important: The path must be absolute, a local path will just return null.

This method is a simplified version of ResourceLoader.load, which can be used for more advanced scenarios.

• float log ( float s )

Natural logarithm. The amount of time needed to reach a certain level of continuous growth.

Note: This is not the same as the “log” function on most calculators, which uses a base 10 logarithm.

log(10) # Returns 2.302585

Note: The logarithm of 0 returns -inf, while negative values return -nan.

• float max ( float a, float b )

Returns the maximum of two values.

max(1, 2) # Returns 2
max(-3.99, -4) # Returns -3.99

• float min ( float a, float b )

Returns the minimum of two values.

min(1, 2) # Returns 1
min(-3.99, -4) # Returns -4

• float move_toward ( float from, float to, float delta )

Moves from toward to by the delta value.

Use a negative delta value to move away.

move_toward(5, 10, 4) # Returns 9
move_toward(10, 5, 4) # Returns 6
move_toward(10, 5, -1.5) # Returns 11.5

• int nearest_po2 ( int value )

Returns the nearest equal or larger power of 2 for integer value.

In other words, returns the smallest value a where a = pow(2, n) such that value <= a for some non-negative integer n.

nearest_po2(3) # Returns 4
nearest_po2(4) # Returns 4
nearest_po2(5) # Returns 8
nearest_po2(0) # Returns 0 (this may not be what you expect)
nearest_po2(-1) # Returns 0 (this may not be what you expect)

WARNING: Due to the way it is implemented, this function returns 0 rather than 1 for non-positive values of value (in reality, 1 is the smallest integer power of 2).

• int ord ( String char )

Returns an integer representing the Unicode code point of the given Unicode character char.

a = ord("A") # a is 65
a = ord("a") # a is 97
a = ord("€") # a is 8364

This is the inverse of char.

• Variant parse_json ( String json )

Parse JSON text to a Variant. (Use typeof to check if the Variant’s type is what you expect.)

Note: The JSON specification does not define integer or float types, but only a number type. Therefore, parsing a JSON text will convert all numerical values to float types.

Note: JSON objects do not preserve key order like Godot dictionaries, thus, you should not rely on keys being in a certain order if a dictionary is constructed from JSON. In contrast, JSON arrays retain the order of their elements:

var p = JSON.parse('["hello", "world", "!"]')
if typeof(p.result) == TYPE_ARRAY:
    print(p.result[0]) # Prints "hello"
else:
    push_error("Unexpected results.")

See also JSON for an alternative way to parse JSON text.

• Vector2 polar2cartesian ( float r, float th )

Converts a 2D point expressed in the polar coordinate system (a distance from the origin r and an angle th) to the cartesian coordinate system (X and Y axis).

• int posmod ( int a, int b )

Returns the integer modulus of a/b that wraps equally in positive and negative.

for i in range(-3, 4):
    print("%2d %2d %2d" % [i, i % 3, posmod(i, 3)])

Produces:

-3  0  0
-2 -2  1
-1 -1  2
 0  0  0
 1  1  1
 2  2  2
 3  0  0

• float pow ( float base, float exp )

Returns the result of base raised to the power of exp.

pow(2, 5) # Returns 32.0

• Resource preload ( String path )

Returns a Resource from the filesystem located at path. The resource is loaded during script parsing, i.e. is loaded with the script and preload effectively acts as a reference to that resource. Note that the method requires a constant path. If you want to load a resource from a dynamic/variable path, use load.

Note: Resource paths can be obtained by right clicking on a resource in the Assets Panel and choosing “Copy Path” or by dragging the file from the FileSystem dock into the script.

# Instance a scene.
var diamond = preload("res://diamond.tscn").instance()

• void print ( … ) vararg

Converts one or more arguments of any type to string in the best way possible and prints them to the console.

a = [1, 2, 3]
print("a", "=", a) # Prints a=[1, 2, 3]

Note: Consider using push_error and push_warning to print error and warning messages instead of print. This distinguishes them from print messages used for debugging purposes, while also displaying a stack trace when an error or warning is printed.

• void print_debug ( … ) vararg

Like print, but prints only when used in debug mode.

• void print_stack ( )

Prints a stack track at code location, only works when running with debugger turned on.

Output in the console would look something like this:

Frame 0 - res://test.gd:16 in function '_process'

• void printerr ( … ) vararg

Prints one or more arguments to strings in the best way possible to standard error line.

printerr("prints to stderr")

• void printraw ( … ) vararg

Prints one or more arguments to strings in the best way possible to console. No newline is added at the end.

printraw("A")
printraw("B")
# Prints AB

Note: Due to limitations with Godot’s built-in console, this only prints to the terminal. If you need to print in the editor, use another method, such as print.

• void prints ( … ) vararg

Prints one or more arguments to the console with a space between each argument.

prints("A", "B", "C") # Prints A B C

• void printt ( … ) vararg

Prints one or more arguments to the console with a tab between each argument.

printt("A", "B", "C") # Prints A       B       C

• void push_error ( String message )

Pushes an error message to Godot’s built-in debugger and to the OS terminal.

push_error("test error") # Prints "test error" to debugger and terminal as error call

Note: Errors printed this way will not pause project execution. To print an error message and pause project execution in debug builds, use assert(false, "test error") instead.

• void push_warning ( String message )

Pushes a warning message to Godot’s built-in debugger and to the OS terminal.

push_warning("test warning") # Prints "test warning" to debugger and terminal as warning call

• float rad2deg ( float rad )

Converts an angle expressed in radians to degrees.

rad2deg(0.523599) # Returns 30.0

• float rand_range ( float from, float to )

Random range, any floating point value between from and to.

prints(rand_range(0, 1), rand_range(0, 1)) # Prints e.g. 0.135591 0.405263

• Array rand_seed ( int seed )

Random from seed: pass a seed, and an array with both number and new seed is returned. “Seed” here refers to the internal state of the pseudo random number generator. The internal state of the current implementation is 64 bits.

• float randf ( )

Returns a random floating point value on the interval [0, 1].

randf() # Returns e.g. 0.375671

• int randi ( )

Returns a random unsigned 32-bit integer. Use remainder to obtain a random value in the interval [0, N - 1] (where N is smaller than 2^32).

randi()           # Returns random integer between 0 and 2^32 - 1
randi() % 20      # Returns random integer between 0 and 19
randi() % 100     # Returns random integer between 0 and 99
randi() % 100 + 1 # Returns random integer between 1 and 100

• void randomize ( )

Randomizes the seed (or the internal state) of the random number generator. Current implementation reseeds using a number based on time.

func _ready():
    randomize()

• Array range ( … ) vararg

Returns an array with the given range. Range can be 1 argument N (0 to N-1), two arguments (initial, final-1) or three arguments (initial, final-1, increment).

print(range(4))
print(range(2, 5))
print(range(0, 6, 2))

Output:

[0, 1, 2, 3]
[2, 3, 4]
[0, 2, 4]

• float range_lerp ( float value, float istart, float istop, float ostart, float ostop )

Maps a value from range [istart, istop] to [ostart, ostop].

range_lerp(75, 0, 100, -1, 1) # Returns 0.5

• float round ( float s )

Rounds s to the nearest whole number, with halfway cases rounded away from zero.

a = round(2.49) # a is 2.0
a = round(2.5)  # a is 3.0
a = round(2.51) # a is 3.0

See also floor, ceil, stepify, and int.

• void seed ( int seed )

Sets seed for the random number generator.

my_seed = "Godot Rocks"
seed(my_seed.hash())

• float sign ( float s )

Returns the sign of s: -1 or 1. Returns 0 if s is 0.

sign(-6) # Returns -1
sign(0)  # Returns 0
sign(6)  # Returns 1

• float sin ( float s )

Returns the sine of angle s in radians.

sin(0.523599) # Returns 0.5

• float sinh ( float s )

Returns the hyperbolic sine of s.

a = log(2.0) # Returns 0.693147
sinh(a) # Returns 0.75

• float smoothstep ( float from, float to, float s )

Returns the result of smoothly interpolating the value of s between 0 and 1, based on the where s lies with respect to the edges from and to.

The return value is 0 if s <= from, and 1 if s >= to. If s lies between from and to, the returned value follows an S-shaped curve that maps s between 0 and 1.

This S-shaped curve is the cubic Hermite interpolator, given by f(y) = 3*y^2 - 2*y^3 where y = (x-from) / (to-from).

smoothstep(0, 2, -5.0) # Returns 0.0
smoothstep(0, 2, 0.5) # Returns 0.15625
smoothstep(0, 2, 1.0) # Returns 0.5
smoothstep(0, 2, 2.0) # Returns 1.0

• float sqrt ( float s )

Returns the square root of s, where s is a non-negative number.

sqrt(9) # Returns 3

Note: Negative values of s return NaN. If you need negative inputs, use System.Numerics.Complex in C#.

• int step_decimals ( float step )

Returns the position of the first non-zero digit, after the decimal point. Note that the maximum return value is 10, which is a design decision in the implementation.

n = step_decimals(5)           # n is 0
n = step_decimals(1.0005)      # n is 4
n = step_decimals(0.000000005) # n is 9

• float stepify ( float s, float step )

Snaps float value s to a given step. This can also be used to round a floating point number to an arbitrary number of decimals.

stepify(100, 32) # Returns 96.0
stepify(3.14159, 0.01) # Returns 3.14

See also ceil, floor, round, and int.

• String str ( … ) vararg

Converts one or more arguments of any type to string in the best way possible.

var a = [10, 20, 30]
var b = str(a);
len(a) # Returns 3
len(b) # Returns 12

• Variant str2var ( String string )

Converts a formatted string that was returned by var2str to the original value.

a = '{ "a": 1, "b": 2 }'
b = str2var(a)
print(b["a"]) # Prints 1

• float tan ( float s )

Returns the tangent of angle s in radians.

tan(deg2rad(45)) # Returns 1

• float tanh ( float s )

Returns the hyperbolic tangent of s.

a = log(2.0) # a is 0.693147
b = tanh(a)  # b is 0.6

• String to_json ( Variant var )

Converts a Variant var to JSON text and return the result. Useful for serializing data to store or send over the network.

# Both numbers below are integers.
a = { "a": 1, "b": 2 }
b = to_json(a)
print(b) # {"a":1, "b":2}
# Both numbers above are floats, even if they display without any decimal places.

Note: The JSON specification does not define integer or float types, but only a number type. Therefore, converting a Variant to JSON text will convert all numerical values to float types.

See also JSON for an alternative way to convert a Variant to JSON text.

• bool type_exists ( String type )

Returns whether the given class exists in ClassDB.

type_exists("Sprite") # Returns true
type_exists("Variant") # Returns false

• int typeof ( Variant what )

Returns the internal type of the given Variant object, using the Variant.Type values.

p = parse_json('["a", "b", "c"]')
if typeof(p) == TYPE_ARRAY:
    print(p[0]) # Prints a
else:
    print("unexpected results")

• String validate_json ( String json )

Checks that json is valid JSON data. Returns an empty string if valid, or an error message otherwise.

j = to_json([1, 2, 3])
v = validate_json(j)
if not v:
    print("Valid JSON.")
else:
    push_error("Invalid JSON: " + v)

• PoolByteArray var2bytes ( Variant var, bool full_objects=false )

Encodes a variable value to a byte array. When full_objects is true encoding objects is allowed (and can potentially include code).

• String var2str ( Variant var )

Converts a Variant var to a formatted string that can later be parsed using str2var.

a = { "a": 1, "b": 2 }
print(var2str(a))

prints

{
"a": 1,
"b": 2
}

• WeakRef weakref ( Object obj )

Returns a weak reference to an object.

A weak reference to an object is not enough to keep the object alive: when the only remaining references to a referent are weak references, garbage collection is free to destroy the referent and reuse its memory for something else. However, until the object is actually destroyed the weak reference may return the object even if there are no strong references to it.

• float wrapf ( float value, float min, float max )

Wraps float value between min and max.

Usable for creating loop-alike behavior or infinite surfaces.

# Infinite loop between 5.0 and 9.9
value = wrapf(value + 0.1, 5.0, 10.0)

# Infinite rotation (in radians)
angle = wrapf(angle + 0.1, 0.0, TAU)

# Infinite rotation (in radians)
angle = wrapf(angle + 0.1, -PI, PI)

Note: If min is 0, this is equivalent to fposmod, so prefer using that instead.

wrapf is more flexible than using the fposmod approach by giving the user control over the minimum value.

• int wrapi ( int value, int min, int max )

Wraps integer value between min and max.

Usable for creating loop-alike behavior or infinite surfaces.

# Infinite loop between 5 and 9
frame = wrapi(frame + 1, 5, 10)

# result is -2
var result = wrapi(-6, -5, -1)

Note: If min is 0, this is equivalent to posmod, so prefer using that instead.

wrapi is more flexible than using the posmod approach by giving the user control over the minimum value.

• GDScriptFunctionState yield ( Object object=null, String signal=”” )

Stops the function execution and returns the current suspended state to the calling function.

From the caller, call GDScriptFunctionState.resume on the state to resume execution. This invalidates the state. Within the resumed function, yield() returns whatever was passed to the resume() function call.

If passed an object and a signal, the execution is resumed when the object emits the given signal. In this case, yield() returns the argument passed to emit_signal() if the signal takes only one argument, or an array containing all the arguments passed to emit_signal() if the signal takes multiple arguments.

You can also use yield to wait for a function to finish:

func _ready():
    yield(countdown(), "completed") # waiting for the countdown() function to complete
    print('Ready')
func countdown():
    yield(get_tree(), "idle_frame") # returns a GDScriptFunctionState object to _ready()
    print(3)
    yield(get_tree().create_timer(1.0), "timeout")
    print(2)
    yield(get_tree().create_timer(1.0), "timeout")
    print(1)
    yield(get_tree().create_timer(1.0), "timeout")
# prints:
# 3
# 2
# 1
# Ready

When yielding on a function, the completed signal will be emitted automatically when the function returns. It can, therefore, be used as the signal parameter of the yield method to resume.

In order to yield on a function, the resulting function should also return a GDScriptFunctionState. Notice yield(get_tree(), "idle_frame") from the above example.