代理（Delegate）

当使用模型与视图来自定义用户界面时，代理在创建显示时扮演了大量的角色。在模型中的每个元素通过代理来实现可视化，用户真实可见的是这些代理元素。

每个代理访问到索引号或者绑定的属性，一些是来自数据模型，一些来自视图。来自模型的数据将会通过属性传递到代理。来自视图的数据将会通过属性传递视图中与代理相关的状态信息。

通常使用的视图绑定属性是ListView.isCurrentItem和ListView.view。第一个是一个布尔值，标识这个元素是否是视图当前元素，这个值是只读的，引用自当前视图。通过访问视图，可以创建可复用的代理，这些代理在被包含时会自动匹配视图的大小。在下面这个例子中，每个代理的width（宽度）属性与视图的width（宽度）属性绑定，每个代理的背景颜色color依赖于绑定的属性ListView.isCurrentItem属性。

  1. import QtQuick 2.0
  3. Rectangle {
  4.     width: 120
  5.     height: 300
  7.     color: "white"
  9.     ListView {
  10.         anchors.fill: parent
  11.         anchors.margins: 20
  13.         clip: true
  15.         model: 100
  17.         delegate: numberDelegate
  18.         spacing: 5
  20.         focus: true
  21.     }
  23.     Component {
  24.         id: numberDelegate
  26.         Rectangle {
  27.             width: ListView.view.width
  28.             height: 40
  30.             color: ListView.isCurrentItem?"gray":"lightGray"
  32.             Text {
  33.                 anchors.centerIn: parent
  35.                 font.pixelSize: 10
  37.                 text: index
  38.             }
  39.         }
  40.     }
  41. }

代理（Delegate） - 图1

如果在模型中的每个元素与一个动作相关，例如点击作用于一个元素时，这个功能是代理完成的。这是由事件管理分配给视图的，这个操作控制了视图中元素的导航，代理控制了特定元素上的动作。

最基础的方法是在每个代理中创建一个MouseArea（鼠标区域）并且响应onClicked信号。在后面章节中将会演示这个例子。

6.4.1 动画添加与移除元素（Animating Added and Removed Items）

在某些情况下，视图中的显示内容会随着时间而改变。由于模型数据的改变，元素会添加或者移除。在这些情况下，一个比较好的做法是使用可视化队列给用户一个方向的感觉来帮助用户知道哪些数据被加入或者移除。

为了方便使用，QML视图为每个代理绑定了两个信号，onAdd和onRemove。使用动画连接它们，可以方便创建识别哪些内容被添加或删除的动画。

下面这个例子演示了如何动态填充一个链表模型（ListModel）。在屏幕下方，有一个添加新元素的按钮。当点击它时，会调用模型的append方法来添加一个新的元素。这个操作会触发视图创建一个新的代理，并发送GridView.onAdd信号。SequentialAnimation队列动画与这个信号连接绑定，使用代理的scale属性来放大视图元素。

