Array

Generic array datatype.

Description

Generic array which can contain several elements of any type, accessible by a numerical index starting at 0. Negative indices can be used to count from the back, like in Python (-1 is the last element, -2 the second to last, etc.).

Example:

var array = ["One", 2, 3, "Four"]
print(array[0]) # One.
print(array[2]) # 3.
print(array[-1]) # Four.
array[2] = "Three"
print(array[-2]) # Three.

Arrays can be concatenated using the + operator:

var array1 = ["One", 2]
var array2 = [3, "Four"]
print(array1 + array2) # ["One", 2, 3, "Four"]

Note: Concatenating with the += operator will create a new array, which has a cost. If you want to append another array to an existing array, append_array is more efficient.

Note: Arrays are always passed by reference. To get a copy of an array which can be modified independently of the original array, use duplicate.

Note: When declaring an array with const, the array itself can still be mutated by defining the values at individual indices or pushing/removing elements. Using const will only prevent assigning the constant with another value after it was initialized.

Methods

Method Descriptions

• Array Array ( PoolColorArray from )

Constructs an array from a PoolColorArray.

• Array Array ( PoolVector3Array from )

Constructs an array from a PoolVector3Array.

• Array Array ( PoolVector2Array from )

Constructs an array from a PoolVector2Array.

• Array Array ( PoolStringArray from )

Constructs an array from a PoolStringArray.

• Array Array ( PoolRealArray from )

Constructs an array from a PoolRealArray.

• Array Array ( PoolIntArray from )

Constructs an array from a PoolIntArray.

• Array Array ( PoolByteArray from )

Constructs an array from a PoolByteArray.

• void append ( Variant value )

Appends an element at the end of the array (alias of push_back).

• void append_array ( Array array )

Appends another array at the end of this array.

var array1 = [1, 2, 3]
var array2 = [4, 5, 6]
array1.append_array(array2)
print(array1) # Prints [1, 2, 3, 4, 5, 6].

• Variant back ( )

Returns the last element of the array. Prints an error and returns null if the array is empty.

Note: Calling this function is not the same as writing array[-1]. If the array is empty, accessing by index will pause project execution when running from the editor.

• int bsearch ( Variant value, bool before=true )

Finds the index of an existing value (or the insertion index that maintains sorting order, if the value is not yet present in the array) using binary search. Optionally, a before specifier can be passed. If false, the returned index comes after all existing entries of the value in the array.

Note: Calling bsearch on an unsorted array results in unexpected behavior.

• int bsearch_custom ( Variant value, Object obj, String func, bool before=true )

Finds the index of an existing value (or the insertion index that maintains sorting order, if the value is not yet present in the array) using binary search and a custom comparison method declared in the obj. Optionally, a before specifier can be passed. If false, the returned index comes after all existing entries of the value in the array. The custom method receives two arguments (an element from the array and the value searched for) and must return true if the first argument is less than the second, and return false otherwise.

func cardinal_to_algebraic(a):
    match a:
        "one":
            return 1
        "two":
            return 2
        "three":
            return 3
        "four":
            return 4
        _:
            return 0
func compare(a, b):
    return cardinal_to_algebraic(a) < cardinal_to_algebraic(b)
func _ready():
    var a = ["one", "two", "three", "four"]
    # `compare` is defined in this object, so we use `self` as the `obj` parameter.
    print(a.bsearch_custom("three", self, "compare", true)) # Expected value is 2.

Note: Calling bsearch_custom on an unsorted array results in unexpected behavior.

• void clear ( )

Clears the array. This is equivalent to using resize with a size of 0.

• int count ( Variant value )

Returns the number of times an element is in the array.

• Array duplicate ( bool deep=false )

Returns a copy of the array.

If deep is true, a deep copy is performed: all nested arrays and dictionaries are duplicated and will not be shared with the original array. If false, a shallow copy is made and references to the original nested arrays and dictionaries are kept, so that modifying a sub-array or dictionary in the copy will also impact those referenced in the source array.

• bool empty ( )

Returns true if the array is empty.

• void erase ( Variant value )

Removes the first occurrence of a value from the array. To remove an element by index, use remove instead.

Note: This method acts in-place and doesn’t return a value.

Note: On large arrays, this method will be slower if the removed element is close to the beginning of the array (index 0). This is because all elements placed after the removed element have to be reindexed.

• int find ( Variant what, int from=0 )

