Pure Python Mode

In some cases, it’s desirable to speed up Python code without losing the ability to run it with the Python interpreter. While pure Python scripts can be compiled with Cython, it usually results only in a speed gain of about 20%-50%.

To go beyond that, Cython provides language constructs to add static typing and cythonic functionalities to a Python module to make it run much faster when compiled, while still allowing it to be interpreted. This is accomplished via an augmenting .pxd file, via Python type annotations (following PEP 484 and PEP 526), and/or via special functions and decorators available after importing the magic cython module. All three ways can be combined at need, although projects would commonly decide on a specific way to keep the static type information easy to manage.

Although it is not typically recommended over writing straight Cython code in a .pyx file, there are legitimate reasons to do this - easier testing and debugging, collaboration with pure Python developers, etc. In pure mode, you are more or less restricted to code that can be expressed (or at least emulated) in Python, plus static type declarations. Anything beyond that can only be done in .pyx files with extended language syntax, because it depends on features of the Cython compiler.

Augmenting .pxd

Using an augmenting .pxd allows to let the original .py file completely untouched. On the other hand, one needs to maintain both the .pxd and the .py to keep them in sync.

While declarations in a .pyx file must correspond exactly with those of a .pxd file with the same name (and any contradiction results in a compile time error, see pxd files), the untyped definitions in a .py file can be overridden and augmented with static types by the more specific ones present in a .pxd.

If a .pxd file is found with the same name as the .py file being compiled, it will be searched for cdef classes and cdef/cpdef functions and methods. The compiler will then convert the corresponding classes/functions/methods in the .py file to be of the declared type. Thus if one has a file A.py:

  1. def myfunction(x, y=2):
  2.     a = x - y
  3.     return a + x * y
  5. def _helper(a):
  6.     return a + 1
  8. class A:
  9.     def __init__(self, b=0):
  10.         self.a = 3
  11.         self.b = b
  13.     def foo(self, x):
  14.         print(x + _helper(1.0))

and adds A.pxd:

  1. cpdef int myfunction(int x, int y=*)
  2. cdef double _helper(double a)
  4. cdef class A:
  5.     cdef public int a, b
  6.     cpdef foo(self, double x)

then Cython will compile the A.py as if it had been written as follows:

  1. cpdef int myfunction(int x, int y=2):
  2.     a = x - y
  3.     return a + x * y
  5. cdef double _helper(double a):
  6.     return a + 1
  8. cdef class A:
  9.     cdef public int a, b
  10.     def __init__(self, b=0):
  11.         self.a = 3
  12.         self.b = b
  14.     cpdef foo(self, double x):
  15.         print(x + _helper(1.0))

Notice how in order to provide the Python wrappers to the definitions in the .pxd, that is, to be accessible from Python,

  • Python visible function signatures must be declared as cpdef (with default arguments replaced by a * to avoid repetition):

    1. cpdef int myfunction(int x, int y=*)

  • C function signatures of internal functions can be declared as cdef:

    1. cdef double _helper(double a)

  • cdef classes (extension types) are declared as cdef class;

  • cdef class attributes must be declared as cdef public if read/write Python access is needed, cdef readonly for read-only Python access, or plain cdef for internal C level attributes;

  • cdef class methods must be declared as cpdef for Python visible methods or cdef for internal C methods.

In the example above, the type of the local variable a in myfunction() is not fixed and will thus be a Python object. To statically type it, one can use Cython’s @cython.locals decorator (see Magic Attributes, and Magic Attributes within the .pxd).

Normal Python (def) functions cannot be declared in .pxd files. It is therefore currently impossible to override the types of plain Python functions in .pxd files, e.g. to override types of their local variables. In most cases, declaring them as cpdef will work as expected.

Magic Attributes

Special decorators are available from the magic cython module that can be used to add static typing within the Python file, while being ignored by the interpreter.

This option adds the cython module dependency to the original code, but does not require to maintain a supplementary .pxd file. Cython provides a fake version of this module as Cython.Shadow, which is available as cython.py when Cython is installed, but can be copied to be used by other modules when Cython is not installed.

“Compiled” switch

  • compiled is a special variable which is set to True when the compiler runs, and False in the interpreter. Thus, the code

    1. import cython
    3. if cython.compiled:
    4.     print("Yep, I'm compiled.")
    5. else:
    6.     print("Just a lowly interpreted script.")

    will behave differently depending on whether or not the code is executed as a compiled extension (.so/.pyd) module or a plain .py file.

