GDScript grammar

This is the formal grammar of GDScript written in EBNF, for reference purposes.

注解

This grammar is descriptive only, derived from the reference documentation and current implementation. The GDScript parser is not generated from a grammar definition. Inconsistencies here likely mean an error in this grammar, not a bug in GDScript.

  1. (* GDScript EBNF grammar.
  2.    Uppercase words are terminals generated by the tokenizer.
  3.    INDENT/DEDENT are not generated by the tokenizer yet, but they are added
  4.    here for reading convenience.
  5.    Naturally, this only cover syntax. Semantics can't be inferred from this
  6.    description.
  7. *)
  9. program = [ inheritance NEWLINE ] [ className ] { topLevelDecl } ;
  11. inheritance = "extends" ( IDENTIFIER | STRING ) { "." IDENTIFIER } ;
  12. className = "class_name" IDENTIFIER [ "," STRING ] NEWLINE ;
  14. topLevelDecl
  15.     = classVarDecl
  16.     | constDecl
  17.     | signalDecl
  18.     | enumDecl
  19.     | methodDecl
  20.     | constructorDecl
  21.     | innerClass
  22.     | "tool"
  23.     ;
  25. classVarDecl = [ "onready" ] [ export ] "var" IDENTIFIER [ ":" typeHint ]
  26.     [ "=" expression ] [ setget ] NEWLINE ;
  27. setget = "setget" [ IDENTIFIER ] [ "," IDENTIFIER] ;
  28. export = "export" [ "(" [ BUILTINTYPE | IDENTIFIER { "," literal } ] ")" ] ;
  29. typeHint = BUILTINTYPE | IDENTIFIER ;
  31. constDecl = "const" IDENTIFIER [ ":" typeHint ] "=" expression NEWLINE ;
  33. signalDecl = "signal" IDENTIFIER [ signalParList ] NEWLINE ;
  34. signalParList = "(" [ IDENTIFIER { "," IDENTIFIER } ] ")" ;
  36. enumDecl = "enum" [ IDENTIFIER ] "{" [ IDENTIFIER [ "=" INTEGER ]
  37.     { "," IDENTIFIER [ "=" INTEGER ] } [ "," ] ] "}" NEWLINE ;
  39. methodDecl = [ rpc ] [ "static" ] "func" IDENTIFIER "(" [ parList ] ")"
  40.     [ "->" typeHint] ":" stmtOrSuite ;
  41. parList = parameter { "," parameter } ;
  42. parameter = [ "var" ] IDENTIFIER [ ":" typeHint ] [ "=" expression ] ;
  43. rpc = "remote" | "master" | "puppet"
  44.     | "remotesync" | "mastersync"  | "puppetsync";
  46. constructorDecl = "func" IDENTIFIER "(" [ parList ] ")"
  47.     [ "." "(" [ argList ] ")" ] ":" stmtOrSuite ;
  48. argList = expression { "," expression } ;
  50. innerClass = "class" IDENTIFIER [ inheritance ] ":" NEWLINE
  51.     INDENT [ inheritance NEWLINE ] topLevelDecl { topLevelDecl } DEDENT ;
  53. stmtOrSuite = stmt | NEWLINE INDENT suite DEDENT ;
  54. suite = stmt { stmt };
  56. stmt
  57.     = varDeclStmt
  58.     | ifStmt
  59.     | forStmt
  60.     | whileStmt
  61.     | matchStmt
  62.     | flowStmt
  63.     | assignmentStmt
  64.     | exprStmt
  65.     | assertStmt
  66.     | yieldStmt
  67.     | preloadStmt
  68.     | "breakpoint" stmtEnd
  69.     | "pass" stmtEnd
  70.     ;
  71. stmtEnd = NEWLINE | ";" ;
  73. ifStmt = "if" expression ":" stmtOrSuite { "elif" expression ":" stmtOrSuite }
  74.     [ "else" ":" stmtOrSuite ] ;
  75. whileStmt = "while" expression ":" stmtOrSuite;
  76. forStmt = "for" IDENTIFIER "in" expression ":" stmtOrSuite ;
  78. matchStmt = "match" expression ":" NEWLINE INDENT matchBlock DEDENT;
  79. matchBlock = patternList ":" stmtOrSuite { patternList ":" stmtOrSuite };
  80. patternList = pattern { "," pattern } ;
  81. (* Note: you can't have a binding in a pattern list, but to not complicate the
  82. grammar more it won't be restricted syntactically *)
  83. pattern = literal | BUILTINTYPE | CONSTANT | "_" | bindingPattern
  84.     | arrayPattern | dictPattern ;
  85. bindingPattern = "var" IDENTIFIER ;
  86. arrayPattern = "[" [ pattern { "," pattern } [ ".." ] ] "]" ;
  87. dictPattern = "{" [ keyValuePattern ] { "," keyValuePattern } [ ".." ] "}" ;
  88. keyValuePattern = STRING [ ":" pattern ] ;
  90. flowStmt
  91.     = "continue" stmtEnd
  92.     | "break" stmtEnd
  93.     | "return" [ expression ] stmtEnd
  94.     ;
  96. assignmentStmt = subscription "=" expression stmtEnd;
  97. varDeclStmt = "var" IDENTIFIER [ "=" expression ] stmtEnd;
  99. assertStmt = "assert" "(" expression [ "," STRING ] ")" stmtEnd ;
  100. yieldStmt = "yield" "(" [ expression "," expression ] ")" ;
  101. preloadStmt = "preload" "(" CONSTANT ")" ;
  103. (* This expression grammar encodes precedence. Items later in the list have
  104. higher precedence than the ones before. *)
  105. exprStmt = expression stmtEnd ;
  106. expression = cast [ "[" expression "]" ] ;
  107. cast = ternaryExpr [ "as" typeHint ];
  108. ternaryExpr = logicOr [ "if" logicOr "else" logicOr ] ;
  109. logicOr = logicAnd { ( "or" | "||" ) logicAnd } ;
  110. logicAnd = logicNot { ( "and" | "&&" ) logicNot };
  111. logicNot = ( "!" | "not" ) logicNot | in;
  112. in = comparison { "in" comparison };
  113. comparison = bitOr { ( "<" | ">" | "<=" | ">=" | "==" | "!=" ) bitOr } ;
  114. bitOr = bitXor { "|" bitXor } ;
  115. bitXor = bitAnd { "^" bitAnd } ;
  116. bitAnd = bitShift { "&" bitShift } ;
  117. bitShift = minus { ( "<<" | ">>" ) minus } ;
  118. minus = plus { "-" plus } ;
  119. plus = factor { "+" factor } ;
  120. factor = sign { ( "*" | "/" | "%" ) sign } ;
  121. sign = ( "-" | "+" ) sign | bitNot ;
  122. bitNot = "~" bitNot | is ;
  123. is = call [ "is" ( IDENTIFIER | BUILTINTYPE ) ] ;
  124. call = attribute [ "(" [ argList ] ")" ];
  125. attribute = subscription { "." IDENTIFIER } ;
  126. subscription = primary [ "[" expression "]" ] ;
  127. primary = "true" | "false" | "null" | "self" | literal | arrayDecl
  128.     | dictDecl | "(" expression ")" ;
  130. literal = STRING | NUMBER | IDENTIFIER | BUILTINTYPE
  131.     | "PI" | "TAU" | "NAN" | "INF" ;
  132. arrayDecl = "[" [ expression { "," expression } "," ] "]" ;
  133. dictDecl = "{" [ keyValue { "," keyValue } "," ] "}" ;
  134. keyValue
  135.     = expression ":" expression
  136.     | IDENTIFIER "=" expression
  137.     ;