Extension Types

Introduction

As well as creating normal user-defined classes with the Python classstatement, Cython also lets you create new built-in Python types, known asextension types. You define an extension type using the cdef classstatement. Here’s an example:

from __future__ import print_function
 
cdef class Shrubbery:
    cdef int width, height
 
    def __init__(self, w, h):
        self.width = w
        self.height = h
 
    def describe(self):
        print("This shrubbery is", self.width,
              "by", self.height, "cubits.")

As you can see, a Cython extension type definition looks a lot like a Pythonclass definition. Within it, you use the def statement to define methods thatcan be called from Python code. You can even define many of the specialmethods such as init() as you would in Python.

The main difference is that you can use the cdef statement to defineattributes. The attributes may be Python objects (either generic or of aparticular extension type), or they may be of any C data type. So you can useextension types to wrap arbitrary C data structures and provide a Python-likeinterface to them.

Static Attributes

Attributes of an extension type are stored directly in the object’s C struct.The set of attributes is fixed at compile time; you can’t add attributes to anextension type instance at run time simply by assigning to them, as you couldwith a Python class instance. However, you can explicitly enable supportfor dynamically assigned attributes, or subclass the extension type with a normalPython class, which then supports arbitrary attribute assignments.See Dynamic Attributes.

There are two ways that attributes of an extension type can be accessed: byPython attribute lookup, or by direct access to the C struct from Cython code.Python code is only able to access attributes of an extension type by thefirst method, but Cython code can use either method.

By default, extension type attributes are only accessible by direct access,not Python access, which means that they are not accessible from Python code.To make them accessible from Python code, you need to declare them aspublic or readonly. For example:

cdef class Shrubbery:
    cdef public int width, height
    cdef readonly float depth

makes the width and height attributes readable and writable from Python code,and the depth attribute readable but not writable.

Note

You can only expose simple C types, such as ints, floats, andstrings, for Python access. You can also expose Python-valued attributes.

Note

Also the public and readonly options apply only toPython access, not direct access. All the attributes of an extension typeare always readable and writable by C-level access.

Dynamic Attributes

It is not possible to add attributes to an extension type at runtime by default.You have two ways of avoiding this limitation, both add an overhead whena method is called from Python code. Especially when calling cpdef methods.

The first approach is to create a Python subclass.:

cdef class Animal:
 
    cdef int number_of_legs
 
    def __cinit__(self, int number_of_legs):
        self.number_of_legs = number_of_legs
 
 
class ExtendableAnimal(Animal):  # Note that we use class, not cdef class
    pass
 
 
dog = ExtendableAnimal(4)
dog.has_tail = True

Declaring a dict attribute is the second way of enabling dynamic attributes.:

cdef class Animal:
 
    cdef int number_of_legs
    cdef dict __dict__
 
    def __cinit__(self, int number_of_legs):
        self.number_of_legs = number_of_legs
 
 
dog = Animal(4)
dog.has_tail = True

Type declarations

Before you can directly access the attributes of an extension type, the Cythoncompiler must know that you have an instance of that type, and not just ageneric Python object. It knows this already in the case of the selfparameter of the methods of that type, but in other cases you will have to usea type declaration.

For example, in the following function:

cdef widen_shrubbery(sh, extra_width): # BAD
    sh.width = sh.width + extra_width

because the sh parameter hasn’t been given a type, the width attributewill be accessed by a Python attribute lookup. If the attribute has beendeclared public or readonly then this will work, but itwill be very inefficient. If the attribute is private, it will not work at all– the code will compile, but an attribute error will be raised at run time.

The solution is to declare sh as being of type Shrubbery, asfollows:

from my_module cimport Shrubbery
 
cdef widen_shrubbery(Shrubbery sh, extra_width):
    sh.width = sh.width + extra_width

Now the Cython compiler knows that sh has a C attribute calledwidth and will generate code to access it directly and efficiently.The same consideration applies to local variables, for example:

from my_module cimport Shrubbery
 
cdef Shrubbery another_shrubbery(Shrubbery sh1):
    cdef Shrubbery sh2
    sh2 = Shrubbery()
    sh2.width = sh1.width
    sh2.height = sh1.height
    return sh2