Static typing

  • cython.declare declares a typed variable in the current scope, which can be used in place of the cdef type var [= value] construct. This has two forms, the first as an assignment (useful as it creates a declaration in interpreted mode as well):

    1. import cython
    3. x = cython.declare(cython.int)              # cdef int x
    4. y = cython.declare(cython.double, 0.57721)  # cdef double y = 0.57721

    and the second mode as a simple function call:

    1. import cython
    3. cython.declare(x=cython.int, y=cython.double)  # cdef int x; cdef double y

    It can also be used to define extension type private, readonly and public attributes:

    ``` import cython

  1. @cython.cclass
  2. class A:
  3.     cython.declare(a=cython.int, b=cython.int)
  4.     c = cython.declare(cython.int, visibility='public')
  5.     d = cython.declare(cython.int)  # private by default.
  6.     e = cython.declare(cython.int, visibility='readonly')
  8.     def __init__(self, a, b, c, d=5, e=3):
  9.         self.a = a
  10.         self.b = b
  11.         self.c = c
  12.         self.d = d
  13.         self.e = e
  14. ```

  • @cython.locals is a decorator that is used to specify the types of local variables in the function body (including the arguments):

    1. import cython
    3. @cython.locals(a=cython.long, b=cython.long, n=cython.longlong)
    4. def foo(a, b, x, y):
    5.     n = a * b
    6.     # ...

  • @cython.returns(<type>) specifies the function’s return type.

  • @cython.exceptval(value=None, *, check=False) specifies the function’s exception return value and exception check semantics as follows:

    1. @exceptval(-1)               # cdef int func() except -1:
    2. @exceptval(-1, check=False)  # cdef int func() except -1:
    3. @exceptval(check=True)       # cdef int func() except *:
    4. @exceptval(-1, check=True)   # cdef int func() except? -1:

  • Python annotations can be used to declare argument types, as shown in the following example. To avoid conflicts with other kinds of annotation usages, this can be disabled with the directive annotation_typing=False.

    1. import cython
    3. def func(foo: dict, bar: cython.int) -> tuple:
    4.     foo["hello world"] = 3 + bar
    5.     return foo, 5

    This can be combined with the @cython.exceptval() decorator for non-Python return types:

    1. import cython
    3. @cython.exceptval(-1)
    4. def func(x: cython.int) -> cython.int:
    5.     if x < 0:
    6.         raise ValueError("need integer >= 0")
    7.     return x + 1

    Since version 0.27, Cython also supports the variable annotations defined in PEP 526. This allows to declare types of variables in a Python 3.6 compatible way as follows:

    1. import cython
    3. def func():
    4.     # Cython types are evaluated as for cdef declarations
    5.     x: cython.int               # cdef int x
    6.     y: cython.double = 0.57721  # cdef double y = 0.57721
    7.     z: cython.float = 0.57721   # cdef float z  = 0.57721
    9.     # Python types shadow Cython types for compatibility reasons
    10.     a: float = 0.54321          # cdef double a = 0.54321
    11.     b: int = 5                  # cdef object b = 5
    12.     c: long = 6                 # cdef object c = 6
    13.     pass
    15. @cython.cclass
    16. class A:
    17.     a: cython.int
    18.     b: cython.int
    20.     def __init__(self, b=0):
    21.         self.a = 3
    22.         self.b = b

    There is currently no way to express the visibility of object attributes.

C types

There are numerous types built into the Cython module. It provides all the standard C types, namely char, short, int, long, longlong as well as their unsigned versions uchar, ushort, uint, ulong, ulonglong. The special bint type is used for C boolean values and Py_ssize_t for (signed) sizes of Python containers.

For each type, there are pointer types p_int, pp_int, etc., up to three levels deep in interpreted mode, and infinitely deep in compiled mode. Further pointer types can be constructed with cython.pointer(cython.int), and arrays as cython.int[10]. A limited attempt is made to emulate these more complex types, but only so much can be done from the Python language.

The Python types int, long and bool are interpreted as C int, long and bint respectively. Also, the Python builtin types list, dict, tuple, etc. may be used, as well as any user defined types.

Typed C-tuples can be declared as a tuple of C types.

Extension types and cdef functions

  • The class decorator @cython.cclass creates a cdef class.
  • The function/method decorator @cython.cfunc creates a cdef function.
  • @cython.ccall creates a cpdef function, i.e. one that Cython code can call at the C level.
  • @cython.locals declares local variables (see above). It can also be used to declare types for arguments, i.e. the local variables that are used in the signature.
  • @cython.inline is the equivalent of the C inline modifier.
  • @cython.final terminates the inheritance chain by preventing a type from being used as a base class, or a method from being overridden in subtypes. This enables certain optimisations such as inlined method calls.

Here is an example of a cdef function:

  1. @cython.cfunc
  2. @cython.returns(cython.bint)
  3. @cython.locals(a=cython.int, b=cython.int)
  4. def c_compare(a,b):
  5.     return a == b

Further Cython functions and declarations

  • address is used in place of the & operator:

    1. cython.declare(x=cython.int, x_ptr=cython.p_int)
    2. x_ptr = cython.address(x)

  • sizeof emulates the sizeof operator. It can take both types and expressions.

    1. cython.declare(n=cython.longlong)
    2. print(cython.sizeof(cython.longlong))
    3. print(cython.sizeof(n))

  • struct can be used to create struct types.:

    1. MyStruct = cython.struct(x=cython.int, y=cython.int, data=cython.double)
    2. a = cython.declare(MyStruct)

    is equivalent to the code:

    1. cdef struct MyStruct:
    2.     int x
    3.     int y
    4.     double data
    6. cdef MyStruct a

  • union creates union types with exactly the same syntax as struct.

  • typedef defines a type under a given name:

    1. T = cython.typedef(cython.p_int)   # ctypedef int* T

  • cast will (unsafely) reinterpret an expression type. cython.cast(T, t) is equivalent to <T>t. The first attribute must be a type, the second is the expression to cast. Specifying the optional keyword argument typecheck=True has the semantics of <T?>t.

    1. t1 = cython.cast(T, t)
    2. t2 = cython.cast(T, t, typecheck=True)

Magic Attributes within the .pxd

The special cython module can also be imported and used within the augmenting .pxd file. For example, the following Python file dostuff.py:

  1. def dostuff(n):
  2.     t = 0
  3.     for i in range(n):
  4.         t += i
  5.     return t

can be augmented with the following .pxd file dostuff.pxd:

  1. import cython
  3. @cython.locals(t=cython.int, i=cython.int)
  4. cpdef int dostuff(int n)

The cython.declare() function can be used to specify types for global variables in the augmenting .pxd file.

Tips and Tricks

Calling C functions

Normally, it isn’t possible to call C functions in pure Python mode as there is no general way to support it in normal (uncompiled) Python. However, in cases where an equivalent Python function exists, this can be achieved by combining C function coercion with a conditional import as follows:

  1. # mymodule.pxd
  3. # declare a C function as "cpdef" to export it to the module
  4. cdef extern from "math.h":
  5.     cpdef double sin(double x)
  1. # mymodule.py
  3. import cython
  5. # override with Python import if not in compiled code
  6. if not cython.compiled:
  7.     from math import sin
  9. # calls sin() from math.h when compiled with Cython and math.sin() in Python
  10. print(sin(0))

Note that the “sin” function will show up in the module namespace of “mymodule” here (i.e. there will be a mymodule.sin() function). You can mark it as an internal name according to Python conventions by renaming it to “_sin” in the .pxd file as follows:

  1. cdef extern from "math.h":
  2.     cpdef double _sin "sin" (double x)

You would then also change the Python import to from math import sin as _sin to make the names match again.

Using C arrays for fixed size lists

C arrays can automatically coerce to Python lists or tuples. This can be exploited to replace fixed size Python lists in Python code by C arrays when compiled. An example:

  1. import cython
  4. @cython.locals(counts=cython.int[10], digit=cython.int)
  5. def count_digits(digits):
  6.     """
  7.     >>> digits = '01112222333334445667788899'
  8.     >>> count_digits(map(int, digits))
  9.     [1, 3, 4, 5, 3, 1, 2, 2, 3, 2]
  10.     """
  11.     counts = [0] * 10
  12.     for digit in digits:
  13.         assert 0 <= digit <= 9
  14.         counts[digit] += 1
  15.     return counts

In normal Python, this will use a Python list to collect the counts, whereas Cython will generate C code that uses a C array of C ints.