Crypto

Inherits: Reference < Object

访问高级加密功能。

描述

Crypto类允许您访问Godot中的一些更高级的加密功能。

目前，这包括生成加密安全的随机字节，RSA密钥和自签名X509证书生成，非对称密钥加密/解密以及签名/验证。

extends Node
var crypto = Crypto.new()
var key = CryptoKey.new()
var cert = X509Certificate.new()
func _ready():
    # Generate new RSA key.
    key = crypto.generate_rsa(4096)
    # Generate new self-signed certificate with the given key.
    cert = crypto.generate_self_signed_certificate(key, "CN=mydomain.com,O=My Game Company,C=IT")
    # Save key and certificate in the user folder.
    key.save("user://generated.key")
    cert.save("user://generated.crt")
    # Encryption
    var data = "Some data"
    var encrypted = crypto.encrypt(key, data.to_utf8())
    # Decryption
    var decrypted = crypto.decrypt(key, encrypted)
    # Signing
    var signature = crypto.sign(HashingContext.HASH_SHA256, data.sha256_buffer(), key)
    # Verifying
    var verified = crypto.verify(HashingContext.HASH_SHA256, data.sha256_buffer(), signature, key)
    # Checks
    assert(verified)
    assert(data.to_utf8() == decrypted)

注意：在HTML5导出中不可用。

方法

方法说明

• bool constant_time_compare ( PoolByteArray trusted, PoolByteArray received )

比较两个PoolByteArray是否相等，而不泄露时间信息，以防止计时攻击。

更多信息参阅这篇博文。

• PoolByteArray decrypt ( CryptoKey key, PoolByteArray ciphertext )

用提供的私人key解密给定的ciphertext。

注意：所接受的密码文本的最大尺寸受到密钥大小限制。

• PoolByteArray encrypt ( CryptoKey key, PoolByteArray plaintext )

用提供的公钥 key 加密给定的plaintext。

注意：接受的明文的最大尺寸受到密钥大小的限制。

• PoolByteArray generate_random_bytes ( int size )

生成具有给定 size 的加密安全随机字节的 PoolByteArray。

• CryptoKey generate_rsa ( int size )

生成可用于创建自签名证书并传递给StreamPeerSSL.accept_stream的RSA CryptoKey。

• X509Certificate generate_self_signed_certificate ( CryptoKey key, String issuer_name=”CN=myserver,O=myorganisation,C=IT”, String not_before=”20140101000000”, String not_after=”20340101000000” )

根据给定的CryptoKey和issuer_name生成自签名的X509Certificate。证书的有效性将由not_before和not_after（第一个有效日期和最后一个有效日期）定义。 issuer_name必须至少包含“ CN =“（通用名称，即域名），“ O =”（组织，即您的公司名称），“ C =“（国家，即2个字母的ISO） -3166组织所在国家/地区的代码）。

一个生成RSA密钥和X509自签名证书的小示例。

var crypto = Crypto.new()
# Generate 4096 bits RSA key.
var key = crypto.generate_rsa(4096)
# Generate self-signed certificate using the given key.
var cert = crypto.generate_self_signed_certificate(key, "CN=example.com,O=A Game Company,C=IT")

• PoolByteArray hmac_digest ( HashType hash_type, PoolByteArray key, PoolByteArray msg )

使用 key 生成 msg 的 HMAC 摘要。 hash_type 参数是用于内部和外部哈希的哈希算法。

目前仅支持 HashingContext.HASH_SHA256 和 HashingContext.HASH_SHA1。

• PoolByteArray sign ( HashType hash_type, PoolByteArray hash, CryptoKey key )

使用提供的私有key对类型为hash_type的给定的hash进行签名。

• bool verify ( HashType hash_type, PoolByteArray hash, PoolByteArray signature, CryptoKey key )

对照提供的公共key验证类型为hash_type的hash_type的给定签名。