Note

We here cimport the class Shrubbery, and this is necessaryto declare the type at compile time. To be able to cimport an extension type,we split the class definition into two parts, one in a definition file andthe other in the corresponding implementation file. You should readSharing Extension Types to learn to do that.

Type Testing and Casting

Suppose I have a method quest() which returns an object of type Shrubbery.To access it’s width I could write:

cdef Shrubbery sh = quest()
print(sh.width)

which requires the use of a local variable and performs a type test on assignment.If you know the return value of quest() will be of type Shrubberyyou can use a cast to write:

print( (<Shrubbery>quest()).width )

This may be dangerous if quest() is not actually a Shrubbery, as itwill try to access width as a C struct member which may not exist. At the C level,rather than raising an AttributeError, either an nonsensical result will bereturned (interpreting whatever data is at that address as an int) or a segfaultmay result from trying to access invalid memory. Instead, one can write:

print( (<Shrubbery?>quest()).width )

which performs a type check (possibly raising a TypeError) before making thecast and allowing the code to proceed.

To explicitly test the type of an object, use the isinstance() builtin function.For known builtin or extension types, Cython translates these into afast and safe type check that ignores changes tothe object’s class attribute etc., so that after a successfulisinstance() test, code can rely on the expected C structure of theextension type and its cdef attributes and methods.

Extension types and None

When you declare a parameter or C variable as being of an extension type,Cython will allow it to take on the value None as well as values of itsdeclared type. This is analogous to the way a C pointer can take on the valueNULL, and you need to exercise the same caution because of it. There is noproblem as long as you are performing Python operations on it, because fulldynamic type checking will be applied. However, when you access C attributesof an extension type (as in the widen_shrubbery function above), it’s up toyou to make sure the reference you’re using is not None – in theinterests of efficiency, Cython does not check this.

You need to be particularly careful when exposing Python functions which takeextension types as arguments. If we wanted to make widen_shrubbery() aPython function, for example, if we simply wrote:

def widen_shrubbery(Shrubbery sh, extra_width): # This is
    sh.width = sh.width + extra_width           # dangerous!

then users of our module could crash it by passing None for the shparameter.

One way to fix this would be:

def widen_shrubbery(Shrubbery sh, extra_width):
    if sh is None:
        raise TypeError
    sh.width = sh.width + extra_width

but since this is anticipated to be such a frequent requirement, Cythonprovides a more convenient way. Parameters of a Python function declared as anextension type can have a not None clause:

def widen_shrubbery(Shrubbery sh not None, extra_width):
    sh.width = sh.width + extra_width

Now the function will automatically check that sh is not None alongwith checking that it has the right type.

Note

not None clause can only be used in Python functions (defined withdef) and not C functions (defined with cdef). Ifyou need to check whether a parameter to a C function is None, you willneed to do it yourself.

Note

Some more things:

• The self parameter of a method of an extension type is guaranteed never tobe None.
• When comparing a value with None, keep in mind that, if x is a Pythonobject, x is None and x is not None are very efficient because theytranslate directly to C pointer comparisons, whereas x == None andx != None, or simply using x as a boolean value (as in if x: …)will invoke Python operations and therefore be much slower.

Special methods

Although the principles are similar, there are substantial differences betweenmany of the xxx() special methods of extension types and their Pythoncounterparts. There is a separate page devoted to this subject, and you shouldread it carefully before attempting to use any special methods in yourextension types.

Properties

You can declare properties in an extension class using the same syntax as in ordinary Python code:

cdef class Spam:
 
    @property
    def cheese(self):
        # This is called when the property is read.
        ...
 
    @cheese.setter
    def cheese(self, value):
            # This is called when the property is written.
            ...
 
    @cheese.deleter
    def cheese(self):
        # This is called when the property is deleted.

There is also a special (deprecated) legacy syntax for defining properties in an extension class:

cdef class Spam:
 
    property cheese:
 
        "A doc string can go here."
 
        def __get__(self):
            # This is called when the property is read.
            ...
 
        def __set__(self, value):
            # This is called when the property is written.
            ...
 
        def __del__(self):
            # This is called when the property is deleted.