Searches the array for a value and returns its index or -1 if not found. Optionally, the initial search index can be passed.

• int find_last ( Variant value )

Searches the array in reverse order for a value and returns its index or -1 if not found.

• Variant front ( )

Returns the first element of the array. Prints an error and returns null if the array is empty.

Note: Calling this function is not the same as writing array[0]. If the array is empty, accessing by index will pause project execution when running from the editor.

• bool has ( Variant value )

Returns true if the array contains the given value.

["inside", 7].has("inside") # True
["inside", 7].has("outside") # False
["inside", 7].has(7) # True
["inside", 7].has("7") # False

Note: This is equivalent to using the in operator as follows:

# Will evaluate to `true`.
if 2 in [2, 4, 6, 8]:
    pass

• int hash ( )

Returns a hashed integer value representing the array and its contents.

Note: Arrays with equal contents can still produce different hashes. Only the exact same arrays will produce the same hashed integer value.

• void insert ( int position, Variant value )

Inserts a new element at a given position in the array. The position must be valid, or at the end of the array (pos == size()).

Note: This method acts in-place and doesn’t return a value.

Note: On large arrays, this method will be slower if the inserted element is close to the beginning of the array (index 0). This is because all elements placed after the newly inserted element have to be reindexed.

• void invert ( )

Reverses the order of the elements in the array.

• Variant max ( )

Returns the maximum value contained in the array if all elements are of comparable types. If the elements can’t be compared, null is returned.

• Variant min ( )

Returns the minimum value contained in the array if all elements are of comparable types. If the elements can’t be compared, null is returned.

• Variant pop_back ( )

Removes and returns the last element of the array. Returns null if the array is empty, without printing an error message. See also pop_front.

• Variant pop_front ( )

Removes and returns the first element of the array. Returns null if the array is empty, without printing an error message. See also pop_back.

Note: On large arrays, this method is much slower than pop_back as it will reindex all the array’s elements every time it’s called. The larger the array, the slower pop_front will be.

• void push_back ( Variant value )

Appends an element at the end of the array. See also push_front.

• void push_front ( Variant value )

Adds an element at the beginning of the array. See also push_back.

Note: On large arrays, this method is much slower than push_back as it will reindex all the array’s elements every time it’s called. The larger the array, the slower push_front will be.

• void remove ( int position )

Removes an element from the array by index. If the index does not exist in the array, nothing happens. To remove an element by searching for its value, use erase instead.

Note: This method acts in-place and doesn’t return a value.

Note: On large arrays, this method will be slower if the removed element is close to the beginning of the array (index 0). This is because all elements placed after the removed element have to be reindexed.

• void resize ( int size )

Resizes the array to contain a different number of elements. If the array size is smaller, elements are cleared, if bigger, new elements are null.

• int rfind ( Variant what, int from=-1 )

Searches the array in reverse order. Optionally, a start search index can be passed. If negative, the start index is considered relative to the end of the array.

• void shuffle ( )

Shuffles the array such that the items will have a random order. This method uses the global random number generator common to methods such as @GDScript.randi. Call @GDScript.randomize to ensure that a new seed will be used each time if you want non-reproducible shuffling.

• int size ( )

Returns the number of elements in the array.

• Array slice ( int begin, int end, int step=1, bool deep=false )

Duplicates the subset described in the function and returns it in an array, deeply copying the array if deep is true. Lower and upper index are inclusive, with the step describing the change between indices while slicing.

• void sort ( )

Sorts the array.

Note: Strings are sorted in alphabetical order (as opposed to natural order). This may lead to unexpected behavior when sorting an array of strings ending with a sequence of numbers. Consider the following example:

var strings = ["string1", "string2", "string10", "string11"]
strings.sort()
print(strings) # Prints [string1, string10, string11, string2]

• void sort_custom ( Object obj, String func )

Sorts the array using a custom method. The arguments are an object that holds the method and the name of such method. The custom method receives two arguments (a pair of elements from the array) and must return either true or false.

Note: you cannot randomize the return value as the heapsort algorithm expects a deterministic result. Doing so will result in unexpected behavior.

class MyCustomSorter:
    static func sort_ascending(a, b):
        if a[0] < b[0]:
            return true
        return false
var my_items = [[5, "Potato"], [9, "Rice"], [4, "Tomato"]]
my_items.sort_custom(MyCustomSorter, "sort_ascending")
print(my_items) # Prints [[4, Tomato], [5, Potato], [9, Rice]].