当视图中的一个代理点击时，将会调用模型的remove方法将一个元素从模型中移除。这个操作将会导致GridView.onRemove信号的发送，触发另一个SequentialAnimation。这时，代理的销毁将会延迟直到动画完成。为了完成这个操作，PropertyAction元素需要在动画前设置GridView.delayRemove属性为true，并在动画后设置为false。这样确保了动画在代理项移除前完成。

  1. import QtQuick 2.0
  3. Rectangle {
  4.     width: 480
  5.     height: 300
  7.     color: "white"
  9.     ListModel {
  10.         id: theModel
  12.         ListElement { number: 0 }
  13.         ListElement { number: 1 }
  14.         ListElement { number: 2 }
  15.         ListElement { number: 3 }
  16.         ListElement { number: 4 }
  17.         ListElement { number: 5 }
  18.         ListElement { number: 6 }
  19.         ListElement { number: 7 }
  20.         ListElement { number: 8 }
  21.         ListElement { number: 9 }
  22.     }
  24.     Rectangle {
  25.         anchors.left: parent.left
  26.         anchors.right: parent.right
  27.         anchors.bottom: parent.bottom
  28.         anchors.margins: 20
  30.         height: 40
  32.         color: "darkGreen"
  34.         Text {
  35.             anchors.centerIn: parent
  37.             text: "Add item!"
  38.         }
  40.         MouseArea {
  41.             anchors.fill: parent
  43.             onClicked: {
  44.                 theModel.append({"number": ++parent.count});
  45.             }
  46.         }
  48.         property int count: 9
  49.     }
  51.     GridView {
  52.         anchors.fill: parent
  53.         anchors.margins: 20
  54.         anchors.bottomMargin: 80
  56.         clip: true
  58.         model: theModel
  60.         cellWidth: 45
  61.         cellHeight: 45
  63.         delegate: numberDelegate
  64.     }
  66.     Component {
  67.         id: numberDelegate
  69.         Rectangle {
  70.             id: wrapper
  72.             width: 40
  73.             height: 40
  75.             color: "lightGreen"
  77.             Text {
  78.                 anchors.centerIn: parent
  80.                 font.pixelSize: 10
  82.                 text: number
  83.             }
  85.             MouseArea {
  86.                 anchors.fill: parent
  88.                 onClicked: {
  89.                     if (!wrapper.GridView.delayRemove)
  90.                         theModel.remove(index);
  91.                 }
  92.             }
  94.             GridView.onRemove: SequentialAnimation {
  95.                 PropertyAction { target: wrapper; property: "GridView.delayRemove"; value: true }
  96.                 NumberAnimation { target: wrapper; property: "scale"; to: 0; duration: 250; easing.type: Easing.InOutQuad }
  97.                 PropertyAction { target: wrapper; property: "GridView.delayRemove"; value: false }
  98.             }
  100.             GridView.onAdd: SequentialAnimation {
  101.                 NumberAnimation { target: wrapper; property: "scale"; from: 0; to: 1; duration: 250; easing.type: Easing.InOutQuad }
  102.             }
  103.         }
  104.     }
  105. }

6.4.2 形变的代理（Shape-Shifting Delegates）

在使用链表时通常会使用当前项激活时展开的机制。这个操作可以被用于动态的将当前项目填充到整个屏幕来添加一个新的用户界面，或者为链表中的当前项提供更多的信息。

在下面的例子中，当点击链表项时，链表项都会展开填充整个链表视图（ListView）。额外的间隔区域被用于添加更多的信息，这种机制使用一个状态来控制，当一个链表项展开时，代理项都能输入expanded（展开）状态，在这种状态下一些属性被改变。

首先，包装器（wrapper）的高度（height）被设置为链表视图（ListView）的高度。标签图片被放大并且下移，使图片从小图片的位置移向大图片的位置。除了这些之外，两个隐藏项，实际视图（factsView）与关闭按键（closeButton）切换它的opactiy（透明度）显示出来。最后设置链表视图（ListView）。

设置链表视图（ListView）包含了设置内容Y坐标（contentsY），这是视图顶部可见的部分代理的Y轴坐标。另一个变化是设置视图的交互（interactive）为false。这个操作阻止了视图的移动，用户不再能够通过滚动条切换当前项。

