for

for.zig

  1. const assert = @import("std").debug.assert;
  3. test "for basics" {
  4.     const items = [_]i32 { 4, 5, 3, 4, 0 };
  5.     var sum: i32 = 0;
  7.     // For loops iterate over slices and arrays.
  8.     for (items) |value| {
  9.         // Break and continue are supported.
  10.         if (value == 0) {
  11.             continue;
  12.         }
  13.         sum += value;
  14.     }
  15.     assert(sum == 16);
  17.     // To iterate over a portion of a slice, reslice.
  18.     for (items[0..1]) |value| {
  19.         sum += value;
  20.     }
  21.     assert(sum == 20);
  23.     // To access the index of iteration, specify a second capture value.
  24.     // This is zero-indexed.
  25.     var sum2: i32 = 0;
  26.     for (items) |value, i| {
  27.         assert(@typeOf(i) == usize);
  28.         sum2 += @intCast(i32, i);
  29.     }
  30.     assert(sum2 == 10);
  31. }
  33. test "for reference" {
  34.     var items = [_]i32 { 3, 4, 2 };
  36.     // Iterate over the slice by reference by
  37.     // specifying that the capture value is a pointer.
  38.     for (items) |*value| {
  39.         value.* += 1;
  40.     }
  42.     assert(items[0] == 4);
  43.     assert(items[1] == 5);
  44.     assert(items[2] == 3);
  45. }
  47. test "for else" {
  48.     // For allows an else attached to it, the same as a while loop.
  49.     var items = [_]?i32 { 3, 4, null, 5 };
  51.     // For loops can also be used as expressions.
  52.     // Similar to while loops, when you break from a for loop, the else branch is not evaluated.
  53.     var sum: i32 = 0;
  54.     const result = for (items) |value| {
  55.         if (value != null) {
  56.             sum += value.?;
  57.         }
  58.     } else blk: {
  59.         assert(sum == 12);
  60.         break :blk sum;
  61.     };
  62.     assert(result == 12);
  63. }
  1. $ zig test for.zig
  2. 1/3 test "for basics"...OK
  3. 2/3 test "for reference"...OK
  4. 3/3 test "for else"...OK
  5. All tests passed.

Labeled for

When a for loop is labeled, it can be referenced from a break or continue from within a nested loop:

test.zig

  1. const std = @import("std");
  2. const assert = std.debug.assert;
  4. test "nested break" {
  5.     var count: usize = 0;
  6.     outer: for ([_]i32{ 1, 2, 3, 4, 5 }) |_| {
  7.         for ([_]i32{ 1, 2, 3, 4, 5 }) |_| {
  8.             count += 1;
  9.             break :outer;
  10.         }
  11.     }
  12.     assert(count == 1);
  13. }
  15. test "nested continue" {
  16.     var count: usize = 0;
  17.     outer: for ([_]i32{ 1, 2, 3, 4, 5, 6, 7, 8 }) |_| {
  18.         for ([_]i32{ 1, 2, 3, 4, 5 }) |_| {
  19.             count += 1;
  20.             continue :outer;
  21.         }
  22.     }
  24.     assert(count == 8);
  25. }
  1. $ zig test test.zig
  2. 1/2 test "nested break"...OK
  3. 2/2 test "nested continue"...OK
  4. All tests passed.

inline for

For loops can be inlined. This causes the loop to be unrolled, which allows the code to do some things which only work at compile time, such as use types as first class values. The capture value and iterator value of inlined for loops are compile-time known.

test.zig

  1. const assert = @import("std").debug.assert;
  3. test "inline for loop" {
  4.     const nums = [_]i32{2, 4, 6};
  5.     var sum: usize = 0;
  6.     inline for (nums) |i| {
  7.         const T = switch (i) {
  8.             2 => f32,
  9.             4 => i8,
  10.             6 => bool,
  11.             else => unreachable,
  12.         };
  13.         sum += typeNameLength(T);
  14.     }
  15.     assert(sum == 9);
  16. }
  18. fn typeNameLength(comptime T: type) usize {
  19.     return @typeName(T).len;
  20. }
  1. $ zig test test.zig
  2. 1/1 test "inline for loop"...OK
  3. All tests passed.

It is recommended to use inline loops only for one of these reasons:

  • You need the loop to execute at comptime for the semantics to work.
  • You have a benchmark to prove that forcibly unrolling the loop in this way is measurably faster.

See also: