DTLSServer

Inherits: Reference < Object

Helper class to implement a DTLS server.

Description

This class is used to store the state of a DTLS server. Upon setup it converts connected PacketPeerUDP to PacketPeerDTLS accepting them via take_connection as DTLS clients. Under the hood, this class is used to store the DTLS state and cookies of the server. The reason of why the state and cookies are needed is outside of the scope of this documentation.

Below a small example of how to use it:

  1. # server.gd
  2. extends Node
  4. var dtls := DTLSServer.new()
  5. var server := UDPServer.new()
  6. var peers = []
  8. func _ready():
  9.     server.listen(4242)
  10.     var key = load("key.key") # Your private key.
  11.     var cert = load("cert.crt") # Your X509 certificate.
  12.     dtls.setup(key, cert)
  14. func _process(delta):
  15.     while server.is_connection_available():
  16.         var peer : PacketPeerUDP = server.take_connection()
  17.         var dtls_peer : PacketPeerDTLS = dtls.take_connection(peer)
  18.         if dtls_peer.get_status() != PacketPeerDTLS.STATUS_HANDSHAKING:
  19.             continue # It is normal that 50% of the connections fails due to cookie exchange.
  20.         print("Peer connected!")
  21.         peers.append(dtls_peer)
  22.     for p in peers:
  23.         p.poll() # Must poll to update the state.
  24.         if p.get_status() == PacketPeerDTLS.STATUS_CONNECTED:
  25.             while p.get_available_packet_count() > 0:
  26.                 print("Received message from client: %s" % p.get_packet().get_string_from_utf8())
  27.                 p.put_packet("Hello DTLS client".to_utf8())
  1. # client.gd
  2. extends Node
  4. var dtls := PacketPeerDTLS.new()
  5. var udp := PacketPeerUDP.new()
  6. var connected = false
  8. func _ready():
  9.     udp.connect_to_host("127.0.0.1", 4242)
  10.     dtls.connect_to_peer(udp, false) # Use true in production for certificate validation!
  12. func _process(delta):
  13.     dtls.poll()
  14.     if dtls.get_status() == PacketPeerDTLS.STATUS_CONNECTED:
  15.         if !connected:
  16.             # Try to contact server
  17.             dtls.put_packet("The answer is... 42!".to_utf8())
  18.         while dtls.get_available_packet_count() > 0:
  19.             print("Connected: %s" % dtls.get_packet().get_string_from_utf8())
  20.             connected = true

Methods

Errorsetup ( CryptoKey key, X509Certificate certificate, X509Certificate chain=null )
PacketPeerDTLStake_connection ( PacketPeerUDP udp_peer )

Method Descriptions

Setup the DTLS server to use the given private_key and provide the given certificate to clients. You can pass the optional chain parameter to provide additional CA chain information along with the certificate.

Try to initiate the DTLS handshake with the given udp_peer which must be already connected (see PacketPeerUDP.connect_to_host).

Note: You must check that the state of the return PacketPeerUDP is PacketPeerDTLS.STATUS_HANDSHAKING, as it is normal that 50% of the new connections will be invalid due to cookie exchange.