The get(), set() and del() methods are alloptional; if they are omitted, an exception will be raised when thecorresponding operation is attempted.

Here’s a complete example. It defines a property which adds to a list eachtime it is written to, returns the list when it is read, and empties the listwhen it is deleted.:

# cheesy.pyx
cdef class CheeseShop:
 
    cdef object cheeses
 
    def __cinit__(self):
        self.cheeses = []
 
    @property
    def cheese(self):
        return "We don't have: %s" % self.cheeses
 
    @cheese.setter
    def cheese(self, value):
        self.cheeses.append(value)
 
    @cheese.deleter
    def cheese(self):
        del self.cheeses[:]
 
# Test input
from cheesy import CheeseShop
 
shop = CheeseShop()
print(shop.cheese)
 
shop.cheese = "camembert"
print(shop.cheese)
 
shop.cheese = "cheddar"
print(shop.cheese)
 
del shop.cheese
print(shop.cheese)

# Test output
We don't have: []
We don't have: ['camembert']
We don't have: ['camembert', 'cheddar']
We don't have: []

Subclassing

If an extension type inherits from other types, the first base class must bea built-in type or another extension type:

cdef class Parrot:
    ...
 
cdef class Norwegian(Parrot):
    ...

A complete definition of the base type must be available to Cython, so if thebase type is a built-in type, it must have been previously declared as anextern extension type. If the base type is defined in another Cython module, itmust either be declared as an extern extension type or imported using thecimport statement.

Multiple inheritance is supported, however the second and subsequent baseclasses must be an ordinary Python class (not an extension type or a built-intype).

Cython extension types can also be subclassed in Python. A Python class caninherit from multiple extension types provided that the usual Python rules formultiple inheritance are followed (i.e. the C layouts of all the base classesmust be compatible).

There is a way to prevent extension types frombeing subtyped in Python. This is done via the final directive,usually set on an extension type using a decorator:

cimport cython
 
@cython.final
cdef class Parrot:
   def done(self): pass

Trying to create a Python subclass from this type will raise aTypeError at runtime. Cython will also prevent subtyping afinal type inside of the same module, i.e. creating an extension typethat uses a final type as its base type will fail at compile time.Note, however, that this restriction does not currently propagate toother extension modules, so even final extension types can still besubtyped at the C level by foreign code.

C methods

Extension types can have C methods as well as Python methods. Like Cfunctions, C methods are declared using cdef or cpdef instead ofdef. C methods are “virtual”, and may be overridden in derivedextension types. In addition, cpdef methods can even be overridden by pythonmethods when called as C method. This adds a little to their calling overheadcompared to a cdef method:

# pets.pyx
cdef class Parrot:
 
    cdef void describe(self):
        print("This parrot is resting.")
 
cdef class Norwegian(Parrot):
 
    cdef void describe(self):
        Parrot.describe(self)
        print("Lovely plumage!")
 
 
cdef Parrot p1, p2
p1 = Parrot()
p2 = Norwegian()
print("p1:")
p1.describe()
print("p2:")
p2.describe()

# Output
p1:
This parrot is resting.
p2:
This parrot is resting.
Lovely plumage!

The above example also illustrates that a C method can call an inherited Cmethod using the usual Python technique, i.e.:

Parrot.describe(self)

cdef methods can be declared static by using the @staticmethod decorator.This can be especially useful for constructing classes that take non-Pythoncompatible types.:

cdef class OwnedPointer:
    cdef void* ptr
 
    def __dealloc__(self):
        if self.ptr is not NULL:
            free(self.ptr)
 
    @staticmethod
    cdef create(void* ptr):
        p = OwnedPointer()
        p.ptr = ptr
        return p

Forward-declaring extension types

Extension types can be forward-declared, like struct andunion types. This is usually not necessary and violates theDRY principle (Don’t Repeat Yourself).

If you are forward-declaring an extension type that has a base class, you mustspecify the base class in both the forward declaration and its subsequentdefinition, for example,:

cdef class A(B)
 
...
 
cdef class A(B):
    # attributes and methods

Fast instantiation

Cython provides two ways to speed up the instantiation of extension types.The first one is a direct call to the new() special static method,as known from Python. For an extension type Penguin, you could usethe following code:

cdef class Penguin:
    cdef object food
 
    def __cinit__(self, food):
        self.food = food
 
    def __init__(self, food):
        print("eating!")
 
normal_penguin = Penguin('fish')
fast_penguin = Penguin.__new__(Penguin, 'wheat')  # note: not calling __init__() !

Note that the path through new() will not call the type’sinit() method (again, as known from Python). Thus, in the exampleabove, the first instantiation will print eating!, but the second willnot. This is only one of the reasons why the cinit() method issafer and preferable over the normal init() method for extensiontypes.

The second performance improvement applies to types that are often createdand deleted in a row, so that they can benefit from a freelist. Cythonprovides the decorator @cython.freelist(N) for this, which creates astatically sized freelist of N instances for a given type. Example:

cimport cython
 
@cython.freelist(8)
cdef class Penguin:
    cdef object food
    def __cinit__(self, food):
        self.food = food
 
penguin = Penguin('fish 1')
penguin = None
penguin = Penguin('fish 2')  # does not need to allocate memory!

Instantiation from existing C/C++ pointers

It is quite common to want to instantiate an extension class from an existing(pointer to a) data structure, often as returned by external C/C++ functions.

As extension classes can only accept Python objects as arguments in theirconstructors, this necessitates the use of factory functions. For example,

from libc.stdlib cimport malloc, free
 
# Example C struct
ctypedef struct my_c_struct:
    int a
    int b
 
 
cdef class WrapperClass:
    """A wrapper class for a C/C++ data structure"""
    cdef my_c_struct *_ptr
    cdef bint ptr_owner
 
    def __cinit__(self):
        self.ptr_owner = False
 
    def __dealloc__(self):
        # De-allocate if not null and flag is set
        if self._ptr is not NULL and self.ptr_owner is True:
            free(self._ptr)
            self._ptr = NULL
 
    # Extension class properties
    @property
    def a(self):
        return self._ptr.a if self._ptr is not NULL else None
 
    @property
    def b(self):
        return self._ptr.b if self._ptr is not NULL else None
 
    @staticmethod
    cdef WrapperClass from_ptr(my_c_struct *_ptr, bint owner=False):
        """Factory function to create WrapperClass objects from
        given my_c_struct pointer.
 
        Setting ``owner`` flag to ``True`` causes
        the extension type to ``free`` the structure pointed to by ``_ptr``
        when the wrapper object is deallocated."""
        # Call to __new__ bypasses __init__ constructor
        cdef WrapperClass wrapper = WrapperClass.__new__(WrapperClass)
        wrapper._ptr = _ptr
        wrapper.ptr_owner = owner
        return wrapper
 
    @staticmethod
    cdef WrapperClass new_struct():
        """Factory function to create WrapperClass objects with
        newly allocated my_c_struct"""
        cdef my_c_struct *_ptr = <my_c_struct *>malloc(sizeof(my_c_struct))
        if _ptr is NULL:
            raise MemoryError
        _ptr.a = 0
        _ptr.b = 0
        return WrapperClass.from_ptr(_ptr, owner=True)

To then create a WrapperClass object from an existing my_c_structpointer, WrapperClass.from_ptr(ptr) can be used in Cython code. To allocatea new structure and wrap it at the same time, WrapperClass.new_struct can beused instead.

It is possible to create multiple Python objects all from the same pointerwhich point to the same in-memory data, if that is wanted, though care must betaken when de-allocating as can be seen above.Additionally, the ptr_owner flag can be used to control whichWrapperClass object owns the pointer and is responsible for de-allocation -this is set to False by default in the example and can be enabled by callingfrom_ptr(ptr, owner=True).

The GIL must not be released in dealloc either, or another lock usedif it is, in such cases or race conditions can occur with multiplede-allocations.

Being a part of the object constructor, the cinit method has a Pythonsignature, which makes it unable to accept a my_c_struct pointer as anargument.

Attempts to use pointers in a Python signature will result in errors like:

Cannot convert 'my_c_struct *' to Python object

This is because Cython cannot automatically convert a pointer to a Pythonobject, unlike with native types like int.

Note that for native types, Cython will copy the value and create a new Pythonobject while in the above case, data is not copied and deallocating memory isa responsibility of the extension class.

Making extension types weak-referenceable

By default, extension types do not support having weak references made tothem. You can enable weak referencing by declaring a C attribute of typeobject called weakref. For example,:

cdef class ExplodingAnimal:
    """This animal will self-destruct when it is
    no longer strongly referenced."""
 
    cdef object __weakref__

Controlling deallocation and garbage collection in CPython

Note

This section only applies to the usual CPython implementationof Python. Other implementations like PyPy work differently.

Introduction

First of all, it is good to understand that there are two ways totrigger deallocation of Python objects in CPython:CPython uses reference counting for all objects and any object with areference count of zero is immediately deallocated. This is the mostcommon way of deallocating an object. For example, consider

>>> x = "foo"
>>> x = "bar"

After executing the second line, the string "foo" is no longer referenced,so it is deallocated. This is done using the tpdealloc slot, which can becustomized in Cython by implementing _dealloc.

The second mechanism is the cyclic garbage collector.This is meant to resolve cyclic reference cycles such as

>>> class Object:
...     pass
>>> def make_cycle():
...     x = Object()
...     y = [x]
...     x.attr = y

When calling makecycle, a reference cycle is created since xreferences y and vice versa. Even though neither x or yare accessible after make_cycle returns, both have a reference countof 1, so they are not immediately deallocated. At regular times, the garbagecollector runs, which will notice the reference cycle(using the tp_traverse slot) and break it.Breaking a reference cycle means taking an object in the cycleand removing all references from it to other Python objects (we call this_clearing an object). Clearing is almost the same as deallocating, exceptthat the actual object is not yet freed. For x in the example above,the attributes of x would be removed from x.

Note that it suffices to clear just one object in the reference cycle,since there is no longer a cycle after clearing one object. Once the cycleis broken, the usual refcount-based deallocation will actually remove theobjects from memory. Clearing is implemented in the tp_clear slot.As we just explained, it is sufficient that one object in the cycleimplements tp_clear.

Enabling the deallocation trashcan

In CPython, it is possible to create deeply recursive objects. For example:

>>> L = None
>>> for i in range(2**20):
...     L = [L]

Now imagine that we delete the final L. Then L deallocatesL[0], which deallocates L[0][0] and so on until we reach arecursion depth of 2**20. This deallocation is done in C and sucha deep recursion will likely overflow the C call stack, crashing Python.

CPython invented a mechanism for this called the trashcan. It limits therecursion depth of deallocations by delaying some deallocations.

By default, Cython extension types do not use the trashcan but it can beenabled by setting the trashcan directive to True. For example:

cimport cython
@cython.trashcan(True)
cdef class Object:
    cdef dict __dict__

Trashcan usage is inherited by subclasses(unless explicitly disabled by @cython.trashcan(False)).Some builtin types like list use the trashcan, so subclasses of ituse the trashcan by default.

Disabling cycle breaking (tp_clear)

By default, each extension type will support the cyclic garbage collector ofCPython. If any Python objects can be referenced, Cython will automaticallygenerate the tp_traverse and tp_clear slots. This is usually what youwant.

There is at least one reason why this might not be what you want: If you needto cleanup some external resources in the dealloc special function andyour object happened to be in a reference cycle, the garbage collector mayhave triggered a call to tp_clear to clear the object(see Introduction).

In that case, any object references have vanished when deallocis called. Now your cleanup code lost access to the objects it has to clean up.To fix this, you can disable clearing instances of a specific class by usingthe no_gc_clear directive:

@cython.no_gc_clear
cdef class DBCursor:
    cdef DBConnection conn
    cdef DBAPI_Cursor *raw_cursor
# ...
def __dealloc__(self):
    DBAPI_close_cursor(self.conn.raw_conn, self.raw_cursor)

This example tries to close a cursor via a database connection when the Pythonobject is destroyed. The DBConnection object is kept alive by the referencefrom DBCursor. But if a cursor happens to be in a reference cycle, thegarbage collector may delete the database connection reference,which makes it impossible to clean up the cursor.

