Union types

The type of a variable or expression can consist of multiple types. This is called a union type. For example, when assigning to a same variable inside different if branches:

  1. if 1 + 2 == 3
  2.   a = 1
  3. else
  4.   a = "hello"
  5. end
  7. a # : Int32 | String

At the end of the if, a will have the Int32 | String type, read “the union of Int32 and String”. This union type is created automatically by the compiler. At runtime, a will of course be of one type only. This can be seen by invoking the class method:

  1. # The runtime type
  2. a.class # => Int32

The compile-time type can be seen by using typeof:

  1. # The compile-time type
  2. typeof(a) # => Int32 | String

A union can consist of an arbitrary large number of types. When invoking a method on an expression whose type is a union type, all types in the union must respond to the method, otherwise a compile-time error is given. The type of the method call is the union type of the return types of those methods.

  1. # to_s is defined for Int32 and String, it returns String
  2. a.to_s # => String
  4. a + 1 # Error, because String#+(Int32) isn't defined

If necessary a variable can be defined as a union type at compile time

  1. # set the compile-time type
  2. a = 0.as(Int32|Nil|String)
  3. typeof(a) # => Int32 | Nil | String

Union types rules

In the general case, when two types T1 and T2 are combined, the result is a union T1 | T2. However, there are a few cases where the resulting type is a different type.

Union of classes and structs under the same hierarchy

If T1 and T2 are under the same hierarchy, and their nearest common ancestor Parent is not Reference, Struct, Int, Float nor Value, the resulting type is Parent+. This is called a virtual type, which basically means the compiler will now see the type as being Parent or any of its subtypes.

For example:

  1. class Foo
  2. end
  4. class Bar < Foo
  5. end
  7. class Baz < Foo
  8. end
  10. bar = Bar.new
  11. baz = Baz.new
  13. # Here foo's type will be Bar | Baz,
  14. # but because both Bar and Baz inherit from Foo,
  15. # the resulting type is Foo+
  16. foo = rand < 0.5 ? bar : baz
  17. typeof(foo) # => Foo+

Union of tuples of the same size

The union of two tuples of the same size results in a tuple type that has the union of the types in each position.

For example:

  1. t1 = {1, "hi"}   # Tuple(Int32, String)
  2. t2 = {true, nil} # Tuple(Bool, Nil)
  4. t3 = rand < 0.5 ? t1 : t2
  5. typeof(t3) # Tuple(Int32 | Bool, String | Nil)

Union of named tuples with the same keys

The union of two named tuples with the same keys (regardless of their order) results in a named tuple type that has the union of the types in each key. The order of the keys will be the ones from the tuple on the left hand side.

For example:

  1. t1 = {x: 1, y: "hi"}   # Tuple(x: Int32, y: String)
  2. t2 = {y: true, x: nil} # Tuple(y: Bool, x: Nil)
  4. t3 = rand < 0.5 ? t1 : t2
  5. typeof(t3) # NamedTuple(x: Int32 | Nil, y: String | Bool)