Installation with Terraform

This topic describes how to use the mesh-task Terraform module to launch your application in AWS ECS as part of Consul service mesh. If you do not use Terraform, see the Manual Installation page to install Consul on ECS without Terraform.

This topic does not include instructions for creating all AWS resources necessary to install Consul, such as a VPC or the ECS cluster. Refer to the linked guides in the Getting Started section for complete, runnable examples.

Overview

This topic describes the following procedure:

1. Create Terraform configuration files for the necessary components:

   • ECS task definition: Use the mesh-task module to create an ECS task definition for Consul on ECS
   • ECS service: Use the aws_ecs_service resource to create an ECS service that schedules service mesh tasks to run on ECS
2. Run Terraform to deploy the resources in AWS

Prerequisites

• You should have some familiarity with using Terraform. Refer to the Terraform documentation to learn about infrastructure as code and how to get started with Terraform.
• You should also be familiar with AWS ECS before following these instructions. See What is Amazon Elastic Container Service for details.

Using the Mesh Task Module

To run an application in ECS with Consul service mesh, you must create an ECS task definition, which includes your application container(s) and additional sidecar containers, such as the Consul agent container and the Envoy sidecar proxy container.

The mesh-task module will automatically include the necessary sidecar containers.

The following example shows a Terraform configuration file that creates a task definition with an application container called example-client-app in a file called mesh-task.tf:

module "my_task" {
  source  = "hashicorp/consul-ecs/aws//modules/mesh-task"
  version = "<latest version>"
  family                = "my_task"
  container_definitions = [
    {
      name         = "example-client-app"
      image        = "docker.io/org/my_task:v0.0.1"
      essential    = true
      portMappings = [
        {
          containerPort = 9090
          hostPort      = 9090
          protocol      = "tcp"
        }
      ]
      cpu         = 0
      mountPoints = []
      volumesFrom = []
    }
  ]
  port       = 9090
  retry_join = ["<address of the Consul server>"]
}

mesh-task.tf

The following fields are required. Refer to the module reference documentation for a complete reference.

Running Terraform

You will need to run Terraform to create the task definition.

Save the Terraform configuration for the task definition to a file, such as mesh-task.tf. You should place this file in a directory alongside other Terraform configuration files for your project.

The mesh-task module requires the AWS Terraform provider. The following example shows how to include and configure the AWS provider in a file called provider.tf. Refer to the AWS Terraform provider documentation for complete configuration details.

terraform {
  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = "<latest version>"
    }
  }
}
provider "aws" {
  region = "<AWS region>"
  ...
}

provider.tf

Additional AWS resources for your project can be included in additional Terraform configuration files in the same directory. The following example shows a basic project directory:

$ ls
mesh-task.tf
provider.tf
...

Terraform should be run in your project directory as follows.

• Run terraform init first to download dependencies, such as Terraform providers
• Run terraform apply to have Terraform create AWS resources, such as the task definition from the mesh-task module.

Terraform automatically reads all files in the current directory that have a .tf file extension. Refer to the Terraform documentation for more information and Terraform best practices.

ECS Service

ECS services are one of the most common ways to start tasks using a task definition.

To define an ECS service, reference the mesh-task module’s task_definition_arn output value in your aws_ecs_service resource. The following example shows how to include the service in the mesh-task.tf file.

module "my_task" {
  source  = "hashicorp/consul-ecs/aws//modules/mesh-task"
  ...
}
resource "aws_ecs_service" "my_task" {
  name            = "my_task_service"
  task_definition = module.my_task.task_definition_arn
  launch_type     = "FARGATE"
  propagate_tags  = "TASK_DEFINITION"
  ...
}

mesh-task.tf

This is a partial configuration to highlight some important fields. See the aws_ecs_service documentation for a complete reference.

After including the ECS service in your Terraform configuration, run terraform apply from your project directory to create the ECS service resource. The ECS service will soon start your application in a task. The task will automatically register itself into the Consul service catalog during startup.

NOTE: If your tasks run in a public subnet, they must have assign_public_ip = true in their network_configuration block so that ECS can pull the Docker images.

Routing

Now that your tasks are registered in the mesh, you’re able to use the service mesh to route between them.

In order to make calls through the service mesh, you must configure the sidecar proxy to listen on a different port for each upstream service your application needs to call. You then must modify your application to make requests to the sidecar proxy on that port.

For example, if your application web makes calls to another application called backend, then you would first configure the mesh-task module’s upstream(s):

module "web" {
  family = "web"
  upstreams = [
    {
      destinationName = "backend"
      localBindPort = 8080
    }
  ]
}

If you have multiple upstream services they each need to be listed here.

Next, configure your application to make requests to localhost:8080 when it wants to call the backend service.

For example, if your service allows configuring the URL for backend via the BACKEND_URL environment variable, you would set:

module "web" {
  family = "web"
  upstreams = [
    {
      destinationName = "backend"
      localBindPort = 8080
    }
  ]
  container_definitions = [
    {
      name        = "web"
      environment = [
        {
          name  = "BACKEND_URL"
          value = "http://localhost:8080"
        }
      ]
      ...
    }
  ]
  ...
}

Bind Address

To ensure that your application only receives traffic through the service mesh, you must change the address that your application is listening on to only the loopback address (also known as localhost, lo, and 127.0.0.1) so that only the sidecar proxy running in the same task can make requests to it.

If your application is listening on all interfaces, e.g. 0.0.0.0, then other applications can call it directly, bypassing its sidecar proxy.

Changing the listening address is specific to the language and framework you’re using in your application. Regardless of which language/framework you’re using, it’s a good practice to make the address configurable via environment variable.

For example in Go, you would use:

s := &http.Server{
    Addr:           "127.0.0.1:8080",
  ...
}
log.Fatal(s.ListenAndServe())

In Django you’d use:

python manage.py runserver "127.0.0.1:8080"

Next Steps

• Follow the Secure Configuration to get production-ready.
• Now that your applications are running in the service mesh, read about other Service Mesh features.
• View the Architecture documentation to understand what’s going on under the hood.