If you use nogc_clear, it is important that any given reference cyclecontains at least one object _without no_gc_clear. Otherwise, the cyclecannot be broken, which is a memory leak.

Disabling cyclic garbage collection

In rare cases, extension types can be guaranteed not to participate in cycles,but the compiler won’t be able to prove this. This would be the case ifthe class can never reference itself, even indirectly.In that case, you can manually disable cycle collection by using theno_gc directive, but beware that doing so when in fact the extension typecan participate in cycles could cause memory leaks

@cython.no_gc
cdef class UserInfo:
    cdef str name
    cdef tuple addresses

If you can be sure addresses will contain only references to strings,the above would be safe, and it may yield a significant speedup, depending onyour usage pattern.

Controlling pickling

By default, Cython will generate a reduce() method to allow picklingan extension type if and only if each of its members are convertible to Pythonand it has no cinit method.To require this behavior (i.e. throw an error at compile time if a classcannot be pickled) decorate the class with @cython.autopickle(True).One can also annotate with @cython.autopickle(False) to get the oldbehavior of not generating a __reduce method in any case.

Manually implementing a reduce or _reduce_ex`_ method will alsodisable this auto-generation and can be used to support pickling of morecomplicated types.

Public and external extension types

Extension types can be declared extern or public. An extern extension typedeclaration makes an extension type defined in external C code available to aCython module. A public extension type declaration makes an extension typedefined in a Cython module available to external C code.

External extension types

An extern extension type allows you to gain access to the internals of Pythonobjects defined in the Python core or in a non-Cython extension module.

Note

In previous versions of Pyrex, extern extension types were also used toreference extension types defined in another Pyrex module. While you can stilldo that, Cython provides a better mechanism for this. SeeSharing Declarations Between Cython Modules.

Here is an example which will let you get at the C-level members of thebuilt-in complex object.:

from __future__ import print_function
 
cdef extern from "complexobject.h":
 
    struct Py_complex:
        double real
        double imag
 
    ctypedef class __builtin__.complex [object PyComplexObject]:
        cdef Py_complex cval
 
# A function which uses the above type
def spam(complex c):
    print("Real:", c.cval.real)
    print("Imag:", c.cval.imag)

Note

Some important things:

• In this example, ctypedef class has been used. This isbecause, in the Python header files, the PyComplexObject struct isdeclared with:

typedef struct {
    ...
} PyComplexObject;

At runtime, a check will be performed when importing the Cythonc-extension module that builtin.complex’s tp_basicsizematches sizeof(`PyComplexObject). This check can fail if the Cythonc-extension module was compiled with one version of thecomplexobject.h header but imported into a Python with a changedheader. This check can be tweaked by using check_size in the namespecification clause.

• As well as the name of the extension type, the module in which its typeobject can be found is also specified. See the implicit importing sectionbelow.

• When declaring an external extension type, you don’t declare anymethods. Declaration of methods is not required in order to call them,because the calls are Python method calls. Also, as withstruct and union, if your extension classdeclaration is inside a cdef extern from block, you only need todeclare those C members which you wish to access.

Name specification clause

The part of the class declaration in square brackets is a special feature onlyavailable for extern or public extension types. The full form of this clauseis:

[object object_struct_name, type type_object_name, check_size cs_option]

Where:

• object_struct_name is the name to assume for the type’s C struct.
• type_object_name is the name to assume for the type’s staticallydeclared type object.
• cs_option is warn (the default), error, or ignore and is onlyused for external extension types. If error, the sizeof(object_struct)that was found at compile time must match the type’s runtime tp_basicsizeexactly, otherwise the module import will fail with an error. If warnor ignore, the object_struct is allowed to be smaller than the type’stp_basicsize, which indicates the runtime type may be part of an updatedmodule, and that the external module’s developers extended the object in abackward-compatible fashion (only adding new fields to the end of the object).If warn, a warning will be emitted in this case.

The clauses can be written in any order.

If the extension type declaration is inside a cdef extern fromblock, the object clause is required, because Cython must be able to generatecode that is compatible with the declarations in the header file. Otherwise,for extern extension types, the object clause is optional.

