GDScript exports

Introduction to exports

In Godot, class members can be exported. This means their value gets saved along with the resource (such as the scene) they’re attached to. They will also be available for editing in the property editor. Exporting is done by using the export keyword:

  1. extends Button
  3. export var number = 5 # Value will be saved and visible in the property editor.

An exported variable must be initialized to a constant expression or have an export hint in the form of an argument to the export keyword (see the Examples section below).

One of the fundamental benefits of exporting member variables is to have them visible and editable in the editor. This way, artists and game designers can modify values that later influence how the program runs. For this, a special export syntax is provided.

Note

Exporting properties can also be done in other languages such as C#. The syntax varies depending on the language.

Examples

  1. # If the exported value assigns a constant or constant expression,
  2. # the type will be inferred and used in the editor.
  4. export var number = 5
  6. # Export can take a basic data type as an argument, which will be
  7. # used in the editor.
  9. export(int) var number
  11. # Export can also take a resource type to use as a hint.
  13. export(Texture) var character_face
  14. export(PackedScene) var scene_file
  15. # There are many resource types that can be used this way, try e.g.
  16. # the following to list them:
  17. export(Resource) var resource
  19. # Integers and strings hint enumerated values.
  21. # Editor will enumerate as 0, 1 and 2.
  22. export(int, "Warrior", "Magician", "Thief") var character_class
  23. # Editor will enumerate with string names.
  24. export(String, "Rebecca", "Mary", "Leah") var character_name
  26. # Named enum values
  28. # Editor will enumerate as THING_1, THING_2, ANOTHER_THING.
  29. enum NamedEnum {THING_1, THING_2, ANOTHER_THING = -1}
  30. export(NamedEnum) var x
  32. # Strings as paths
  34. # String is a path to a file.
  35. export(String, FILE) var f
  36. # String is a path to a directory.
  37. export(String, DIR) var f
  38. # String is a path to a file, custom filter provided as hint.
  39. export(String, FILE, "*.txt") var f
  41. # Using paths in the global filesystem is also possible,
  42. # but only in scripts in "tool" mode.
  44. # String is a path to a PNG file in the global filesystem.
  45. export(String, FILE, GLOBAL, "*.png") var tool_image
  46. # String is a path to a directory in the global filesystem.
  47. export(String, DIR, GLOBAL) var tool_dir
  49. # The MULTILINE setting tells the editor to show a large input
  50. # field for editing over multiple lines.
  51. export(String, MULTILINE) var text
  53. # Limiting editor input ranges
  55. # Allow integer values from 0 to 20.
  56. export(int, 20) var i
  57. # Allow integer values from -10 to 20.
  58. export(int, -10, 20) var j
  59. # Allow floats from -10 to 20 and snap the value to multiples of 0.2.
  60. export(float, -10, 20, 0.2) var k
  61. # Allow values 'y = exp(x)' where 'y' varies between 100 and 1000
  62. # while snapping to steps of 20. The editor will present a
  63. # slider for easily editing the value.
  64. export(float, EXP, 100, 1000, 20) var l
  66. # Floats with easing hint
  68. # Display a visual representation of the 'ease()' function
  69. # when editing.
  70. export(float, EASE) var transition_speed
  72. # Colors
  74. # Color given as red-green-blue value (alpha will always be 1).
  75. export(Color, RGB) var col
  76. # Color given as red-green-blue-alpha value.
  77. export(Color, RGBA) var col
  79. # Nodes
  81. # Another node in the scene can be exported as a NodePath.
  82. export(NodePath) var node_path
  83. # Do take note that the node itself isn't being exported -
  84. # there is one more step to call the true node:
  85. onready var node = get_node(node_path)
  87. # Resources
  89. export(Resource) var resource
  90. # In the Inspector, you can then drag and drop a resource file
  91. # from the FileSystem dock into the variable slot.
  93. # Opening the inspector dropdown may result in an
  94. # extremely long list of possible classes to create, however.
  95. # Therefore, if you specify an extension of Resource such as:
  96. export(AnimationNode) var resource
  97. # The drop-down menu will be limited to AnimationNode and all
  98. # its inherited classes.

It must be noted that even if the script is not being run while in the editor, the exported properties are still editable. This can be used in conjunction with a script in “tool” mode.

Exporting bit flags

Integers used as bit flags can store multiple true/false (boolean) values in one property. By using the export hint int, FLAGS, ..., they can be set from the editor:

  1. # Set any of the given flags from the editor.
  2. export(int, FLAGS, "Fire", "Water", "Earth", "Wind") var spell_elements = 0

You must provide a string description for each flag. In this example, Fire has value 1, Water has value 2, Earth has value 4 and Wind corresponds to value 8. Usually, constants should be defined accordingly (e.g. const ELEMENT_WIND = 8 and so on).

Export hints are also provided for the physics and render layers defined in the project settings:

  1. export(int, LAYERS_2D_PHYSICS) var layers_2d_physics
  2. export(int, LAYERS_2D_RENDER) var layers_2d_render
  3. export(int, LAYERS_3D_PHYSICS) var layers_3d_physics
  4. export(int, LAYERS_3D_RENDER) var layers_3d_render

Using bit flags requires some understanding of bitwise operations. If in doubt, use boolean variables instead.

Exporting arrays

Exported arrays can have initializers, but they must be constant expressions.

If the exported array specifies a type which inherits from Resource, the array values can be set in the inspector by dragging and dropping multiple files from the FileSystem dock at once.

  1. # Default value must be a constant expression.
  3. export var a = [1, 2, 3]
  5. # Exported arrays can specify type (using the same hints as before).
  7. export(Array, int) var ints = [1, 2, 3]
  8. export(Array, int, "Red", "Green", "Blue") var enums = [2, 1, 0]
  9. export(Array, Array, float) var two_dimensional = [[1.0, 2.0], [3.0, 4.0]]
  11. # You can omit the default value, but then it would be null if not assigned.
  13. export(Array) var b
  14. export(Array, PackedScene) var scenes
  16. # Arrays with specified types which inherit from resource can be set by
  17. # drag-and-dropping multiple files from the FileSystem dock.
  19. export(Array, Texture) var textures
  20. export(Array, PackedScene) var scenes
  22. # Typed arrays also work, only initialized empty:
  24. export var vector3s = PoolVector3Array()
  25. export var strings = PoolStringArray()
  27. # Default value can include run-time values, but can't
  28. # be exported.
  30. var c = [a, 2, 3]

Setting exported variables from a tool script

When changing an exported variable’s value from a script in Tool mode, the value in the inspector won’t be updated automatically. To update it, call property_list_changed_notify() after setting the exported variable’s value.

Advanced exports

Not every type of export can be provided on the level of the language itself to avoid unnecessary design complexity. The following describes some more or less common exporting features which can be implemented with a low-level API.

Before reading further, you should get familiar with the way properties are handled and how they can be customized with _set(), _get(), and _get_property_list() methods as described in Accessing data or logic from an object.

See also

For binding properties using the above methods in C++, see Binding properties using _set/_get/_get_property_list.

Warning

The script must operate in the tool mode so the above methods can work from within the editor.

Properties

To understand how to better use the sections below, you should understand how to make properties with advanced exports.

  1. func _get_property_list():
  2.     var properties = []
  3.     # Same as "export(int) var my_property"
  4.     properties.append({
  5.         name = "my_property",
  6.         type = TYPE_INT
  7.     })
  8.     return properties

  • The _get_property_list() function gets called by the inspector. You can override it for more advanced exports. You must return an Array with the contents of the properties for the function to work.

  • name is the name of the property

  • type is the type of the property from Variant.Type.

Note

The float type is called a real (TYPE_REAL) in the Variant.Type enum.

Attaching variables to properties

To attach variables to properties (allowing the value of the property to be used in scripts), you need to create a variable with the exact same name as the property or else you may need to override the _set() and _get() methods. Attaching a variable to to a property also gives you the ability to give it a default state.

  1. # This variable is determined by the function below.
  2. # This variable acts just like a regular gdscript export.
  3. var my_property = 5
  5. func _get_property_list():
  6.     var properties = []
  7.     # Same as "export(int) var my_property"
  8.     properties.append({
  9.         name = "my_property",
  10.         type = TYPE_INT
  11.     })
  12.     return properties

Adding default values for properties

To define default values for advanced exports, you need to override the property_can_revert() and property_get_revert() methods.

  • The property_can_revert() method takes the name of a property and must return true if the property can be reverted. This will enable the Revert button next to the property in the inspector.

  • The property_get_revert() method takes the name of a property and must return the default value for that property.

  1. func _get_property_list():
  2.     var properties = []
  3.     properties.append({
  4.         name = "my_property",
  5.         type = TYPE_INT
  6.     })
  7.     return properties
  9. func property_can_revert(property):
  10.     if property == "my_property":
  11.         return true
  12.     return false
  14. func property_get_revert(property):
  15.     if property == "my_property":
  16.         return 5

Adding script categories

For better visual distinguishing of properties, a special script category can be embedded into the inspector to act as a separator. Script Variables is one example of a built-in category.

  1. func _get_property_list():
  2.     var properties = []
  3.     properties.append({
  4.         name = "Debug",
  5.         type = TYPE_NIL,
  6.         usage = PROPERTY_USAGE_CATEGORY | PROPERTY_USAGE_SCRIPT_VARIABLE
  7.     })
  9.     # Example of adding a property to the script category
  10.     properties.append({
  11.         name = "Logging_Enabled",
  12.         type = TYPE_BOOL
  13.     })
  14.     return properties

  • name is the name of a category to be added to the inspector;

  • Every following property added after the category definition will be a part of the category.

  • PROPERTY_USAGE_CATEGORY indicates that the property should be treated as a script category specifically, so the type TYPE_NIL can be ignored as it won’t be actually used for the scripting logic, yet it must be defined anyway.

Grouping properties

A list of properties with similar names can be grouped.

  1. func _get_property_list():
  2.     var properties = []
  3.     properties.append({
  4.         name = "Rotate",
  5.         type = TYPE_NIL,
  6.         hint_string = "rotate_",
  7.         usage = PROPERTY_USAGE_GROUP | PROPERTY_USAGE_SCRIPT_VARIABLE
  8.     })
  10.     # Example of adding to the group
  11.     properties.append({
  12.         name = "rotate_speed",
  13.         type = TYPE_REAL
  14.     })
  16.     # This property won't get added to the group
  17.     # due to not having the "rotate_" prefix.
  18.     properties.append({
  19.         name = "trail_color",
  20.         type = TYPE_COLOR
  21.     })
  22.     return properties

  • name is the name of a group which is going to be displayed as collapsible list of properties;

  • Every following property added after the group property with the prefix (which determined by hint_string) will be shortened. For instance, rotate_speed is going to be shortened to speed in this case. However, movement_speed won’t be a part of the group and will not be shortened.

  • PROPERTY_USAGE_GROUP indicates that the property should be treated as a script group specifically, so the type TYPE_NIL can be ignored as it won’t be actually used for the scripting logic, yet it must be defined anyway.