Random number generation

Many games rely on randomness to implement core game mechanics. This page guides you through common types of randomness and how to implement them in Godot.

After giving you a brief overview of useful functions that generate random numbers, you will learn how to get random elements from arrays, dictionaries, and how to use a noise generator in GDScript.

Note

Computers cannot generate “true” random numbers. Instead, they rely on pseudorandom number generators (PRNGs).

Global scope versus RandomNumberGenerator class

Godot exposes two ways to generate random numbers: via global scope methods or using the RandomNumberGenerator class.

Global scope methods are easier to set up, but they don’t offer as much control.

RandomNumberGenerator requires more code to use, but exposes many methods not found in global scope such as randi_range() and randfn(). On top of that, it allows creating multiple instances each with their own seed.

This tutorial uses global scope methods, except when the method only exists in the RandomNumberGenerator class.

The randomize() method

In global scope, you can find a randomize() method. This method should be called only once when your project starts to initialize the random seed. Calling it multiple times is unnecessary and may impact performance negatively.

Putting it in your main scene script’s _ready() method is a good choice:

  1. func _ready():
  2.     randomize()

You can also set a fixed random seed instead using seed(). Doing so will give you deterministic results across runs:

  1. func _ready():
  2.     seed(12345)
  3.     # To use a string as a seed, you can hash it to a number.
  4.     seed("Hello world".hash())

When using the RandomNumberGenerator class, you should call randomize() on the instance since it has its own seed:

  1. var rng = RandomNumberGenerator.new()
  2. rng.randomize()

Getting a random number

Let’s look at some of the most commonly used functions and methods to generate random numbers in Godot.

The function randi() returns a random number between 0 and 2^32-1. Since the maximum value is huge, you most likely want to use the modulo operator (%) to bound the result between 0 and the denominator:

  1. # Prints a random integer between 0 and 49.
  2. print(randi() % 50)
  4. # Prints a random integer between 10 and 60.
  5. print(randi() % 51 + 10)

randf() returns a random floating-point number between 0 and 1. This is useful to implement a Weighted random probability system, among other things.

randfn() returns a random floating-point number following a normal distribution. This means the returned value is more likely to be around the mean (0.0 by default), varying by the deviation (1.0 by default):

  1. # Prints a random floating-point number from a normal distribution with a mean 0.0 and deviation 1.0.
  2. var rng = RandomNumberGenerator.new()
  3. rng.randomize()
  4. print(rng.randfn())

rand_range() takes two arguments from and to, and returns a random floating-point number between from and to:

  1. # Prints a random floating-point number between -4 and 6.5.
  2. print(rand_range(-4, 6.5))

RandomNumberGenerator.randi_range() takes two arguments from and to, and returns a random integer between from and to:

  1. # Prints a random integer between -10 and 10.
  2. var rng = RandomNumberGenerator.new()
  3. rng.randomize()
  4. print(rng.randi_range(-10, 10))

Get a random array element

We can use random integer generation to get a random element from an array:

  1. var fruits = ["apple", "orange", "pear", "banana"]
  4. func _ready():
  5.     randomize()
  7.     for i in 100:
  8.         # Pick 100 fruits randomly.
  9.         # (``for i in 100`` is a faster shorthand for ``for i in range(100)``.)
  10.         print(get_fruit())
  13. func get_fruit():
  14.     var random_fruit = fruits[randi() % fruits.size()]
  15.     # Returns "apple", "orange", "pear", or "banana" every time the code runs.
  16.     # We may get the same fruit multiple times in a row.
  17.     return random_fruit

To prevent the same fruit from being picked more than once in a row, we can add more logic to this method:

  1. var fruits = ["apple", "orange", "pear", "banana"]
  2. var last_fruit = ""
  5. func _ready():
  6.     randomize()
  8.     # Pick 100 fruits randomly.
  9.     # Note: ``for i in 100`` is a shorthand for ``for i in range(100)``.
  10.     for i in 100:
  11.         print(get_fruit())
  14. func get_fruit():
  15.     var random_fruit = fruits[randi() % fruits.size()]
  16.     while random_fruit == last_fruit:
  17.         # The last fruit was picked, try again until we get a different fruit.
  18.         random_fruit = fruits[randi() % fruits.size()]
  20.     # Note: if the random element to pick is passed by reference,
  21.     # such as an array or dictionary,
  22.     # use `last_fruit = random_fruit.duplicate()` instead.
  23.     last_fruit = random_fruit
  25.     # Returns "apple", "orange", "pear", or "banana" every time the code runs.
  26.     # The function will never return the same fruit more than once in a row.
  27.     return random_fruit

