通过 VB.NET 的流畅 APIFluent API with VB.NET

Code First 允许使用 C# 或 VB.NET 类定义模型。 还可以选择使用类和属性上的属性或使用 Fluent API 来执行其他配置。 本演练演示如何使用 VB.NET 执行 Fluent API 配置。

本页假设您基本了解 Code First。 有关 Code First 的详细信息，请参阅以下演练：

先决条件Pre-Requisites

需要至少安装 Visual Studio 2010 或 Visual Studio 2012 才能完成此演练。

如果你使用的是 Visual Studio 2010，你还需要安装NuGet

创建应用程序Create the Application

为了简单起见，我们将构建一个使用 Code First 执行数据访问的基本控制台应用程序。

  • 打开 Visual Studio
  • 文件->> 项目 。
  • 从左侧菜单和控制台应用程序选择Windows
  • 输入CodeFirstVBSample作为名称
  • 选择“确定”

定义模型Define the Model

在此步骤中，将定义表示概念模型的 VB.NET POCO 实体类型。 类不需要从任何基类派生或实现任何接口。

  • 向项目中添加一个新类，为类名输入SchoolModel
  • 将新类的内容替换为以下代码
  1. Public Class Department
  2.     Public Sub New()
  3.         Me.Courses = New List(Of Course)()
  4.     End Sub
  6.     ' Primary key
  7.     Public Property DepartmentID() As Integer
  8.     Public Property Name() As String
  9.     Public Property Budget() As Decimal
  10.     Public Property StartDate() As Date
  11.     Public Property Administrator() As Integer?
  12.     Public Overridable Property Courses() As ICollection(Of Course)
  13. End Class
  15. Public Class Course
  16.     Public Sub New()
  17.         Me.Instructors = New HashSet(Of Instructor)()
  18.     End Sub
  20.     ' Primary key
  21.     Public Property CourseID() As Integer
  22.     Public Property Title() As String
  23.     Public Property Credits() As Integer
  25.     ' Foreign  key that does not follow the Code First convention.
  26.     ' The fluent API will be used to configure DepartmentID_FK  to be the foreign key for this entity.
  27.     Public Property DepartmentID_FK() As Integer
  29.     ' Navigation properties
  30.     Public Overridable Property Department() As Department
  31.     Public Overridable Property Instructors() As ICollection(Of Instructor)
  32. End Class
  34. Public Class OnlineCourse
  35.     Inherits Course
  37.     Public Property URL() As String
  38. End Class
  40. Partial Public Class OnsiteCourse
  41.     Inherits Course
  43.     Public Sub New()
  44.         Details = New OnsiteCourseDetails()
  45.     End Sub
  47.     Public Property Details() As OnsiteCourseDetails
  48.  End Class
  50. ' Complex type
  51. Public Class OnsiteCourseDetails
  52.     Public Property Time() As Date
  53.     Public Property Location() As String
  54.     Public Property Days() As String
  55. End Class
  57. Public Class Person
  58.     ' Primary key
  59.     Public Property PersonID() As Integer
  60.     Public Property LastName() As String
  61.     Public Property FirstName() As String
  62. End Class
  64. Public Class Instructor
  65.     Inherits Person
  67.     Public Sub New()
  68.         Me.Courses = New List(Of Course)()
  69.     End Sub
  71.     Public Property HireDate() As Date
  73.     ' Navigation properties
  74.     Private privateCourses As ICollection(Of Course)
  75.     Public Overridable Property Courses() As ICollection(Of Course)
  76.     Public Overridable Property OfficeAssignment() As OfficeAssignment
  77. End Class
  79. Public Class OfficeAssignment
  80.     ' Primary key that does not follow the Code First convention.
  81.     ' The HasKey method is used later to configure the primary key for the entity.
  82.     Public Property InstructorID() As Integer
  84.     Public Property Location() As String
  85.     Public Property Timestamp() As Byte()
  87.     ' Navigation property
  88.     Public Overridable Property Instructor() As Instructor
  89. End Class