For public extension types, the object and type clauses are both required,because Cython must be able to generate code that is compatible with external Ccode.

Attribute name matching and aliasing

Sometimes the type’s C struct as specified in objectstructname may usedifferent labels for the fields than those in the PyTypeObject. This caneasily happen in hand-coded C extensions where the PyTypeObject_Foo has agetter method, but the name does not match the name in the PyFooObject. InNumPy, for instance, python-level dtype.itemsize is a getter for the Cstruct field elsize. Cython supports aliasing field names so that one canwrite dtype.itemsize in Cython code which will be compiled into directaccess of the C struct field, without going through a C-API equivalent ofdtype.__getattr('itemsize').

For example we may have an extensionmodule foo_extension:

cdef class Foo:
    cdef public int field0, field1, field2;
 
    def __init__(self, f0, f1, f2):
        self.field0 = f0
        self.field1 = f1
        self.field2 = f2

but a C struct in a file foo_nominal.h:

typedef struct {
     PyObject_HEAD
     int f0;
     int f1;
     int f2;
 } FooStructNominal;

Note that the struct uses f0, f1, f2 but they are field0,field1, and field2 in Foo. We are given this situation, includinga header file with that struct, and we wish to write a function to sum thevalues. If we write an extension module wrapper:

cdef extern from "foo_nominal.h":
 
    ctypedef class foo_extension.Foo [object FooStructNominal]:
        cdef:
            int field0
            int field1
            int feild2
 
def sum(Foo f):
    return f.field0 + f.field1 + f.field2

then wrapper.sum(f) (where f = foo_extension.Foo(1, 2, 3)) will stilluse the C-API equivalent of:

return f.__getattr__('field0') +
       f.__getattr__('field1') +
       f.__getattr__('field1')

instead of the desired C equivalent of return f->f0 + f->f1 + f->f2. We canalias the fields by using:

cdef extern from "foo_nominal.h":
 
    ctypedef class foo_extension.Foo [object FooStructNominal]:
        cdef:
            int field0 "f0"
            int field1 "f1"
            int field2 "f2"
 
def sum(Foo f) except -1:
    return f.field0 + f.field1 + f.field2

and now Cython will replace the slow getattr with direct C access tothe FooStructNominal fields. This is useful when directly processing Pythoncode. No changes to Python need be made to achieve significant speedups, eventhough the field names in Python and C are different. Of course, one shouldmake sure the fields are equivalent.

Implicit importing

Cython requires you to include a module name in an extern extension classdeclaration, for example,:

cdef extern class MyModule.Spam:
    ...

The type object will be implicitly imported from the specified module andbound to the corresponding name in this module. In other words, in thisexample an implicit:

from MyModule import Spam

statement will be executed at module load time.

The module name can be a dotted name to refer to a module inside a packagehierarchy, for example,:

cdef extern class My.Nested.Package.Spam:
    ...

You can also specify an alternative name under which to import the type usingan as clause, for example,:

cdef extern class My.Nested.Package.Spam as Yummy:
   ...

which corresponds to the implicit import statement:

from My.Nested.Package import Spam as Yummy

Type names vs. constructor names

Inside a Cython module, the name of an extension type serves two distinctpurposes. When used in an expression, it refers to a module-level globalvariable holding the type’s constructor (i.e. its type-object). However, itcan also be used as a C type name to declare variables, arguments and returnvalues of that type.

When you declare:

cdef extern class MyModule.Spam:
    ...

the name Spam serves both these roles. There may be other names by which youcan refer to the constructor, but only Spam can be used as a type name. Forexample, if you were to explicitly import MyModule, you could useMyModule.Spam() to create a Spam instance, but you wouldn’t be able to useMyModule.Spam as a type name.

When an as clause is used, the name specified in the as clause also takes overboth roles. So if you declare:

cdef extern class MyModule.Spam as Yummy:
    ...

then Yummy becomes both the type name and a name for the constructor. Again,there are other ways that you could get hold of the constructor, but onlyYummy is usable as a type name.

Public extension types

An extension type can be declared public, in which case a .h file isgenerated containing declarations for its object struct and type object. Byincluding the .h file in external C code that you write, that code canaccess the attributes of the extension type.