This approach can be useful to make random number generation feel less repetitive. Still, it doesn’t prevent results from “ping-ponging” between a limited set of values. To prevent this, use the shuffle bag pattern instead.

Get a random dictionary value

We can apply similar logic from arrays to dictionaries as well:

  1. var metals = {
  2.     "copper": {"quantity": 50, "price": 50},
  3.     "silver": {"quantity": 20, "price": 150},
  4.     "gold": {"quantity": 3, "price": 500},
  5. }
  8. func _ready():
  9.     randomize()
  11.     for i in 20:
  12.         print(get_metal())
  15. func get_metal():
  16.     var random_metal = metals.values()[randi() % metals.size()]
  17.     # Returns a random metal value dictionary every time the code runs.
  18.     # The same metal may be selected multiple times in succession.
  19.     return random_metal

Weighted random probability

The randf() method returns a floating-point number between 0.0 and 1.0. We can use this to create a “weighted” probability where different outcomes have different likelihoods:

  1. func _ready():
  2.     randomize()
  4.     for i in 100:
  5.         print(get_item_rarity())
  8. func get_item_rarity():
  9.     var random_float = randf()
  11.     if random_float < 0.8:
  12.         # 80% chance of being returned.
  13.         return "Common"
  14.     elif random_float < 0.95:
  15.         # 15% chance of being returned.
  16.         return "Uncommon"
  17.     else:
  18.         # 5% chance of being returned.
  19.         return "Rare"

“Better” randomness using shuffle bags

Taking the same example as above, we would like to pick fruits at random. However, relying on random number generation every time a fruit is selected can lead to a less uniform distribution. If the player is lucky (or unlucky), they could get the same fruit three or more times in a row.

You can accomplish this using the shuffle bag pattern. It works by removing an element from the array after choosing it. After multiple selections, the array ends up empty. When that happens, you reinitialize it to its default value:

  1. var fruits = ["apple", "orange", "pear", "banana"]
  2. # A copy of the fruits array so we can restore the original value into `fruits`.
  3. var fruits_full = []
  6. func _ready():
  7.     randomize()
  8.     fruits_full = fruits.duplicate()
  9.     fruits.shuffle()
  11.     for i in 100:
  12.         print(get_fruit())
  15. func get_fruit():
  16.     if fruits.empty():
  17.         # Fill the fruits array again and shuffle it.
  18.         fruits = fruits_full.duplicate()
  19.         fruits.shuffle()
  21.     # Get a random fruit, since we shuffled the array,
  22.     # and remove it from the `fruits` array.
  23.     var random_fruit = fruits.pop_front()
  24.     # Prints "apple", "orange", "pear", or "banana" every time the code runs.
  25.     return random_fruit

When running the above code, there is a chance to get the same fruit twice in a row. Once we picked a fruit, it will no longer be a possible return value unless the array is now empty. When the array is empty, we reset it back to its default value, making it possible to have the same fruit again, but only once.

Random noise

The random number generation shown above can show its limits when you need a value that slowly changes depending on the input. The input can be a position, time, or anything else.

To achieve this, you can use random noise functions. Noise functions are especially popular in procedural generation to generate realistic-looking terrain. Godot provides OpenSimplexNoise for this, which supports 1D, 2D, 3D, and 4D noise. Here’s an example with 1D noise:

  1. var noise = OpenSimplexNoise.new()
  3. func _ready():
  4.     randomize()
  5.     # Configure the OpenSimplexNoise instance.
  6.     noise.seed = randi()
  7.     noise.octaves = 4
  8.     noise.period = 20.0
  9.     noise.persistence = 0.8
  11.     for i in 100:
  12.         # Prints a slowly-changing series of floating-point numbers
  13.         # between -1.0 and 1.0.
  14.         print(noise.get_noise_1d(i))