由于设置第一个链表项为可点击，向它输入一个expanded（展开）状态，导致了它的代理项被填充到整个链表并且内容重置。当点击关闭按钮时，清空状态，导致它的代理项返回上一个状态，并且重新设置链表视图（ListView）有效。

  1. import QtQuick 2.0
  3. Item {
  4.     width: 300
  5.     height: 480
  7.     ListView {
  8.         id: listView
  10.         anchors.fill: parent
  12.         delegate: detailsDelegate
  13.         model: planets
  14.     }
  16.     ListModel {
  17.         id: planets
  19.         ListElement { name: "Mercury"; imageSource: "images/mercury.jpeg"; facts: "Mercury is the smallest planet in the Solar System. It is the closest planet to the sun. It makes one trip around the Sun once every 87.969 days." }
  20.         ListElement { name: "Venus"; imageSource: "images/venus.jpeg"; facts: "Venus is the second planet from the Sun. It is a terrestrial planet because it has a solid, rocky surface. The other terrestrial planets are Mercury, Earth and Mars. Astronomers have known Venus for thousands of years." }
  21.         ListElement { name: "Earth"; imageSource: "images/earth.jpeg"; facts: "The Earth is the third planet from the Sun. It is one of the four terrestrial planets in our Solar System. This means most of its mass is solid. The other three are Mercury, Venus and Mars. The Earth is also called the Blue Planet, 'Planet Earth', and 'Terra'." }
  22.         ListElement { name: "Mars"; imageSource: "images/mars.jpeg"; facts: "Mars is the fourth planet from the Sun in the Solar System. Mars is dry, rocky and cold. It is home to the largest volcano in the Solar System. Mars is named after the mythological Roman god of war because it is a red planet, which signifies the colour of blood." }
  23.     }
  25.     Component {
  26.         id: detailsDelegate
  28.         Item {
  29.             id: wrapper
  31.             width: listView.width
  32.             height: 30
  34.             Rectangle {
  35.                 anchors.left: parent.left
  36.                 anchors.right: parent.right
  37.                 anchors.top: parent.top
  39.                 height: 30
  41.                 color: "#ffaa00"
  43.                 Text {
  44.                     anchors.left: parent.left
  45.                     anchors.verticalCenter: parent.verticalCenter
  47.                     font.pixelSize: parent.height-4
  49.                     text: name
  50.                 }
  51.             }
  53.             Rectangle {
  54.                 id: image
  56.                 color: "black"
  58.                 anchors.right: parent.right
  59.                 anchors.top: parent.top
  60.                 anchors.rightMargin: 2
  61.                 anchors.topMargin: 2
  63.                 width: 26
  64.                 height: 26
  66.                 Image {
  67.                     anchors.fill: parent
  69.                     fillMode: Image.PreserveAspectFit
  71.                     source: imageSource
  72.                 }
  73.             }
  75.             MouseArea {
  76.                 anchors.fill: parent
  77.                 onClicked: parent.state = "expanded"
  78.             }
  80.             Item {
  81.                 id: factsView
  83.                 anchors.top: image.bottom
  84.                 anchors.left: parent.left
  85.                 anchors.right: parent.right
  86.                 anchors.bottom: parent.bottom
  88.                 opacity: 0
  90.                 Rectangle {
  91.                     anchors.fill: parent
  93.                     color: "#cccccc"
  95.                     Text {
  96.                         anchors.fill: parent
  97.                         anchors.margins: 5
  99.                         clip: true
  100.                         wrapMode: Text.WordWrap
  102.                         font.pixelSize: 12
  104.                         text: facts
  105.                     }
  106.                 }
  107.             }
  109.             Rectangle {
  110.                 id: closeButton
  112.                 anchors.right: parent.right
  113.                 anchors.top: parent.top
  114.                 anchors.rightMargin: 2
  115.                 anchors.topMargin: 2
  117.                 width: 26
  118.                 height: 26
  120.                 color: "red"
  122.                 opacity: 0
  124.                 MouseArea {
  125.                     anchors.fill: parent
  126.                     onClicked: wrapper.state = ""
  127.                 }
  128.             }
  130.             states: [
  131.                 State {
  132.                     name: "expanded"
  134.                     PropertyChanges { target: wrapper; height: listView.height }
  135.                     PropertyChanges { target: image; width: listView.width; height: listView.width; anchors.rightMargin: 0; anchors.topMargin: 30 }
  136.                     PropertyChanges { target: factsView; opacity: 1 }
  137.                     PropertyChanges { target: closeButton; opacity: 1 }
  138.                     PropertyChanges { target: wrapper.ListView.view; contentY: wrapper.y; interactive: false }
  139.                 }
  140.             ]
  142.             transitions: [
  143.                 Transition {
  144.                     NumberAnimation {
  145.                         duration: 200;
  146.                         properties: "height,width,anchors.rightMargin,anchors.topMargin,opacity,contentY"
  147.                     }
  148.                 }
  149.             ]
  150.         }
  151.     }
  152. }

代理（Delegate） - 图2

代理（Delegate） - 图3

这个技术展示了展开代理来填充视图能够简单的通过代理的形变来完成。例如当浏览一个歌曲的链表时，可以通过放大当前项来对该项添加更多的说明。