定义派生上下文Define a Derived Context

我们即将开始使用实体框架中的类型，因此我们需要添加 EntityFramework NuGet 包。

  • * * 项目–>管理 NuGet 程序包 …

备注

如果你没有 “管理 NuGet 包 … “ 选项你应安装最新版本的 NuGet

  • 选择 “联机“ 选项卡
  • 选择EntityFramework包
  • 单击“安装”

现在可以定义一个派生上下文，它表示与数据库的会话，从而使我们能够查询和保存数据。 我们定义了从 DbContext 派生的上下文，并为模型中的每个类公开了类型化的 DbSet。

  • 向项目中添加一个新类，为类名输入SchoolContext
  • 将新类的内容替换为以下代码
  1. Imports System.ComponentModel.DataAnnotations
  2. Imports System.ComponentModel.DataAnnotations.Schema
  3. Imports System.Data.Entity
  4. Imports System.Data.Entity.Infrastructure
  5. Imports System.Data.Entity.ModelConfiguration.Conventions
  7. Public Class SchoolContext
  8.     Inherits DbContext
  10.     Public Property OfficeAssignments() As DbSet(Of OfficeAssignment)
  11.     Public Property Instructors() As DbSet(Of Instructor)
  12.     Public Property Courses() As DbSet(Of Course)
  13.     Public Property Departments() As DbSet(Of Department)
  15.     Protected Overrides Sub OnModelCreating(ByVal modelBuilder As DbModelBuilder)
  16.     End Sub
  17. End Class

用熟知 API 配置Configuring with the Fluent API

本部分演示如何使用熟知的 Api 将类型配置为表映射、属性到列的映射，以及模型中\类型的表之间的关系。 Fluent API 通过DbModelBuilder类型公开，最常用的方法是重写DbContext上的OnModelCreating方法。

  • 复制以下代码并将其添加到SchoolContext类中定义的OnModelCreating方法中。注释说明了每个映射的作用
  1. ' Configure Code First to ignore PluralizingTableName convention
  2. ' If you keep this convention then the generated tables
  3. ' will have pluralized names.
  4. modelBuilder.Conventions.Remove(Of PluralizingTableNameConvention)()
  7. ' Specifying that a Class is a Complex Type
  9. ' The model defined in this topic defines a type OnsiteCourseDetails.
  10. ' By convention, a type that has no primary key specified
  11. ' is treated as a complex type.
  12. ' There are some scenarios where Code First will not
  13. ' detect a complex type (for example, if you do have a property
  14. ' called ID, but you do not mean for it to be a primary key).
  15. ' In such cases, you would use the fluent API to
  16. ' explicitly specify that a type is a complex type.
  17. modelBuilder.ComplexType(Of OnsiteCourseDetails)()
  20. ' Mapping a CLR Entity Type to a Specific Table in the Database.
  22. ' All properties of OfficeAssignment will be mapped
  23. ' to columns  in a table called t_OfficeAssignment.
  24. modelBuilder.Entity(Of OfficeAssignment)().ToTable("t_OfficeAssignment")
  27. ' Mapping the Table-Per-Hierarchy (TPH) Inheritance
  29. ' In the TPH mapping scenario, all types in an inheritance hierarchy
  30. ' are mapped to a single table.
  31. ' A discriminator column is used to identify the type of each row.
  32. ' When creating your model with Code First,      
  33. ' TPH is the default strategy for the types that
  34. ' participate in the inheritance hierarchy.
  35. ' By default, the discriminator column is added
  36. ' to the table with the name “Discriminator”
  37. ' and the CLR type name of each type in the hierarchy
  38. ' is used for the discriminator values.
  39. ' You can modify the default behavior by using the fluent API.
  40. modelBuilder.Entity(Of Person)().
  41.     Map(Of Person)(Function(t) t.Requires("Type").
  42.         HasValue("Person")).
  43.         Map(Of Instructor)(Function(t) t.Requires("Type").
  44.         HasValue("Instructor"))
  47. ' Mapping the Table-Per-Type (TPT) Inheritance
  49. ' In the TPT mapping scenario, all types are mapped to individual tables.
  50. ' Properties that belong solely to a base type or derived type are stored
  51. ' in a table that maps to that type. Tables that map to derived types
  52. ' also store a foreign key that joins the derived table with the base table.
  53. modelBuilder.Entity(Of Course)().ToTable("Course")
  54. modelBuilder.Entity(Of OnsiteCourse)().ToTable("OnsiteCourse")
  55. modelBuilder.Entity(Of OnlineCourse)().ToTable("OnlineCourse")
  58. ' Configuring a Primary Key
  60. ' If your class defines a property whose name is “ID” or “Id”,
  61. ' or a class name followed by “ID” or “Id”,
  62. ' the Entity Framework treats this property as a primary key by convention.
  63. ' If your property name does not follow this pattern, use the HasKey method
  64. ' to configure the primary key for the entity.
  65. modelBuilder.Entity(Of OfficeAssignment)().
  66.     HasKey(Function(t) t.InstructorID)
  69. ' Specifying the Maximum Length on a Property
  71. ' In the following example, the Name property
  72. ' should be no longer than 50 characters.
  73. ' If you make the value longer than 50 characters,
  74. ' you will get a DbEntityValidationException exception.
  75. modelBuilder.Entity(Of Department)().Property(Function(t) t.Name).
  76.     HasMaxLength(60)
  79. ' Configuring the Property to be Required
  81. ' In the following example, the Name property is required.
  82. ' If you do not specify the Name,
  83. ' you will get a DbEntityValidationException exception.
  84. ' The database column used to store this property will be non-nullable.
  85. modelBuilder.Entity(Of Department)().Property(Function(t) t.Name).
  86.     IsRequired()
  89. ' Switching off Identity for Numeric Primary Keys
  91. ' The following example sets the DepartmentID property to
  92. ' System.ComponentModel.DataAnnotations.DatabaseGeneratedOption.None to indicate that
  93. ' the value will not be generated by the database.
  94. modelBuilder.Entity(Of Course)().Property(Function(t) t.CourseID).
  95.     HasDatabaseGeneratedOption(DatabaseGeneratedOption.None)
  97. 'Specifying NOT to Map a CLR Property to a Column in the Database
  98.  modelBuilder.Entity(Of Department)().
  99.      Ignore(Function(t) t.Administrator)
  101. 'Mapping a CLR Property to a Specific Column in the Database
  102.  modelBuilder.Entity(Of Department)().Property(Function(t) t.Budget).
  103.      HasColumnName("DepartmentBudget")
  105. 'Configuring the Data Type of a Database Column
  106.  modelBuilder.Entity(Of Department)().Property(Function(t) t.Name).
  107.      HasColumnType("varchar")
  109. 'Configuring Properties on a Complex Type
  110. modelBuilder.Entity(Of OnsiteCourse)().Property(Function(t) t.Details.Days).
  111.     HasColumnName("Days")
  112. modelBuilder.Entity(Of OnsiteCourse)().Property(Function(t) t.Details.Location).
  113.     HasColumnName("Location")
  114. modelBuilder.Entity(Of OnsiteCourse)().Property(Function(t) t.Details.Time).
  115.     HasColumnName("Time")
  118. ' Map one-to-zero or one relationship
  120. ' The OfficeAssignment has the InstructorID
  121. ' property that is a primary key and a foreign key.
  122. modelBuilder.Entity(Of OfficeAssignment)().
  123.     HasRequired(Function(t) t.Instructor).
  124.     WithOptional(Function(t) t.OfficeAssignment)
  127. ' Configuring a Many-to-Many Relationship
  129. ' The following code configures a many-to-many relationship
  130. ' between the Course  and Instructor types.
  131. ' In the following example, the default Code First conventions
  132. ' are used  to create a join table.
  133. ' As a result the CourseInstructor table is created with
  134. ' Course_CourseID  and Instructor_InstructorID columns.
  135. modelBuilder.Entity(Of Course)().
  136.     HasMany(Function(t) t.Instructors).
  137.     WithMany(Function(t) t.Courses)
  140. ' Configuring a Many-to-Many Relationship and specifying the names
  141. ' of the columns in the join table
  143. ' If you want to specify the join table name
  144. ' and the names of the columns in the table
  145. ' you need to do additional configuration by using the Map method.
  146. ' The following code generates the CourseInstructor
  147. ' table with CourseID and InstructorID columns.
  148. modelBuilder.Entity(Of Course)().
  149.     HasMany(Function(t) t.Instructors).
  150.     WithMany(Function(t) t.Courses).
  151.     Map(Sub(m)
  152.             m.ToTable("CourseInstructor")
  153.             m.MapLeftKey("CourseID")
  154.             m.MapRightKey("InstructorID")
  155.         End Sub)
  158. ' Configuring a foreign key name that does not follow the Code First convention
  160. ' The foreign key property on the Course class is called DepartmentID_FK
  161. ' since that does not follow Code First conventions you need to explicitly specify
  162. ' that you want DepartmentID_FK to be the foreign key.
  163. modelBuilder.Entity(Of Course)().
  164.     HasRequired(Function(t) t.Department).
  165.     WithMany(Function(t) t.Courses).
  166.     HasForeignKey(Function(t) t.DepartmentID_FK)
  169. ' Enabling Cascade Delete
  171. ' By default, if a foreign key on the dependent entity is not nullable,
  172. ' then Code First sets cascade delete on the relationship.
  173. ' If a foreign key on the dependent entity is nullable,
  174. ' Code First does not set cascade delete on the relationship,
  175. ' and when the principal is deleted the foreign key will be set to null.
  176. ' The following code configures cascade delete on the relationship.
  178. ' You can also remove the cascade delete conventions by using:
  179. ' modelBuilder.Conventions.Remove<OneToManyCascadeDeleteConvention>()
  180. ' and modelBuilder.Conventions.Remove<ManyToManyCascadeDeleteConvention>().
  181. modelBuilder.Entity(Of Course)().
  182.     HasRequired(Function(t) t.Department).
  183.     WithMany(Function(t) t.Courses).
  184.     HasForeignKey(Function(d) d.DepartmentID_FK).
  185.     WillCascadeOnDelete(False)

使用模型Using the Model

让我们使用SchoolContext执行一些数据访问，以查看操作中的模型。

  • 打开定义了 Main 函数的 Module1 文件
  • 复制并粘贴以下 Module1 定义
  1. Imports System.Data.Entity
  3. Module Module1
  5.     Sub Main()
  7.         Using context As New SchoolContext()
  9.             ' Create and save a new Department.
  10.             Console.Write("Enter a name for a new Department: ")
  11.             Dim name = Console.ReadLine()
  13.             Dim department = New Department With { .Name = name, .StartDate = DateTime.Now }
  14.             context.Departments.Add(department)
  15.             context.SaveChanges()
  17.             ' Display all Departments from the database ordered by name
  18.             Dim departments =
  19.                 From d In context.Departments
  20.                 Order By d.Name
  21.                 Select d
  23.             Console.WriteLine("All Departments in the database:")
  24.             For Each department In departments
  25.                 Console.WriteLine(department.Name)
  26.             Next
  28.         End Using
  30.         Console.WriteLine("Press any key to exit...")
  31.         Console.ReadKey()
  33.     End Sub
  35. End Module

你现在可以运行该应用程序并对其进行测试。

  1. Enter a name for a new Department: Computing
  2. All Departments in the database:
  3. Computing
  4. Press any key to exit...